sci-electronics/dsview: add 1.3.0

Signed-off-by: Huang Rui <vowstar@gmail.com>

sci-electronics/dsview/Manifest

@@ -1 +1,2 @@
 DIST dsview-1.2.1.tar.gz 8357048 BLAKE2B d1269aa6b55d69e6ce2b75ede916daac063200ac3f7be33d51f5363457c699956c9666b12a0a3557ccd8541ded78d3f2ffcb94ea8c71137452624988f711e339 SHA512 305e4223d10e45488cec96427fc43ee327d416bedb9dee603cb8acf8a6aca1b11f358e2ca53b825dc1c7c022da0495f83b497a9a70a3748c7540f5987cb2f993
+DIST dsview-1.3.0.tar.gz 9747423 BLAKE2B bee5969e80c6d57e5551d490e4682af94681db2d6396e44cd38708ff4c1022ee4e890ce0a17ebf6244888ffda46605bace3b6fc97824c42a2c8df1d91565d480 SHA512 367be9c8e7fe88008ec411d2122220df86678d622d5062f1248e63b1204185d1e09e4189910f96dd2e1df3005bf3b8ecba6061e9ae27ad77e696c7c1098dc4c9

sci-electronics/dsview/dsview-1.3.0.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GITHUB_PN="DSView"
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake python-r1 udev xdg
+
+DESCRIPTION="An open source multi-function instrument"
+HOMEPAGE="
+	https://www.dreamsourcelab.com
+	https://github.com/DreamSourceLab/DSView
+"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/DreamSourceLab/${GITHUB_PN}.git"
+else
+	SRC_URI="https://github.com/DreamSourceLab/${GITHUB_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${GITHUB_PN}-${PV}"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-cpp/glibmm:2
+	dev-libs/boost
+	dev-libs/glib
+	dev-libs/libzip
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtsvg:5
+	dev-qt/qtconcurrent:5
+	sci-libs/fftw:3.0
+	virtual/libusb:1
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	udev_reload
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	udev_reload
+	xdg_pkg_postrm
+}