gui-libs/mir: add 2.19.2

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

gui-libs/mir/Manifest

@@ -1 +1,2 @@
 DIST mir-2.18.3.tar.gz 6759986 BLAKE2B f651fd7b743d7f1faa4c6d83a1ba9eecd8fe20afb437fffee5f03bbe8238731034577c154cc4b0fc953156e708d613fbb5cc17bff3e86ce2b48e6a031bca4298 SHA512 7a2cc6678ff622cb131ba4aad5b84843d63ff054897e7990c6a605327ec5b599b7903a7ce68c356c62196680d90aa7adb90671dcc31706b8a07b1eb3d97fc752
+DIST mir-2.19.2.tar.gz 6811003 BLAKE2B 012ad7852974c88abba53e98f5fed3e8f2873f3ad5c3ba8a89c1b43ac67a9871cb7b1eba0034dacb5bd5a410dc931f03290096c9e31020c312788f55b2e851fd SHA512 99e5b09e3321b51bfd9427d778b5983b5a62628648b927c64bacfccb2a757f4c0db4664aaf3b87614472837c9434351681cdae42221b3760c8f947e2895712c2

gui-libs/mir/mir-2.19.2.ebuild

@@ -0,0 +1,90 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Set of libraries for building Wayland based shells"
+HOMEPAGE="https://mir-server.io/"
+SRC_URI="https://github.com/canonical/mir/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 GPL-3 ) || ( LGPL-2.1 LGPL-3 )"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="test X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/glibmm:2
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/yaml-cpp:=
+	dev-libs/boost:=
+	dev-libs/glib:2
+	dev-libs/libinput:=
+	dev-libs/wayland
+	dev-util/lttng-ust:=
+	media-libs/freetype
+	media-libs/libepoxy
+	media-libs/libglvnd
+	media-libs/mesa
+	sys-apps/util-linux
+	x11-libs/libXcursor
+	x11-libs/libdrm
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+	virtual/libudev:=
+	X? ( x11-libs/libX11 )
+"
+DEPEND="
+	${RDEPEND}
+	media-libs/glm
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	test? (
+		dev-cpp/gtest
+		dev-util/umockdev
+		x11-base/xwayland
+	)
+"
+
+PATCHES=(
+	# bug 932786
+	"${FILESDIR}/${PN}-2.17.0-remove-debug-flags.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+	cmake_comment_add_subdirectory examples/
+}
+
+src_configure() {
+	local platforms="gbm-kms;atomic-kms;wayland"
+	use X && platforms="${platforms};x11"
+
+	local mycmakeargs=(
+		# wlcs is not packaged
+		-DMIR_ENABLE_WLCS_TESTS=OFF
+		-DMIR_ENABLE_TESTS="$(usex test)"
+		-DMIR_FATAL_COMPILE_WARNINGS=OFF
+		-DMIR_PLATFORM="${platforms}"
+	)
+	use test && mycmakeargs+=(
+		# likely will not work in build environment
+		-DMIR_BUILD_PERFORMANCE_TESTS=OFF
+		-DMIR_BUILD_PLATFORM_TEST_HARNESS=OFF
+		-DMIR_BUILD_UNIT_TESTS=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use test; then
+		# remove dummy libraries
+		rm -f "${ED}/usr/$(get_libdir)/mir/server-platform/"{graphics-dummy.so,input-stub.so} || die
+	fi
+}