net-im/flare: new package, add 0.12.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

net-im/flare/Manifest

@@ -0,0 +1 @@
+DIST flare-0.12.0.tar.xz 56592956 BLAKE2B 7dfd32cf1af0a3a35032b09a702be0fcc4e1f583a0e189eb84bc8ae410b29757eaf84b53f164bf5b17b9ec9178ddd2ef0e9b6fd92ef89335dfc62ec52bd21cc1 SHA512 c2136be40f72a58a20b7fc4e79384365a10f47079cb02a1e161d0200f8cb4a224c63b976865b6b7f377f52b85178eb85c956d3b4f28bc7cb87ad2a4b87219c56

net-im/flare/flare-0.12.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson xdg
+
+PKG_ID=112823190
+DESCRIPTION="Chat with your friends on Signal"
+HOMEPAGE="
+	https://mobile.schmidhuberj.de/flare
+	https://gitlab.com/schmiddi-on-mobile/flare
+"
+SRC_URI="https://gitlab.com/schmiddi-on-mobile/${PN}/-/package_files/${PKG_ID}/download -> ${P}.tar.xz"
+BUILD_DIR="${S}/build"
+
+LICENSE="AGPL-3"
+# Dependent crate licenses
+LICENSE+="
+	|| ( 0BSD Apache-2.0 MIT )
+	|| ( Apache-2.0 Apache-2.0-with-LLVM-exceptions MIT )
+	|| ( Apache-2.0 BSD MIT )
+	|| ( Apache-2.0 BSD-1 MIT )
+	|| ( Apache-2.0 Boost-1.0 )
+	|| ( Apache-2.0 CC0-1.0 )
+	|| ( Apache-2.0 CC0-1.0 MIT-0 )
+	|| ( Apache-2.0 ISC MIT )
+	|| ( Apache-2.0 MIT )
+	|| ( Apache-2.0 MIT ZLIB )
+	|| ( MIT Unlicense )
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD BSD-2 ISC MIT Unicode-DFS-2016 ZLIB openssl
+"
+
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	app-text/libspelling:1
+	>=dev-libs/glib-2.66:2
+	>=gui-libs/gtk-4.12:4[X]
+	gui-libs/gtksourceview:5
+	>=gui-libs/libadwaita-1.4:1
+	media-libs/graphene
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-libs/glib:2
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	virtual/rust
+"
+
+QA_FLAGS_IGNORED="usr/bin/${PN}"
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

net-im/flare/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<name>Julian Schmidhuber</name>
+			<email>schmidhuberj2@protonmail.com</email>
+		</maintainer>
+		<remote-id type="gitlab">schmiddi-on-mobile/flare</remote-id>
+	</upstream>
+</pkgmetadata>