app-crypt/certbot-dns-rfc2136: add 2.8.0

Signed-off-by: Thibaud CANALE <thican@thican.net>

app-crypt/certbot-dns-rfc2136/Manifest

@@ -2,3 +2,4 @@ DIST certbot-2.6.0.gh.tar.gz 1336339 BLAKE2B 0c0575ad553ebe0f3ab56da750572bca46b
 DIST certbot-2.7.2.gh.tar.gz 1343827 BLAKE2B 83fade55e9ea348b5a0fb10ab425f1d23ef6f4e8d43e7c762e363230548ede061ace66cbc49212cca1262809bcf046703859b80a93d698b7ffc545ff16f56bf5 SHA512 bb82a6f6f8d4042e598f9b4b583fd3ea3128026f41acbacb9ee932b195522e565eaddf7ae8d6a661cab5e2f15a436e234f36e0388c730844bff40a3f982a45ee
 DIST certbot-2.7.3.gh.tar.gz 1344285 BLAKE2B b32a57c5a13cb1dac474f291eba17c51abe11455455d9831d88c77e0559e9c76b78da2e4dc14165dc892c61b901713687e72657504947ca810c9c139038fe4f0 SHA512 6251f7c3062fcac5b13df94d70c5bcf72e541da4f1dd73a3cc3198fbab050cc3e584fc8ccae9819435896c1d2d2df372ce7465ef571592896afcfee473148f0c
 DIST certbot-2.7.4.gh.tar.gz 1345476 BLAKE2B 9050765a345ab1195edbf6f0194b9442f64d468f34d26a6ec780901850835ce488d235b72d0a4d5079f29b433454b2bd24e1c0b2001e136216734e353f3627d9 SHA512 4363a2b9cc0d80692c26b6e4e82d7b2f1b57145f82603d33591cc6d00f08a920a2f9b963268c9a24211492e570fc8a91a1c64ccbcd4a44068e30590ce0a1d369
+DIST certbot-2.8.0.gh.tar.gz 1344483 BLAKE2B f9957367ae65f69ab43a83993b29da4d28c0d01bd7a89ebefcbfb82915c26167b7443d08f6ee4d28e029f5a58736dee01700a30261aaa1dc0290273868da08e9 SHA512 2fbaf5349e7ef0dcb054c3b22d63007c588cbdc0d23d484a56e62ad38d21c91b838887e6e94cf9c0045a4382567c342288a796c81307deba84a246f5cc3bc5d6

app-crypt/certbot-dns-rfc2136/certbot-dns-rfc2136-2.8.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+PARENT_PN="${PN%-dns-rfc2136}"
+PARENT_P="${PARENT_PN}-${PV}"
+
+if [[ "${PV}" == *9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/certbot/certbot.git"
+	EGIT_SUBMODULES=()
+	EGIT_CHECKOUT_DIR="${WORKDIR}/${PARENT_P}"
+else
+	SRC_URI="
+		https://github.com/certbot/certbot/archive/v${PV}.tar.gz
+			-> ${PARENT_P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="RFC 2136 DNS Authenticator plugin for Certbot (Let’s Encrypt client)"
+HOMEPAGE="
+	https://github.com/certbot/certbot
+	https://letsencrypt.org/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+S="${WORKDIR}/${PARENT_P}/${PN}"
+
+BDEPEND="
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=app-crypt/acme-${PV}[${PYTHON_USEDEP}]
+	>=app-crypt/certbot-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/dnspython-1.15.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+# Same than PATCHES but from repository's root directory,
+# please see function `python_prepare_all` below.
+# Simplier for users IMHO.
+PARENT_PATCHES=(
+)
+
+# Here for patches within "${PN}" subdirectory.
+PATCHES=(
+)
+
+python_prepare_all() {
+	pushd "${WORKDIR}/${PARENT_P}" > /dev/null || die
+	[[ -n "${PARENT_PATCHES[@]}" ]] && eapply "${PARENT_PATCHES[@]}"
+	eapply_user
+	popd > /dev/null || die
+
+	distutils-r1_python_prepare_all
+}