dev-python/pytest-vcr: initial import

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/pytest-vcr/Manifest

@@ -0,0 +1 @@
+DIST pytest-vcr-1.0.2.tar.gz 9281 BLAKE2B dc12d9a2fda156e072c32c5b08b2b35549398ed4372f9c8c17cd086b83286e78cce98f1aa54b3db21883dda84f379facb477442fa0f411532be4bdbc498ea1e1 SHA512 29dceb51092d73f2190b89e82e88b59506591a35cfe4f141bb877c05420d67a8ab2f21f63c2630972c35697d01b242891917d1be19b14fdfa810c1799f8542c2

dev-python/pytest-vcr/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">pytest-vcr</remote-id>
+		<remote-id type="github">ktosiek/pytest-vcr</remote-id>
+		<maintainer>
+			<email>tomasz.kontusz@gmail.com</email>
+			<name>Tomasz Kontusz</name>
+		</maintainer>
+	</upstream>
+</pkgmetadata>

dev-python/pytest-vcr/pytest-vcr-1.0.2.ebuild

@@ -0,0 +1,41 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DOCS_BUILDER="mkdocs"
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 docs
+
+DESCRIPTION="Plugin for managing VCR.py cassettes"
+HOMEPAGE="
+	https://pypi.org/project/pytest-vcr/
+	https://github.com/ktosiek/pytest-vcr
+"
+SRC_URI="https://github.com/ktosiek/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/pytest[${PYTHON_USEDEP}]
+	dev-python/vcrpy[${PYTHON_USEDEP}]
+"
+
+DOCS=( docs README.rst )
+
+EPYTEST_DESELECT=( tests/test_vcr.py::test_no_warnings )
+
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# pytest.config was removed in >=dev-python/pytest-5.0
+	sed "/pytest.config/d" -i tests/test_vcr.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	docs_compile
+}