dev-python/mcp: new package, add 1.26.0

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>

dev-python/mcp/Manifest

@@ -0,0 +1,2 @@
+DIST mcp-1.26.0.tar.gz 608005 BLAKE2B d1dd8dd2cbe38574a9a7a6e7e9369e5944a63b750ed932c1b7751e171f06dca7f95db7f76dd0d9cc4b049baa3c945bc1074efd9e1a583dd41e183b40bdce5f7e SHA512 3de0c77f0fe580065a92be570528d1e56839973e79c035616008f186a0ff0eec85fdb10d1b3b3adb36f1ad0d52adb41fd5360873cb73c9271c33ada351549f12
+DIST mcp-1.26.0.tar.gz.provenance 9789 BLAKE2B a2457a56ac3ad700805a886606199d4053c532cf2ac202ca1713d83b3c9f2a88557174e54da4bc710b55ff85478ac738e47c1dd86ed4f0f089e95241d36525c7 SHA512 c38d1125b8049bccdfeccb686ffe324d6b1bac5b38fe96089f5652e34e1c38247c1d2c07e8ffed7ae849d580b15dba4eee1c9f5cf049ee608e3ce94ad6baacc1

dev-python/mcp/mcp-1.26.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/modelcontextprotocol/python-sdk
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Model Context Protocol SDK"
+HOMEPAGE="
+	https://modelcontextprotocol.io/
+	https://github.com/modelcontextprotocol/python-sdk
+	https://pypi.org/project/mcp/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="cli"
+REQUIRED_USE="test? ( cli )"
+
+RDEPEND="
+	>=dev-python/anyio-4.9.0[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.27.1[${PYTHON_USEDEP}]
+	>=dev-python/httpx-sse-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.20.0[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-2.12.0[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-settings-2.5.2[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/python-multipart-0.0.9[${PYTHON_USEDEP}]
+	>=dev-python/sse-starlette-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/starlette-0.27.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.13.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-inspection-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/uvicorn-0.31.1[${PYTHON_USEDEP}]
+	cli? (
+		>=dev-python/python-dotenv-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/typer-0.16.0[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		>=dev-python/python-dotenv-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/rich-13.9.4[${PYTHON_USEDEP}]
+		>=dev-python/typer-0.16.0[${PYTHON_USEDEP}]
+		>=dev-python/websockets-15.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( anyio )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Requires dev-python/pytest-examples which depends on missing Python
+	# bindings in dev-util/ruff::gentoo
+	tests/test_examples.py
+)
+EPYTEST_DESELECT=(
+	# TODO Tests have changed significantly/moved in master; re-check on vbump
+	# Fails due to changes in schema generation in newer Pydantic versions (v1.26.0)
+	tests/server/fastmcp/test_func_metadata.py::test_structured_output_unserializable_type_error
+	# Runs dev-python/uv and requires network access (v1.26.0)
+	tests/client/test_config.py::test_command_execution
+	# Fails for an unknown reason (wrong response type) (v1.26.0)
+	tests/shared/test_streamable_http.py::test_json_response
+)
+
+pkg_postinst() {
+	optfeature "colorized log output" dev-python/rich
+	optfeature "WebSockets support" dev-python/websockets
+}
+
+python_test() {
+	epytest -o asyncio_mode=auto
+}

dev-python/mcp/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>falbrechtskirchinger@gmail.com</email>
+		<name>Florian Albrechtskirchinger</name>
+	</maintainer>
+	<use>
+		<flag name="cli">Install dependencies required for the Command Line Interface</flag>
+	</use>
+	<upstream>
+		<remote-id type="pypi">mcp</remote-id>
+		<remote-id type="github">modelcontextprotocol/python-sdk</remote-id>
+	</upstream>
+</pkgmetadata>