media-gfx/swayimg: add 3.5

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>

media-gfx/swayimg/Manifest

@@ -1,2 +1,3 @@
 DIST swayimg-3.2.tar.gz 665154 BLAKE2B 6ece41b6f57190babb7236acdfc74b4855bc67b8e32916af8c8c34e482ba427d77a6fb242995457ef44bf7757cb381252a480cb0ef24dfc8916558448e17454e SHA512 9355e4b66e602b9cd6aabce834bdfd138952e8605fb60b7a78aef39fa1a6bf2ae83a04d745e7f8e133b3f94cdcd7361cf6faff55865ed8d243f62ba7e683b893
 DIST swayimg-3.4.tar.gz 668782 BLAKE2B 8d1e05ee592761e46bff760be98f79d0a76438cc0b129ca05205ce00b22e43c223ae83e6d11d98809c3d49b1f02bc281b177df89f24fa62d2767087c0b33209c SHA512 fb558bba0b2be70023f72444eec16fd0260f81bc7376f1d28c68136acc91befef148f0509f053d90cd3911755f270da908118afdc2a41c19bcb37d5018eb8450
+DIST swayimg-3.5.tar.gz 669706 BLAKE2B 21c8f6ba5cf99c1ff6e89f1f55dbbd3a8c097525f654592976853d6e98579177a199150de4a77f8058034f69a37485c7e197e3c5f98a3440c6a801ba557636ac SHA512 0f50775a02a12ce76f451d00117f395d704b225b759104f40342d0a22fffbe2c2a18ca927f5efb1c4d30d4712f2230a6015966d7f1d93c8146f0c5599689ca16

media-gfx/swayimg/swayimg-3.5.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="A lightweight image viewer for Wayland display servers"
+HOMEPAGE="https://github.com/artemsen/swayimg"
+SRC_URI="https://github.com/artemsen/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="avif bash-completion exif exr gif heif jpeg jpegxl png svg test tiff webp X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/json-c:=
+	dev-libs/wayland
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/libxkbcommon
+	avif? ( media-libs/libavif:= )
+	bash-completion? ( app-shells/bash-completion )
+	exif? ( media-libs/libexif )
+	exr? ( media-libs/openexr:= )
+	gif? ( media-libs/giflib:= )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( media-libs/libjxl:= )
+	png? ( media-libs/libpng:= )
+	svg? (
+		dev-libs/glib:2
+		gnome-base/librsvg:2
+		x11-libs/cairo[X=]
+	)
+	tiff? ( media-libs/tiff:= )
+	webp? ( media-libs/libwebp:= )"
+DEPEND="${RDEPEND}
+	dev-libs/wayland-protocols
+	svg? ( X? ( x11-base/xorg-proto ) )
+"
+BDEPEND="
+	dev-util/wayland-scanner
+	test? ( dev-cpp/gtest )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature avif)
+		$(meson_feature exif)
+		$(meson_feature exr)
+		$(meson_feature gif)
+		$(meson_feature heif)
+		$(meson_feature jpeg)
+		$(meson_feature jpegxl jxl)
+		$(meson_feature png)
+		$(meson_feature svg)
+		$(meson_feature test tests)
+		$(meson_feature tiff)
+		$(meson_feature webp)
+		$(meson_feature bash-completion bash)
+		-Dversion=${PV}
+		-Ddesktop=true
+		-Dman=true
+		-Dzsh=enabled
+	)
+	meson_src_configure
+}