gui-libs/xdg-desktop-portal-hyprland: add 1.3.8

Signed-off-by: Johannes Huber <johu@gmx.de>
Closes: https://github.com/gentoo/guru/pull/255
Signed-off-by: David Roman <davidroman96@gmail.com>

gui-libs/xdg-desktop-portal-hyprland/Manifest

@@ -1 +1,2 @@
 DIST xdg-desktop-portal-hyprland-1.3.3.gh.tar.gz 49323 BLAKE2B 6f0bd6636d1a457d238dbb9095782a41961e30b37eacd05e1a4d545fc933b9d3b529400321a31cfb08c6b5d69279bb8905e84f11743bf97b22587432a5e9cf14 SHA512 c100ca27e9cd430602ad0ea4733f34919d84206df084df0d9f8ed8ca8a634069cc7ef71cb587f92eae6eeedf4029a88644b24b9b8d37138cb544279f5be30720
+DIST xdg-desktop-portal-hyprland-1.3.8.gh.tar.gz 50149 BLAKE2B 72fe8b534dce50f8a01e26660ba16516dc15f078a30fecff885afcbf6e36a6b47aefcb1f4cdbd7952d7bf7f1c89fabfb30f288915fdfa320b29f51a2d38cb2a7 SHA512 71e727c6fea3984f8eac62e5448fc7cf4f57ed28f2620a863578b210d2e0a8fd8882b12b65c5e8d3a3f690ef57206815dbb13a7fed4aab50418df2024d70269d

gui-libs/xdg-desktop-portal-hyprland/xdg-desktop-portal-hyprland-1.3.8.ebuild

@@ -0,0 +1,72 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs
+
+DESCRIPTION="xdg-desktop-portal backend for hyprland"
+HOMEPAGE="https://github.com/hyprwm/xdg-desktop-portal-hyprland"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/hyprwm/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/hyprwm/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	>=media-video/pipewire-1.2.0:=
+	>=dev-cpp/sdbus-c++-2.0.0
+	dev-libs/hyprlang:=
+	dev-libs/inih
+	dev-libs/wayland
+	dev-qt/qtbase:6[gui,widgets]
+	dev-qt/qtwayland:6
+	media-libs/mesa
+	sys-apps/util-linux
+	x11-libs/libdrm
+	|| (
+		systemd? ( >=sys-apps/systemd-237 )
+		elogind? ( >=sys-auth/elogind-237 )
+		sys-libs/basu
+	)
+"
+
+RDEPEND="
+	${DEPEND}
+	sys-apps/xdg-desktop-portal
+"
+
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.24
+	>=dev-util/hyprwayland-scanner-0.4.2
+	dev-libs/hyprland-protocols
+	virtual/pkgconfig
+	|| ( >=sys-devel/gcc-13:* >=sys-devel/clang-17:* )
+"
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} == binary ]] && return
+
+	if tc-is-gcc && ver_test $(gcc-version) -lt 13 ; then
+		eerror "XDPH needs >=gcc-13 or >=clang-17 to compile."
+		eerror "Please upgrade GCC: emerge -v1 sys-devel/gcc"
+		die "GCC version is too old to compile XDPH!"
+	elif tc-is-clang && ver_test $(clang-version) -lt 17 ; then
+		eerror "XDPH needs >=gcc-13 or >=clang-17 to compile."
+		eerror "Please upgrade Clang: emerge -v1 sys-devel/clang"
+		die "Clang version is too old to compile XDPH!"
+	fi
+}
+
+src_prepare() {
+	sed -i "/add_compile_options(-O3)/d" "${S}/CMakeLists.txt" || die
+	cmake_src_prepare
+}