media-sound/yandex-music: 5.74.1 vesrion bump

Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru>
2026-07-09 15:13:31 -04:00 · 2025-10-23 22:08:53 +03:00
parent f7411483ff
commit 933318baae
2 changed files with 130 additions and 0 deletions
--- a/media-sound/yandex-music/Manifest
+++ b/media-sound/yandex-music/Manifest
@@ -1,2 +1,3 @@
 DIST Yandex_Music_amd64_5.72.5.deb 90322566 BLAKE2B 8434c7ff60b50143f4c485194151ddc4bd74f8d0e92763b1a46fedab5f23ec4d94803514bc52f7090859b961f4e7674dc0e316dd1921f82aec60049d62eb1de3 SHA512 711e48d4c847ae9027c4a9a9f2e7d1a0609a5871df7b461f48fee13812ce1934ffb813d909182b184565b1a8b68b7397f47a27439b309f92a42bf45b8673f608
 DIST Yandex_Music_amd64_5.73.1.deb 90315806 BLAKE2B 7dc9833ddf5233d6b6820d9bb5ffa29d885b86e68334859faf0f180a369eac326ada5510c9820fcc5c131b258a0e8e7bfa1f3521b3644bc34cf7df682c126348 SHA512 bd99359575921153a89a870a286be5006f179b42b1ffc854add9b8df889ae6c83b27b2a9905347ff579d4d4d7d7d33a3dbdc5967921033f43169bfd12ef95ff9
+DIST Yandex_Music_amd64_5.74.1.deb 90333876 BLAKE2B 09cfaf75f1731078fa8198ff92bb7f1cfebcf19ee26e97ca8f36e6c4730310d02f09b8296f026656b8f5d095810c991f977b530997b1d273244d7f94d10104ff SHA512 fdbc1a1607062bde6d23d9e94325ee1e4a7e4fca38444a5f24e6f57015dcf174288f430635a9cbb56f51613b1da96ada47d94d5d7e824ccd1769d627dfbf0b6c
--- a/media-sound/yandex-music/yandex-music-5.74.1.ebuild
+++ b/media-sound/yandex-music/yandex-music-5.74.1.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi fil fr gu he hi hr hu id it ja kn ko \
+lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+inherit chromium-2 pax-utils wrapper unpacker xdg
+
+MY_PN="${PN/-/}"
+
+DESCRIPTION="Yandex Music streaming service"
+HOMEPAGE="https://music.yandex.ru/"
+SRC_URI="
+	amd64? ( https://music-desktop-application.s3.yandex.net/stable/Yandex_Music_amd64_${PV}.deb )
+"
+
+S="${WORKDIR}"
+
+LICENSE="Yandex-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-core
+	app-arch/bzip2
+	dev-libs/expat
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/gmp
+	dev-libs/libffi
+	dev-libs/libpcre2
+	dev-libs/libtasn1
+	dev-libs/libunistring
+	dev-libs/nettle
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-gfx/graphite2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz
+	media-libs/libepoxy
+	media-libs/libjpeg-turbo
+	media-libs/libpng
+	media-libs/mesa
+	net-dns/libidn2
+	net-libs/gnutls
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/systemd-utils
+	sys-apps/util-linux
+	sys-devel/gcc
+	sys-libs/glibc
+	sys-libs/libcap
+	sys-libs/zlib
+	x11-libs/cairo[X,glib]
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango[X]
+	x11-libs/pixman
+"
+DEPEND="
+	>=dev-util/patchelf-0.9
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/yandex-music.*\\.desktop"
+YANDEX_HOME="opt/${PN}"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	unpack_deb ${A}
+	mv -T "${S}/opt/Яндекс Музыка" "${S}/${YANDEX_HOME}" || die
+	mv -T "${S}/usr/share/doc/${MY_PN}" "${S}/usr/share/doc/${PF}" || die
+}
+
+src_prepare() {
+	default
+	sed -i -e "s|/opt/Яндекс Музыка/${MY_PN}|/opt/bin/${PN}|" -i -e "s/Audio;/AudioVideo;/" \
+		"${S}/usr/share/applications/${MY_PN}.desktop" || die
+
+	sed -i -e "s|/opt/Яндекс Музыка|/${YANDEX_HOME}|" "${S}/${YANDEX_HOME}"/resources/apparmor-profile || die
+
+	gunzip "usr/share/doc/${PF}/changelog.gz" || die "Failed to decompress docs"
+
+	rm "${S}/${YANDEX_HOME}"/resources/app-update.yml || die
+
+	pushd "${YANDEX_HOME}/locales" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/chrome-sandbox" || die "Failed to fix library rpath (chrome-sandbox)"
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/${MY_PN}" || die "Failed to fix library rpath (yandexmusic)"
+}
+
+src_install() {
+	insinto /opt
+	doins -r opt/*
+
+	insinto /usr
+	doins -r usr/*
+
+	make_wrapper ${PN} "/${YANDEX_HOME}/${MY_PN}" "" "/${YANDEX_HOME}" "/opt/bin/"
+
+	fowners root:root "/${YANDEX_HOME}/${MY_PN}"
+	fperms 4711 "/${YANDEX_HOME}/chrome-sandbox"
+	pax-mark m "${ED}${YANDEX_HOME}/chrome-sandbox"
+	fperms 755 "/${YANDEX_HOME}/${MY_PN}"
+}