gui-wm/phoc: add 0.48.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

gui-wm/phoc/Manifest

@@ -2,3 +2,5 @@ DIST phoc-0.46.0.tar.xz 730608 BLAKE2B 51716b99447c0275bdc3af0bd6587c53c240612f6
 DIST phoc-0.46.0.tar.xz.asc 833 BLAKE2B c7f2fe56f4fb085160d968bda21d47574ef4decb145c4e08f6f9b337a28dabaab52efb306eab1e09646420553f49804e58cfe4aed70973c4f83dacee63985edb SHA512 29c67a5b6dbc1420e47ab7853d4c19a255eeaf09c1ef0bc3920e48c74feeae20d864a335e76d71178ab95f27127ad3b2a362ba10d3bad18ad834f4a6527031c7
 DIST phoc-0.47.0.tar.xz 732348 BLAKE2B 1558858760f56bb6a693d261807beae3d30e3c6296a52e42bb73c51963e92a710b13a060a0b87e216fb09899f1ce879518a5110c7c409f43d8e00885b572b92e SHA512 b36c413edea91fa5bde2fb8f7761f2fb9f5ad5f546da4d712dce90a083300e99d902b43e38268a87922870296f705bae8402fc81d95f83f866956cf33ecbf00c
 DIST phoc-0.47.0.tar.xz.asc 833 BLAKE2B 96f0641c5ea0f53154fef331359f0ce8b7f408dddc56270f82397d9d91656f5411c2c712db5733c46f60b5459f8fb140105c301631e4d56817f177c5a8b9d39d SHA512 3eca2f2cc5a208dd6f61a91dbd2c9649078224eee1ba9aa797624c86b2a36872c962a4355b744660b629362ba6cfbe77e855a168867ae5e39456e77051784a82
+DIST phoc-0.48.0.tar.xz 777556 BLAKE2B 8397c25208e4238e0aa8d4c79d18731fa9134ef61ddfc199f370886c01c00899030a24dae1c4717869888ee594c28752d4eb413c1418e81edcc7f049a63e7ed9 SHA512 b643bd5147ec72ca686ba4b5e5e4361ec12156b3d20c7e03a125b8155fc726be03a41f110b40b8ba85c9dcb944171d9f2645a0997f1dba0ca13a66d809a652c9
+DIST phoc-0.48.0.tar.xz.asc 833 BLAKE2B 59565bc75a78fb1e244b52fece6137fb5f76a3ca627e965e96e88eeb4a4293bfd690a5fc137f337e1368c1fefeda62d67aca74e59bca702af6472508cb7c0d32 SHA512 80127601fbb02f59069be4cced006ce6b468f53ace481d293e5cee8015ab86f647a559f3fff2bd2dd19a58cf2985f8148ae718baaf13c4b3dbfb2d32483c0303

gui-wm/phoc/phoc-0.48.0.ebuild

@@ -0,0 +1,119 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson verify-sig virtualx xdg
+
+DESCRIPTION="Wayland compositor for mobile phones"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )
+"
+
+LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc man test"
+RESTRICT="!test? ( test )"
+
+WLROOTS_RDEPEND="
+	>=dev-libs/libinput-1.19.0:=
+	>=dev-libs/libliftoff-0.4
+	>=dev-libs/wayland-1.23.1
+	media-libs/libdisplay-info:=
+	media-libs/libglvnd
+	>=media-libs/mesa-24.1.0_rc1[opengl]
+	media-libs/vulkan-loader
+	sys-apps/hwdata
+	sys-auth/seatd:=
+	x11-base/xwayland
+	x11-libs/cairo
+	>=x11-libs/libdrm-2.4.122
+	x11-libs/libxcb:=
+	>=x11-libs/pixman-0.43.0
+	x11-libs/xcb-util-errors
+	x11-libs/xcb-util-renderutil
+	x11-libs/xcb-util-wm
+	virtual/libudev:=
+"
+WLROOTS_DEPEND="
+	dev-util/vulkan-headers
+	>=x11-libs/libxkbcommon-1.8.0
+"
+WLROOTS_BDEPEND="
+	dev-util/glslang
+"
+
+RDEPEND="${WLROOTS_RDEPEND}
+	>=dev-libs/glib-2.80:2
+	dev-libs/gmobile
+	dev-libs/libinput:=
+	>=dev-libs/wayland-1.23.1
+	>=gnome-base/gnome-desktop-3.26:3=
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/pixman-0.43.4
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+"
+DEPEND="${WLROOTS_DEPEND}
+	${RDEPEND}
+	test? ( x11-wm/mutter )
+"
+BDEPEND="${WLROOTS_BDEPEND}
+	dev-libs/glib:2
+	>=dev-libs/wayland-protocols-1.41
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_prepare() {
+	default
+
+	cd subprojects/wlroots-* || die
+	eapply "${S}"/subprojects/packagefiles/wlroots
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		-Ddefault_library=static
+		-Dembed-wlroots=enabled
+		-Dxwayland=enabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local -x LC_ALL="C.UTF-8"
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install --skip-subprojects wlroots
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+
+	newbin tools/auto-maximize phoc-auto-maximize
+	newbin tools/scale-to-fit phoc-scale-to-fit
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}