media-gfx/swayimg: Bump to 4.3

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>

media-gfx/swayimg/Manifest

@@ -1,2 +1,3 @@
 DIST swayimg-4.1.tar.gz 772139 BLAKE2B f20aca21800510f348f0cff3ee9d2c1a176f746b0e75f3b39147d1cee23ef54454ee618120c87d9649fde0bb0565ed2462bdc148b107c6eaf026d94cd8d7f3ad SHA512 0cce9c60bba1daa85776d155a656f7d3988a4e8fd5fa8f461c1bec00c800fdf6a51f6a18212042f61e324d45936434988d60e80bf03f237172d9a159e3e52153
 DIST swayimg-4.2.tar.gz 778261 BLAKE2B 58a0fc1b70c7218493d499d224fd32bfcd4083515060ae6d5ec40225f127a0cc9115dff9237f90e12fb46ac66f110d7003edf8ea13218d7b5e631074c8d30f76 SHA512 6496591410ddadd4569c51e12b92d32f83b233b055212a50c861facb30cc7fe5c58c8b4e4955ae862086ed3d06f014fcc657fb8ba112b3bbfb287dc1e3ec3852
+DIST swayimg-4.3.tar.gz 785384 BLAKE2B 1d341b92865436b7cb1393e719a2e5fa3a69200a7cc4e2b0ce0d07564578245835951fd70bb186b3defaffc7765962694db8d73fa97b3721c2e2e992b7f6c38d SHA512 cdd9ee386fdc63f136ec91aa2750ffb67eb6b5a8b6751f75b7947a1793814d1ba81973ad7db19316d496cd6a355fc6288c326a042e8fe7f410e2a2346b2c6b57

media-gfx/swayimg/swayimg-4.3.ebuild

@@ -0,0 +1,83 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="A lightweight image viewer for Wayland display servers"
+HOMEPAGE="https://github.com/artemsen/swayimg"
+SRC_URI="https://github.com/artemsen/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="avif bash-completion exif exr gif heif jpeg jpegxl png raw sixel svg test tiff +wayland webp X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/wayland
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/libxkbcommon
+	avif? ( media-libs/libavif:= )
+	bash-completion? ( app-shells/bash-completion )
+	exif? ( media-libs/libexif )
+	exr? ( media-libs/openexr:= )
+	gif? ( media-libs/giflib:= )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( media-libs/libjxl:= )
+	png? ( media-libs/libpng:= )
+	raw? ( media-libs/libraw:= )
+	sixel? ( media-libs/libsixel )
+	svg? (
+		dev-libs/glib:2
+		gnome-base/librsvg:2
+		x11-libs/cairo[X=]
+	)
+	tiff? ( media-libs/tiff:= )
+	wayland? ( dev-libs/json-c:= )
+	webp? ( media-libs/libwebp:= )
+"
+DEPEND="${RDEPEND}
+	dev-libs/wayland-protocols
+	svg? ( X? ( x11-base/xorg-proto ) )
+"
+BDEPEND="
+	dev-util/wayland-scanner
+	test? ( dev-cpp/gtest )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature avif)
+		$(meson_feature exif)
+		$(meson_feature exr)
+		$(meson_feature gif)
+		$(meson_feature heif)
+		$(meson_feature jpeg)
+		$(meson_feature jpegxl jxl)
+		$(meson_feature png)
+		$(meson_feature raw)
+		$(meson_feature sixel)
+		$(meson_feature svg)
+		$(meson_feature test tests)
+		$(meson_feature tiff)
+		$(meson_feature wayland compositor)
+		$(meson_feature webp)
+		$(meson_feature bash-completion bash)
+		-Dversion=${PV}
+		-Ddesktop=true
+		# avoid automagic building with scdoc
+		-Dman=false
+		-Dzsh=enabled
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	doman extra/*.{1,5}
+}