dev-python/thonny: add 5.0.0

Signed-off-by: Dominik George <nik+gentoo@squirrel.land>

dev-python/thonny/Manifest

@@ -1 +1,2 @@
 DIST thonny-4.1.7.tar.gz 4085064 BLAKE2B fd91d4c3f45dd545d9c7c6d1edda636d0c784bb8dc491f2f8185f9bf1198c3ef81f43a56e4c7cc59b6fed9c337891b36b55523ab44cd39abe448eced2ced375d SHA512 8f263c0eb3430947bbd601090befad1181ae6990ea23f2962e3837aaf9dbf083f3f89eaae717e2db526d969311a28f170b76b7ccad2c8c269c253065eb8cfbb8
+DIST thonny-5.0.0.tar.gz 4435895 BLAKE2B 7ab21e5605397f2e7e8a0e34559a1c1c55bba377890c5be90fe6da37cc08bff8403d54152b92a7bf43ce1ff79f4598db6fc890cb08dc491750bae8713fbec5e3 SHA512 978b3f32ea03296ecb0530eb5e4d044f300ba665b552ae5a228de4270eb6efa41b8091e39a6fd17946140ac39a0f24d090df425d346aa179249a15c7517e277e

dev-python/thonny/thonny-5.0.0.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=uv-build
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="tk"
+
+inherit desktop distutils-r1 xdg optfeature
+
+DESCRIPTION="Thonny is a Python IDE meant for learning programming"
+HOMEPAGE="
+	https://thonny.org/ https://github.com/thonny/thonny"
+SRC_URI="
+	https://github.com/thonny/thonny/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/jedi-0.18.1[${PYTHON_USEDEP}]
+	dev-python/minny[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/pyserial[${PYTHON_USEDEP}]
+	dev-python/pylint[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/mypy[${PYTHON_USEDEP}]
+	dev-python/asttokens[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+	newicon packaging/icons/thonny-32x32.png thonny.png
+	domenu "${S}/packaging/linux/org.thonny.Thonny.desktop"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "CircuitPython support" dev-python/esptool
+	optfeature "MicroPython support" dev-python/adafruit-ampy
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}