gui-apps/yambar: add 1.7.0

Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Leonardo Neumann <leonardo@neumann.dev.br>

gui-apps/yambar/Manifest

@@ -1 +1,2 @@
 DIST yambar-1.6.2.tar.gz 135455 BLAKE2B 71d5b584bf04a7212ac84d8e0d8cb71c1abd7c7548c5ec998aff480d76afbd09825b059fe642edd4dd2537af6a5b811bd333a45bfa53f6a3a814a2be95eb58b4 SHA512 64a5e983be6dc99feb2f39d06fe265163c3b8f3f23f33a58c386891b63a9c915816cbde22d031473e700e839522c86c53b06f0cce1a57ebdab8ed6aeebe627e1
+DIST yambar-1.7.0.tar.gz 148762 BLAKE2B a394b588bb1a8c64e149f8f39d6a8056d139cb3518fc15c87db0da7ead9c96ce5d7b9d764a617c4626d9fa574edbda2c0e1e2b11b07741241188c5cd282d5643 SHA512 e34cc808533cf76ff0b95d18346b796b4758271b0a61151e80b33eaa0ce34c2d5a9f1c6671d28f377d1563a7979c5784782b9f2f87a3cb615efb129e89865ad3

gui-apps/yambar/yambar-1.7.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="https://codeberg.org/dnkl/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/${PN}.git"
+fi
+
+DESCRIPTION="Simplistic and highly configurable status panel for X and Wayland"
+HOMEPAGE="https://codeberg.org/dnkl/yambar"
+LICENSE="MIT"
+SLOT="0"
+IUSE="wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+RDEPEND="
+	>=media-libs/fcft-2.4.0
+	dev-libs/json-c
+	dev-libs/libyaml
+	media-libs/alsa-lib
+	media-libs/libmpdclient
+	virtual/libudev:=
+	x11-libs/pixman
+	wayland? ( dev-libs/wayland )
+	X? (
+		x11-libs/libxcb:0=[xkb]
+		x11-libs/xcb-util
+		x11-libs/xcb-util-cursor
+		x11-libs/xcb-util-wm
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/tllist-1.0.1
+	>=dev-util/meson-0.53.0
+	virtual/pkgconfig
+	wayland? (
+		dev-libs/wayland-protocols
+		dev-util/wayland-scanner
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature wayland backend-wayland)
+		$(meson_feature X backend-x11)
+		-Dwerror=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${D}/usr/share/doc/${PN}"
+}