gui-apps/noctalia: add 5.0.0_beta1

Signed-off-by: dsaf <ghostyn678+git@gmail.com>

gui-apps/noctalia/noctalia-5.0.0_beta1.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature xdg
+
+MY_PV="${PV/_/-}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="A lightweight Wayland shell and bar built directly on Wayland + OpenGL ES"
+HOMEPAGE="https://noctalia.dev/ https://github.com/noctalia-dev/noctalia"
+
+SRC_URI="https://github.com/noctalia-dev/noctalia/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+
+IUSE="+jemalloc"
+
+DEPEND="
+	dev-cpp/sdbus-c++
+	dev-libs/glib:2
+	jemalloc? ( dev-libs/jemalloc:= )
+	dev-libs/libxml2
+	dev-libs/wayland
+	gnome-base/librsvg:2
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/libwebp
+	media-libs/mesa
+	media-video/pipewire
+	net-misc/curl
+	sci-libs/libqalculate
+	sys-auth/polkit
+	sys-libs/pam
+	virtual/opengl
+	x11-libs/cairo[glib]
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	dev-cpp/tomlplusplus
+	dev-libs/md4c
+"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="
+	dev-libs/wayland
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+"
+
+DOCS=( {README,CREDITS}.md example.toml )
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature jemalloc)
+		-Dsystem_md4c=true
+		-Dsystem_tomlplusplus=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "external display brightness control" app-misc/ddcutil
+	optfeature "hardware-accelerated screen recording" media-video/gpu-screen-recorder
+}

gui-apps/noctalia/noctalia-5.0.0_pre99999999.ebuild

@@ -3,7 +3,7 @@
 
 EAPI=8
 
-inherit meson optfeature git-r3 xdg-utils
+inherit meson optfeature git-r3 xdg
 
 DESCRIPTION="A lightweight Wayland shell and bar built directly on Wayland + OpenGL ES"
 HOMEPAGE="https://noctalia.dev/ https://github.com/noctalia-dev/noctalia"
@@ -47,7 +47,7 @@ BDEPEND="
 	dev-util/wayland-scanner
 "
 
-DOCS=( README.md CREDITS.md example.toml )
+DOCS=( {README,CREDITS}.md example.toml )
 
 src_configure() {
 	local emesonargs=(
@@ -59,7 +59,8 @@ src_configure() {
 }
 
 pkg_postinst() {
-	xdg_icon_cache_update
+	xdg_pkg_postinst
+
 	optfeature "external display brightness control" app-misc/ddcutil
 	optfeature "hardware-accelerated screen recording" media-video/gpu-screen-recorder
 }