dev-ml/happy-eyeballs: initial import

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

dev-ml/happy-eyeballs/Manifest

@@ -0,0 +1 @@
+DIST happy-eyeballs-0.3.0.tar.gz 11378 BLAKE2B 186e3f448ee8f04de79dc48c2f1c6d31218a2d48a5d18377265972a8b2269ba85563ad06d0cf2595812ecacf5f5a7baadaccad6e3f12a9b67ba8e4547e74d271 SHA512 a2c38dd618df585e3de446674e0675668da85fa17c0e285bb174b3d23b38bdedae45e0c740f261d0f4e091a14cd32eb2f2b209a7f8c7f9a957fce18e1dcbf63f

dev-ml/happy-eyeballs/happy-eyeballs-0.3.0.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune multiprocessing
+
+DESCRIPTION="An implementation of happy eyeballs (RFC 8305) in OCaml with lwt"
+HOMEPAGE="https://github.com/roburio/happy-eyeballs"
+SRC_URI="https://github.com/roburio/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="lwt mirage ocamlopt"
+
+RDEPEND="
+	dev-ml/domain-name
+	dev-ml/ipaddr
+	dev-ml/logs
+	dev-ml/fmt
+
+	lwt? (
+		dev-ml/cmdliner
+		dev-ml/mtime
+		dev-ml/lwt
+		dev-ml/dns[client]
+		dev-ml/duration
+	)
+	mirage? (
+		dev-ml/mirage-clock
+		dev-ml/dns[client]
+		dev-ml/lwt
+		dev-ml/tcpip
+		dev-ml/mirage-random
+		dev-ml/mirage-time
+		dev-ml/duration
+	)
+"
+DEPEND="${RDEPEND}"
+
+src_compile() {
+	local pkgs="happy-eyeballs"
+	for u in lwt mirage ; do
+		if use ${u} ; then
+			pkgs="${pkgs},happy-eyeballs-${u}"
+		fi
+	done
+	dune build --only-packages "${pkgs}" -j $(makeopts_jobs) --profile release || die
+}
+
+src_install() {
+	dune_src_install happy-eyeballs
+	for u in lwt mirage ; do
+		if use ${u} ; then
+			dune_src_install "happy-eyeballs-${u}"
+		fi
+	done
+}

dev-ml/happy-eyeballs/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+   <maintainer type="person">
+        <email>lssndrbarbieri@gmail.com</email>
+        <name>Alessandro Barbieri</name>
+    </maintainer>
+    <upstream>
+        <remote-id type="github">roburio/happy-eyeballs</remote-id>
+    </upstream>
+    <use>
+        <flag name="lwt">Connecting to a remote host via IP version 4 or 6 using Lwt_unix</flag>
+        <flag name="mirage">Connecting to a remote host via IP version 4 or 6 using Mirage</flag>
+    </use>
+</pkgmetadata>