media-sound/yandex-music: 5.94.0 version bump

Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru>
2026-10-12 17:51:11 -04:00 · 2026-04-02 20:48:30 +03:00
1 parent 5fba16378c
commit e16af1087b
@@ -4,3 +4,4 @@ DIST Yandex_Music_amd64_5.90.0.deb 93754898 BLAKE2B 013327c8b6a539549d416e2dffda
 DIST Yandex_Music_amd64_5.91.1.deb 93752812 BLAKE2B 133bfd55755a369885b4fbfdbbf2b61867178699833480f995f7f06310e64fa2e076608e35275a9584d055ba15a898c9e1b3f922d936b5192213ad1f6b720a0e SHA512 bb2da80f1f5b1b2726b40ed8663eacd923ee614a6f273de938fd2384bb8c21b20b5fed9e0f1ad53f6c81c6517f3481112a9e77f9b74001fe3f167034b3bfa6af
 DIST Yandex_Music_amd64_5.92.1.deb 93767688 BLAKE2B 2ac087ff2a3a4932d7d269839ebf58921baa9447c379acb244855634bf50ea8c6106ca9fcaddc0aa85c1f9da7436e2b885dec0781e99ebbf37ff3c9962a5cccd SHA512 b3c29b1bd03ffe6573ea898612e4333a5e2a5482d61983b685e6ca7d594cadb2ec91642f6372e3c9f8ae5a13d1675f877e294dab9e5b919111da6249ca901cac
 DIST Yandex_Music_amd64_5.93.1.deb 93791660 BLAKE2B 59b3f9d398c4a6c8641642d99fcbe9a2f009ad1289dcb68081c1e9fa02a6bd085b5fd33d8a5c2f624805284e179ad5e6e6e7198c1278c1c4c89761c81c42b4e2 SHA512 68ed135c6651964bb7a1448911e77e1c33304658785d5739a0919923b169cf824f7dedd1366a362a3b8d98cc5c1a62de263ac5eaf1e0556a59900f1c51158b4a
+DIST Yandex_Music_amd64_5.94.0.deb 93795704 BLAKE2B ad29afe8f65b78c91d8070f7cfa4cf16630dbc7160c706c5af09babc0aa9fe4dee140d6fa57946e92c2fe1cac22f75bd6dd1bbdc2c90f58609ea1a0cac22e153 SHA512 24277e5e7cfb7fa59c5b22a58396756d71eb7740bd68e899e82e818c1f36f76ffdb8b9e62410cc0963e563ee5c6b5b56175a3950480d5ebcb02d3ec9f9f21cfd
@@ -0,0 +1,129 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi fil fr gu he hi hr hu id it ja kn ko \
+lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+inherit chromium-2 pax-utils wrapper unpacker xdg
+
+MY_PN="${PN/-/}"
+
+DESCRIPTION="Yandex Music streaming service"
+HOMEPAGE="https://music.yandex.ru/"
+SRC_URI="
+	amd64? ( https://music-desktop-application.s3.yandex.net/stable/Yandex_Music_amd64_${PV}.deb )
+"
+
+S="${WORKDIR}"
+
+LICENSE="Yandex-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-core
+	app-arch/bzip2
+	dev-libs/expat
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/gmp
+	dev-libs/libffi
+	dev-libs/libpcre2
+	dev-libs/libtasn1
+	dev-libs/libunistring
+	dev-libs/nettle
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-gfx/graphite2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz
+	media-libs/libepoxy
+	media-libs/libjpeg-turbo
+	media-libs/libpng
+	media-libs/mesa
+	net-dns/libidn2
+	net-libs/gnutls
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/systemd-utils
+	sys-apps/util-linux
+	sys-devel/gcc
+	sys-libs/glibc
+	sys-libs/libcap
+	virtual/zlib
+	x11-libs/cairo[X,glib]
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango[X]
+	x11-libs/pixman
+"
+DEPEND="
+	>=dev-util/patchelf-0.9
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/yandex-music.*\\.desktop"
+YANDEX_HOME="opt/${PN}"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	unpack_deb ${A}
+	mv -T "${S}/opt/Яндекс Музыка" "${S}/${YANDEX_HOME}" || die
+	mv -T "${S}/usr/share/doc/${MY_PN}" "${S}/usr/share/doc/${PF}" || die
+}
+
+src_prepare() {
+	default
+	sed -i -e "s|/opt/Яндекс Музыка/${MY_PN}|/opt/bin/${PN}|" -i -e "s/Audio;/AudioVideo;/" \
+		"${S}/usr/share/applications/${MY_PN}.desktop" || die
+
+	sed -i -e "s|/opt/Яндекс Музыка|/${YANDEX_HOME}|" "${S}/${YANDEX_HOME}"/resources/apparmor-profile || die
+
+	gunzip "usr/share/doc/${PF}/changelog.gz" || die "Failed to decompress docs"
+
+	rm "${S}/${YANDEX_HOME}"/resources/app-update.yml || die
+
+	pushd "${YANDEX_HOME}/locales" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/chrome-sandbox" || die "Failed to fix library rpath (chrome-sandbox)"
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/${MY_PN}" || die "Failed to fix library rpath (yandexmusic)"
+}
+
+src_install() {
+	insinto /opt
+	doins -r opt/*
+
+	insinto /usr
+	doins -r usr/*
+
+	make_wrapper ${PN} "/${YANDEX_HOME}/${MY_PN}" "" "/${YANDEX_HOME}" "/opt/bin/"
+
+	fowners root:root "/${YANDEX_HOME}/${MY_PN}"
+	fperms 4711 "/${YANDEX_HOME}/chrome-sandbox"
+	pax-mark m "${ED}${YANDEX_HOME}/chrome-sandbox"
+	fperms 755 "/${YANDEX_HOME}/${MY_PN}"
+}