app-text/komikku: add 1.84.0

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

app-text/komikku/Manifest

@@ -1 +1,2 @@
 DIST komikku-1.78.0.tar.gz 4435738 BLAKE2B b5b489b2c8adf7f49d405d4ca61245b974992559c4de4bf60bfed2e62396b80ddf43b3a7a2f33cd0fe9050dfc0c1257bd5348f24d18bb51bbdbe688ed929cf7f SHA512 07b1a5888f105e36636ed5c2b9ba4518d0beb1464e35c5706e145d1f0c2eaebd43c4af4aa39f632db2d85ec52389a747a90eb6ef42ad955115684e6651db9e84
+DIST komikku-1.84.0.tar.gz 4488581 BLAKE2B b76b3e3271eda7663527fc16ab1f5ffe078ea64c1d93c92cf07853cd94d7e2e6b55638bc600de25c0bedcfa0b4854e6531d3d34238282897b8a12f9a4deee893 SHA512 ecfb305eafda5295ad345428b6192dc0f60e88b9a9fc33efa73d415f65b74f0ee9d01dd9a45130bd47708148234843ab09e36e94afa82d2a61723257995f288b

app-text/komikku/komikku-1.84.0.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="CC0-1.0 CC-BY-4.0 GPL-3+ OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.7:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/modern-colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		>=dev-python/pillow-11.3.0[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+"
+
+EPYTEST_PLUGINS=( pytest-steps )
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}