x11-apps/lightdm-gtk-greeter-settings: enable py3.11

Closes: https://bugs.gentoo.org/897670
Closes: https://bugs.gentoo.org/850337
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

x11-apps/lightdm-gtk-greeter-settings/lightdm-gtk-greeter-settings-1.2.2-r1.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg
+
+DESCRIPTION="Configuration tool for the LightDM GTK Greeter"
+HOMEPAGE="https://github.com/xubuntu/lightdm-gtk-greeter-settings"
+SRC_URI="https://github.com/Xubuntu/${PN}/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="xfce"
+
+RDEPEND="
+	dev-libs/glib:2
+	x11-libs/gtk+:3[introspection]
+	x11-libs/pango[introspection]
+	x11-misc/lightdm-gtk-greeter
+	xfce? ( xfce-base/xfce4-settings )
+	$(python_gen_cond_dep '
+		dev-libs/gobject-introspection[${PYTHON_SINGLE_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/python-distutils-extra[${PYTHON_USEDEP}]
+	')
+"
+
+python_configure_all() {
+	if use xfce; then
+		DISTUTILS_ARGS=( --xfce-integration )
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+	rm -r "${ED}/usr/share/doc/${PN}" || die
+}

x11-apps/lightdm-gtk-greeter-settings/lightdm-gtk-greeter-settings-1.2.2.ebuild

@@ -1,45 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-
-DISTUTILS_SINGLE_IMPL=1
-inherit distutils-r1 xdg-utils
-
-DESCRIPTION="Configuration tool for the LightDM GTK Greeter"
-HOMEPAGE="https://github.com/xubuntu/lightdm-gtk-greeter-settings"
-SRC_URI="https://github.com/Xubuntu/${PN}/releases/download/${P}/${P}.tar.gz"
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64"
-RESTRICT="mirror"
-IUSE="xfce"
-RDEPEND="x11-misc/lightdm-gtk-greeter
-		xfce? ( xfce-base/xfce4-settings )"
-BDEPEND="dev-python/python-distutils-extra"
-
-python_configure_all() {
-	if use xfce; then
-		DISTUTILS_ARGS=( --xfce-integration )
-	fi
-}
-
-src_install() {
-	distutils-r1_src_install
-	python_optimize
-}
-
-pkg_preinst() {
-	rm -r "${D}/usr/share/doc/${PN}"
-}
-
-pkg_postinst() {
-	xdg_desktop_database_update
-	xdg_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-	xdg_icon_cache_update
-}