kde-apps/kaidan: add 0.8.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

kde-apps/kaidan/Manifest

@@ -1 +1,2 @@
 DIST kaidan-0.7.0.tar.xz 516684 BLAKE2B 6ee2f6696b1fca2ec564563e13c621f63edc8696d4b14ec22157adef611d5ba9d2d522bd960d1becc16a720851263503251d5a1f850af409daf439165a23839f SHA512 89389db3dfbc6acfae252c6fad2492a997760495f9a55d6f56bbf0f49832fcbff35548ba89dc3f24e6ff05b0c4b1ee0242566ca1c7f662fc096b13b37f99af94
+DIST kaidan-0.8.0.tar.xz 532028 BLAKE2B 75607bec35606bb87b820277c9d94af02f110c4b56d78cb7e3261555f89eecaa823b9cdbfe53a7561f145d0d94eef3fbd6acb76b4d975746706aa796e565cd3f SHA512 2084693dd2ae0f1410e6df57f77f1c2c080e9b48c771e632b4cc9bf0351e435fd9d6937209f50d0f41a7235317fe42578cc8c983163f61e0d6c541d148a202bf

kde-apps/kaidan/kaidan-0.8.0.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.67.0
+QTMIN=5.14.0
+inherit ecm
+
+DESCRIPTION="A simple, user-friendly Jabber/XMPP client for every device!"
+HOMEPAGE="https://www.kaidan.im"
+SRC_URI="mirror://kde/unstable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="Apache-2.0 CC-BY-SA-4.0 GPL-3+ GPL-3-with-openssl-exception MIT"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE="kde nls"
+
+BDEPEND="
+	nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
+"
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtlocation-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5[qml]
+	>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+	>=dev-qt/qtpositioning-${QTMIN}:5[qml]
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=media-libs/zxing-cpp-1.0.8
+	>=net-libs/qxmpp-1.3.0
+	kde? ( >=kde-frameworks/knotifications-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DI18N=$(usex nls)
+		-DBUILD_TESTS=$(usex test)
+		-DUSE_KNOTIFICATIONS=$(usex kde)
+		# compile QML at build time
+		-DQUICK_COMPILER=ON
+	)
+	ecm_src_configure
+}