dev-python/cyclopts: add 4.23.3

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>

dev-python/cyclopts/Manifest

@@ -1 +1,2 @@
 DIST cyclopts-4.22.1.gh.tar.gz 2366157 BLAKE2B 22dec31521d7bb8f93a144ce1feeb10d6209be4a4bfe13620d8b58b78fe939725adbe383fe61ee3d7a4bcfe1de0877a48f1f5ffe34765e0070f68d89fb2267d1 SHA512 677a640d14ac8f87edff63416dedef0c07d0bc7a155d1c3a3e58f044a5f7e5b720e3f7c95cb0926c55e2d2cbdad79ae6a62f70ddc659b48a9be1cf2447c6cd21
+DIST cyclopts-4.23.3.gh.tar.gz 2375268 BLAKE2B 97d365b63602ab2cad66bce19160510ae29d09d02647b4784107e514340a528253b047b54f0d19768155d4337090c94f940e93563cececc2478d23c53c2df1f7 SHA512 962c7a932ee96bff94d5b35d98e8928302896a1a846b70cc81c18d0a6afc40fb32afbd1bf3af2358cff487f634347b14b21911aac2fbac29a1cc21efd2ae386b

dev-python/cyclopts/cyclopts-4.23.3.ebuild

@@ -0,0 +1,58 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Intuitive, easy CLIs based on type hints"
+HOMEPAGE="
+	https://github.com/BrianPugh/cyclopts
+	https://pypi.org/project/cyclopts/
+"
+SRC_URI="https://github.com/BrianPugh/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/attrs-23.1.0[${PYTHON_USEDEP}]
+	>=dev-python/docstring-parser-0.15[${PYTHON_USEDEP}]
+	>=dev-python/rich-13.6.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-rst-1.3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/pydantic-2.11.2[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/trio-0.10.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=(
+	pytest-mock
+	syrupy
+)
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Requires dev-python/mkdocs
+	tests/test_docs_snapshots.py::TestMkDocsDirectiveSnapshots
+)
+EPYTEST_IGNORE=(
+	# Requires dev-python/mkdocs
+	tests/test_mkdocs_ext.py
+)
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+pkg_postinst() {
+	optfeature "Trio async backend" dev-python/trio
+	optfeature "reading YAML configurations" dev-python/pyyaml
+}