gui-apps/fuzzel: add 1.11.0

Signed-off-by: Jonas Frei <freijon@pm.me>

gui-apps/fuzzel/Manifest

@@ -1,2 +1,3 @@
 DIST fuzzel-1.10.2.tar.gz 440973 BLAKE2B 201d5ac43629ead9f2dcbc55f97e6847ec9c39fc6b8d4c48ad286a0a45c89a685464ea113f04179378d775ffe93ee1dfe4a99cd13b0797df374e6d3948772c0f SHA512 bc2a3780838ae4a68f23cd9c5e240576cb79c8c29fe5a2069628f3763670139d9c19695b55fbc10cf16affcf8527bedcef0524e374d406e698be8c4afb7a2579
+DIST fuzzel-1.11.0.tar.gz 473635 BLAKE2B 046eef81998ab89b710c225f5df79a64d7f5d38d247f9bc2c3efcd569106562d2b66574f1c0f3348b38ff92655f714e07495dc4870dfb8eb97158dd5442452fd SHA512 d52bb149f786a652576bf47f2167dde38d273825a6c59d362fa1f50b29b06da4eb6ca0605df481271e0016eff09aafb40ab61228e51ac93fb7bbe98428bd0c3f
 DIST fuzzel-1.9.2.tar.gz 433292 BLAKE2B 7b0533f7bb705b330e9c5c0fb89831283cc5e349891408d398d26f20c7c78c599ae28c18e92379df8888a8099ec4b7736ea356b6342ff3b1c3fde57085580f23 SHA512 a92f0b6eb9470aa099651c2f5d095986347565bbd7366bffe0719801dbb1ae4f7e413460c59872d40e910bb1d3bc8195e9d9038a73c2de835bcda77f9372b393

gui-apps/fuzzel/fuzzel-1.11.0.ebuild

@@ -0,0 +1,57 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/fuzzel.git"
+else
+	SRC_URI="https://codeberg.org/dnkl/fuzzel/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}"
+fi
+
+DESCRIPTION="Application launcher for wlroots based Wayland compositors."
+HOMEPAGE="https://codeberg.org/dnkl/fuzzel"
+LICENSE="MIT"
+SLOT="0"
+IUSE="png svg"
+
+DEPEND="
+	dev-libs/wayland
+	<media-libs/fcft-4.0.0
+	>=media-libs/fcft-3.0.0
+	media-libs/fontconfig
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	png? ( media-libs/libpng )
+	svg? ( media-libs/nanosvg )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/tllist-1.0.1
+	>=dev-libs/wayland-protocols-1.32
+	dev-util/wayland-scanner
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dpng-backend=$(usex png libpng none)
+		-Dsvg-backend=$(usex svg nanosvg none)
+		$(meson_feature svg system-nanosvg)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/share/doc/fuzzel" || die
+}
+
+pkg_postinst() {
+	optfeature "For rounded corner support" x11-libs/cairo
+}