gui-wm/phoc: drop 0.48.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

gui-wm/phoc/Manifest

@@ -1,5 +1,3 @@
-DIST phoc-0.48.0.tar.xz 777556 BLAKE2B 8397c25208e4238e0aa8d4c79d18731fa9134ef61ddfc199f370886c01c00899030a24dae1c4717869888ee594c28752d4eb413c1418e81edcc7f049a63e7ed9 SHA512 b643bd5147ec72ca686ba4b5e5e4361ec12156b3d20c7e03a125b8155fc726be03a41f110b40b8ba85c9dcb944171d9f2645a0997f1dba0ca13a66d809a652c9
-DIST phoc-0.48.0.tar.xz.asc 833 BLAKE2B 59565bc75a78fb1e244b52fece6137fb5f76a3ca627e965e96e88eeb4a4293bfd690a5fc137f337e1368c1fefeda62d67aca74e59bca702af6472508cb7c0d32 SHA512 80127601fbb02f59069be4cced006ce6b468f53ace481d293e5cee8015ab86f647a559f3fff2bd2dd19a58cf2985f8148ae718baaf13c4b3dbfb2d32483c0303
 DIST phoc-0.49.0.tar.xz 778512 BLAKE2B e99808c9a1b6c49fc65b959e983fb9bbafa8e00d42e759d43e30ea4f12bdf22f31594c8d846d9d66681b8b3d3dab03cd2a5f28afb514e7ca313051d2bf68346a SHA512 75853ff03a3bd55ba938a21310e2bcb95b6030020f9fcd2d58d55f6c1ba233e771c16e4314b7537e37247b1a7965d884e288765d72de2b0afdda70bc04e42c84
 DIST phoc-0.49.0.tar.xz.asc 833 BLAKE2B e9543a52aa5fa12f6e69131993fe3275a68144a713e4de52a7d85d632a75e48574e04320df87a305ff1c25ac1360d8a4087a90e7f3893f13d9865e6e6161c1a5 SHA512 9632ad05ac42a83ab1942985b580cd569cc8250286616b5df56d526cfbf9aff656672cf3d98fba3606d5448f31a394a816e98b7dcf5f47aeeb7c5156bf234461
 DIST phoc-0.50.0.tar.xz 784008 BLAKE2B 03f49c43512b6d3a36aa813fa766318136d6fc6889886fb005b6725b6bf4f46445907feb066caf6a83f54d01270cdd115538f759d8c13e107ddf574c0784fa63 SHA512 4b33651d0df483a741230192284b3365ba2d42aed60ea77b279ebcc9768fbc0b0ae23f2a386299cb0ebde47f118ee2b9e7381a414d3f37fef3716a34814f9192

gui-wm/phoc/phoc-0.48.0.ebuild

@@ -1,119 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit gnome2-utils meson verify-sig virtualx xdg
-
-DESCRIPTION="Wayland compositor for mobile phones"
-HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
-SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
-	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )
-"
-
-LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-IUSE="gtk-doc man test"
-RESTRICT="!test? ( test )"
-
-WLROOTS_RDEPEND="
-	>=dev-libs/libinput-1.19.0:=
-	>=dev-libs/libliftoff-0.4
-	>=dev-libs/wayland-1.23.1
-	media-libs/libdisplay-info:=
-	media-libs/libglvnd
-	>=media-libs/mesa-24.1.0_rc1[opengl]
-	media-libs/vulkan-loader
-	sys-apps/hwdata
-	sys-auth/seatd:=
-	x11-base/xwayland
-	x11-libs/cairo
-	>=x11-libs/libdrm-2.4.122
-	x11-libs/libxcb:=
-	>=x11-libs/pixman-0.43.0
-	x11-libs/xcb-util-errors
-	x11-libs/xcb-util-renderutil
-	x11-libs/xcb-util-wm
-	virtual/libudev:=
-"
-WLROOTS_DEPEND="
-	dev-util/vulkan-headers
-	>=x11-libs/libxkbcommon-1.8.0
-"
-WLROOTS_BDEPEND="
-	dev-util/glslang
-"
-
-RDEPEND="${WLROOTS_RDEPEND}
-	>=dev-libs/glib-2.80:2
-	dev-libs/gmobile
-	dev-libs/libinput:=
-	>=dev-libs/wayland-1.23.1
-	>=gnome-base/gnome-desktop-3.26:3=
-	gnome-base/gsettings-desktop-schemas
-	>=x11-libs/pixman-0.43.4
-	x11-libs/libxcb:=
-	x11-libs/libxkbcommon
-"
-DEPEND="${WLROOTS_DEPEND}
-	${RDEPEND}
-	test? ( x11-wm/mutter )
-"
-BDEPEND="${WLROOTS_BDEPEND}
-	dev-libs/glib:2
-	>=dev-libs/wayland-protocols-1.41
-	dev-util/wayland-scanner
-	sys-devel/gettext
-	gtk-doc? ( dev-util/gi-docgen )
-	man? ( dev-python/docutils )
-	verify-sig? ( sec-keys/openpgp-keys-phosh )
-"
-
-VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
-
-src_prepare() {
-	default
-
-	cd subprojects/wlroots-* || die
-	eapply "${S}"/subprojects/packagefiles/wlroots
-}
-
-src_configure() {
-	local emesonargs=(
-		$(meson_use gtk-doc gtk_doc)
-		$(meson_use man)
-		$(meson_use test tests)
-		-Ddefault_library=static
-		-Dembed-wlroots=enabled
-		-Dxwayland=enabled
-	)
-	meson_src_configure
-}
-
-src_test() {
-	local -x LC_ALL="C.UTF-8"
-	virtx meson_src_test
-}
-
-src_install() {
-	meson_src_install --skip-subprojects wlroots
-
-	if use gtk-doc; then
-		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
-		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
-	fi
-
-	newbin tools/auto-maximize phoc-auto-maximize
-	newbin tools/scale-to-fit phoc-scale-to-fit
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-	gnome2_schemas_update
-}
-
-pkg_postrm() {
-	xdg_pkg_postrm
-	gnome2_schemas_update
-}