dev-ml/nbd: initial import

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

dev-ml/nbd/Manifest

@@ -0,0 +1 @@
+DIST nbd-5.0.0.tar.gz 45288 BLAKE2B 783f54a633693315493d4e6edfb900aa885a41e0233514f75dde4658f9e60bfa9a076d3c314e83987f98d41ef7b632e79d2527389d6e1232c8488fb8454a6528 SHA512 33bece2c02666b39ab671ea5ae3425780deaa542ae135d01a7c5f9c4020a0e3953a4811cc1cfc2d02bed4d143d469d8425f5c9bf0b6df4bc444c3326826f129f

dev-ml/nbd/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>lssndrbarbieri@gmail.com</email>
+    <name>Alessandro Barbieri</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">xapi-project/nbd</remote-id>
+  </upstream>
+  <use>
+    <flag name="tool">command line helper for serving and mirroring disks over NBD, and getting information about the disks exported by an NBD server</flag>
+    <flag name="unix">Lwt_unix implementation</flag>
+  </use>
+</pkgmetadata>

dev-ml/nbd/nbd-5.0.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune multiprocessing
+
+DESCRIPTION="Ocaml NBD library"
+HOMEPAGE="https://github.com/xapi-project/nbd"
+SRC_URI="https://github.com/xapi-project/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="ocamlopt test tool unix"
+
+RDEPEND="
+	dev-ml/cstruct[ppx]
+	dev-ml/io-page
+	dev-ml/mirage-block-unix
+	dev-ml/lwt
+	dev-ml/lwt_log
+	dev-ml/ppx_sexp_conv
+	dev-ml/rresult
+	dev-ml/sexplib
+	dev-ml/uri
+
+	tool? ( dev-ml/cmdliner )
+	unix? (
+		dev-ml/cstruct[lwt]
+		dev-ml/io-page[unix(-)]
+		dev-ml/lwt_ssl
+		dev-ml/ocaml-ssl
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		app-emulation/qemu
+		dev-ml/alcotest
+		dev-ml/io-page[unix(-)]
+		sys-block/nbd
+		|| ( net-analyzer/openbsd-netcat net-analyzer/nmap[ncat] )
+	)
+"
+
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	tool? ( unix )
+	test? ( tool )
+"
+
+src_compile() {
+	local pkgs="nbd"
+	for u in tool unix ; do
+		if use ${u} ; then
+			pkgs="${pkgs},nbd-${u}"
+		fi
+	done
+	dune build -p "${pkgs}" -j $(makeopts_jobs) || die
+}
+
+src_install() {
+	dune_src_install nbd
+	use tool && dune_src_install nbd-tool
+	use unix && dune_src_install nbd-unix
+}