gui-wm/mangowm: add 0.15.6

Signed-off-by: HAZARD <ghostyn678+git@gmail.com>

gui-wm/mangowm/Manifest

@@ -1 +1,2 @@
 DIST mangowm-0.15.5.tar.gz 500228 BLAKE2B ad3b90d7cd53767da26024e02e3851e463022bd699b0a207f7e543f8cfe6fbc796c572bd5451dd7de6ef60be5515e8fddc0e9728e743f6c55b3f7026827f3dfe SHA512 50ffcd98a48122bc39c14412a549b1ab6ab77521fd94325881da694b12a689cfd777f674222e179d7a5ed55700f5b446b6d228da322bdf23649198f486585981
+DIST mangowm-0.15.6.tar.gz 501916 BLAKE2B 5e4ce9b2aff9b67450f106fbf068fbea9c16f6befa1a41984e43039d8c499cc7f5eb269580cb318a294451f1aa1acedc8ef276c836235836ad3a3ca42448bf0c SHA512 c511b630063d49a8e49e39a07cb96bb80bea71b2314778a246703ade6b6efb46f26d2199bb5107ded9d80b79c0be9a0c8d1f09fac3b59fb9bfb90ed25dc1391c

gui-wm/mangowm/mangowm-0.15.6.ebuild

@@ -0,0 +1,77 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+MY_PN="mango"
+MY_P=${MY_PN}-${PV}
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mangowm/mango.git"
+else
+	SRC_URI="https://github.com/mangowm/mango/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="A fast, feature-rich Wayland compositor built on dwl"
+HOMEPAGE="
+	https://github.com/mangowm/mango
+	https://mangowm.github.io
+"
+
+LICENSE="CC0-1.0 GPL-3+ MIT"
+SLOT="0"
+
+DOCS=(
+	README.md
+	.github/CONTRIBUTING.md
+)
+
+IUSE="X asan"
+
+RDEPEND="
+	>=gui-libs/wlroots-0.20:=[libinput,session,X?]
+	<gui-libs/wlroots-0.21:=[X?]
+	>=gui-libs/scenefx-0.5:0.5
+
+	dev-libs/cJSON
+	dev-libs/libinput:=
+	dev-libs/libpcre2
+	dev-libs/wayland
+
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	x11-libs/pixman
+
+	X? (
+		x11-base/xwayland
+		x11-libs/libxcb:=
+		x11-libs/xcb-util-wm
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+	sys-kernel/linux-headers
+"
+
+BDEPEND="
+	>=dev-build/meson-0.60.0
+	>=dev-libs/wayland-protocols-1.32
+	>=dev-util/wayland-scanner-1.23
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature X xwayland)
+		$(meson_use asan)
+	)
+
+	meson_src_configure
+}