mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-07-10 15:45:15 -04:00
phosh-base/phosh-shell: add 0.40.0
Closes: https://bugs.gentoo.org/933129 Closes: https://bugs.gentoo.org/927033 Closes: https://bugs.gentoo.org/928366 Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
This commit is contained in:
Anna (cybertailor) Vyalkova
@@ -2,3 +2,5 @@ DIST phosh-0.36.0.tar.xz 839440 BLAKE2B a6aa1c6fc2356055b0a451cb66fcfcbf3329059a
|
||||
DIST phosh-0.36.0.tar.xz.asc 833 BLAKE2B 1dcdfd6cd0708f60408a34bd2df891db4050de02c9349d5517fe23b2e17e0fb0fdfe97e3f86f5b30fb47c871932bd67310b889ce4d03b32408c7704d7ea31ce4 SHA512 c1ceac2eaad073b79f342915205f0539454f789eb6cb8aaae5fa4847bfac60641822796ee0adc83970af7ee6d6e57248bba48a718a05da1d2123984c4a3c9b91
|
||||
DIST phosh-0.38.0.tar.xz 866816 BLAKE2B 22be8e8a673494da7795270d7fb7fff2bfb87762b8cce9540d2f8644ded760ee2ac8a75d8052eb46172d6f5764e020ef949330ed14f5cc645cef586e26b5a398 SHA512 dfde54b64ea6edba2b66dfe2f5ff0f4b3edbb192b1a37fbc8c98d9365bdedc5d19ddb1464673e516cb8e436a6c0ea00c84087cc6431b6c1862019f90e02b73ce
|
||||
DIST phosh-0.38.0.tar.xz.asc 833 BLAKE2B d9c49a42bc5083678e3195eb6fded80455312887b0c0f99dd03c6662d3c01bec228b0c68f7044dfe86fe1473b8ddbaf797729a5a92fbbbb5c8d18302149376dd SHA512 8007c2f58c311659310d06962ad825c51fb90f4da864f110db5b1f0f5d7c70b0ef69ddbfa169489657b3088ed6b89dbdf7e910101267ccd307578d75f9301b46
|
||||
DIST phosh-0.40.0.tar.xz 910888 BLAKE2B 9bf1da29af73387b4f080f580dc29422d6f113c19b52c72596bcf2dd1f3e4e61da4270f3798f07148f8a197f8b076b67e51108c08af503c0a4a5566c8ef13669 SHA512 e82e1955b708f01827f5ce8e31cd5b6449e66b527dd9a1bc6300a70c6c90ccffa14ae9d569bfa8627f995d96437ef4d063e7ebd7e20556a273dc75902a1e9538
|
||||
DIST phosh-0.40.0.tar.xz.asc 833 BLAKE2B e45a7726d4f94cabd98f36d9de2c870d51a480f8b4b10f1ea046fa4cffbef165caf3c701892a7cd80e63753fc791556da854dfd24c8f80bd70b2a19ce63c9508 SHA512 9bb24e6f0ccf3534a9a28711e82b5aa8b2a10bcbe3b99b7d7329476ed2916b53ce9dc31c0c06aaec7d67370bc05dc35199da60f191d6706bb636f7a6b7ecffb8
|
||||
|
||||
145
phosh-base/phosh-shell/phosh-shell-0.40.0.ebuild
Normal file
145
phosh-base/phosh-shell/phosh-shell-0.40.0.ebuild
Normal file
@@ -0,0 +1,145 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit gnome2-utils meson pam systemd verify-sig virtualx xdg
|
||||
|
||||
MY_PN="${PN%-shell}"
|
||||
MY_P="${MY_PN}-${PV}"
|
||||
DESCRIPTION="Pure Wayland shell for mobile devices"
|
||||
HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phosh/"
|
||||
SRC_URI="https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz
|
||||
verify-sig? ( https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz.asc )"
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
LICENSE="CC0-1.0 CC-BY-SA-4.0 GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+ MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64"
|
||||
IUSE="elogind gtk-doc introspection +lockscreen-plugins man test test-full"
|
||||
REQUIRED_USE="
|
||||
gtk-doc? ( introspection )
|
||||
test? ( lockscreen-plugins )
|
||||
"
|
||||
|
||||
COMMON_DEPEND="
|
||||
>=app-crypt/gcr-3.7.5:0[introspection?]
|
||||
app-crypt/libsecret
|
||||
>=dev-libs/feedbackd-0.2.0
|
||||
dev-libs/fribidi
|
||||
>=dev-libs/glib-2.76:2
|
||||
dev-libs/gmobile
|
||||
dev-libs/libgudev:=
|
||||
dev-libs/libical:=
|
||||
>=dev-libs/wayland-1.14
|
||||
>=gnome-base/gnome-desktop-3.26:3
|
||||
>=gnome-base/gsettings-desktop-schemas-42
|
||||
>=gnome-extra/evolution-data-server-3.33.1:=
|
||||
>=gui-libs/libhandy-1.1.90:1[introspection?]
|
||||
media-libs/libpulse[glib]
|
||||
media-sound/callaudiod
|
||||
net-libs/libsoup:3.0
|
||||
>=net-misc/networkmanager-1.14[introspection?]
|
||||
sys-apps/dbus
|
||||
>=sys-auth/polkit-0.105
|
||||
sys-libs/pam
|
||||
>=sys-power/upower-0.99.1:=
|
||||
x11-libs/cairo
|
||||
x11-libs/gdk-pixbuf
|
||||
x11-libs/pango
|
||||
>=x11-libs/gtk+-3.22:3[introspection?,wayland]
|
||||
elogind? ( >=sys-auth/elogind-241 )
|
||||
!elogind? ( >=sys-apps/systemd-241:= )
|
||||
lockscreen-plugins? (
|
||||
app-text/evince:=
|
||||
gui-libs/gtk:4
|
||||
gui-libs/libadwaita:1
|
||||
)
|
||||
"
|
||||
RUNTIME_DEPEND="
|
||||
gnome-base/gnome-shell
|
||||
virtual/freedesktop-icon-theme
|
||||
x11-themes/gnome-themes-standard
|
||||
"
|
||||
|
||||
DEPEND="
|
||||
${COMMON_DEPEND:?}
|
||||
>=dev-libs/wayland-protocols-1.12
|
||||
test-full? ( ${RUNTIME_DEPEND:?} )
|
||||
"
|
||||
RDEPEND="
|
||||
${COMMON_DEPEND:?}
|
||||
${RUNTIME_DEPEND:?}
|
||||
!elogind? ( sys-libs/libcap )
|
||||
"
|
||||
BDEPEND="
|
||||
dev-libs/glib:2
|
||||
dev-libs/libxml2
|
||||
dev-util/gdbus-codegen
|
||||
dev-util/glib-utils
|
||||
dev-util/wayland-scanner
|
||||
sys-devel/gettext
|
||||
gtk-doc? ( dev-util/gi-docgen )
|
||||
man? ( dev-python/docutils )
|
||||
test-full? ( >=gui-wm/phoc-0.36.0-r1 )
|
||||
verify-sig? ( sec-keys/openpgp-keys-phosh )
|
||||
"
|
||||
|
||||
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
-Dcompositor="${EPREFIX}"/usr/bin/phoc
|
||||
-Dtools=true
|
||||
-Dquick-setting-plugins=true
|
||||
$(meson_use gtk-doc gtk_doc)
|
||||
$(meson_use introspection)
|
||||
$(meson_use lockscreen-plugins)
|
||||
$(meson_use man)
|
||||
$(meson_use test tests)
|
||||
$(meson_feature test-full phoc_tests)
|
||||
)
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
local -x LC_ALL="C.UTF-8"
|
||||
local -x WLR_RENDERER="pixman"
|
||||
|
||||
virtx meson_src_test --suite unit
|
||||
if use test-full; then
|
||||
virtx meson_src_test --suite integration
|
||||
fi
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
pamd_mimic system-local-login phosh auth account session
|
||||
systemd_douserunit data/phosh.service
|
||||
|
||||
if use gtk-doc; then
|
||||
mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
|
||||
mv "${ED}"/usr/share/doc/${MY_PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
|
||||
fi
|
||||
}
|
||||
|
||||
phosh_giomodule_cache_update() {
|
||||
local plugins_dir
|
||||
plugins_dir=$(pkg-config --variable=lockscreen_plugins_dir phosh-plugins) || return 1
|
||||
|
||||
ebegin "Updating GIO modules cache"
|
||||
gio-querymodules "${plugins_dir}"
|
||||
eend $?
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
gnome2_schemas_update
|
||||
phosh_giomodule_cache_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_pkg_postrm
|
||||
gnome2_schemas_update
|
||||
phosh_giomodule_cache_update
|
||||
}
|
||||
Reference in New Issue
Block a user