phosh-base/phosh-osk-stevia: add 0.49.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

phosh-base/phosh-osk-stevia/Manifest

@@ -1,2 +1,4 @@
 DIST phosh-osk-stevia-0.48.0.tar.xz 333260 BLAKE2B b0a9a93bb0ebaf990a2dbf99391744cb2f9d3370cdf9eee69040c8bff59795a37dc03b1d847308cbd15542a7941dfed5618670b5b08c8fb9468eb5e62abe6bc9 SHA512 f84bd3fda653f61fc69305b526ece0a4ea25270f73bab06c62bae90d060a12e20d7cef3a5ab350487c8f1367fb6e27bd19cae25d1b61992854c2b129e1a0b7f5
 DIST phosh-osk-stevia-0.48.0.tar.xz.asc 833 BLAKE2B 13cfb47808802beb6420212ea8c829dfbf19e02c51bb7abe2e62b61ad804cd5167861aa80e6d42d26186b95fdc93892e98c001f3b1ac500888d3a01d4cc177d6 SHA512 78216af29e9a75ee23b01eaf7b7376fdaaaea521ccfa8b5d2ee7a12158a40027fbf2486f87d7c7b961bf8c9db9b126ea4ddac801628f25e3d3d01ba86bc2cc1b
+DIST phosh-osk-stevia-0.49.0.tar.xz 293124 BLAKE2B c01da4f944a99d3fa436d34b907fe93e14775aad8ffa32929492bf7127f8a1b25e32ad265c6579d2dccf761148758e44242062f06f1aa5afe7f1145b78a2ed37 SHA512 ae8ee20bee6b96d8571b41983fafe35df343ee3fed4c3218234b22f962a46061181820c7941b00900b2a6bf6079b9ccad810148ab6f8e2d525ac40c8267ea81e
+DIST phosh-osk-stevia-0.49.0.tar.xz.asc 833 BLAKE2B d82abe63efd5645e3fd4b71d041fc862f526aa0626af25e61095294d1425d9e04486c670e32ee0dca45f7abade25dea375e36eb8a9de9e7d1381562ae3f36d7c SHA512 fc45785fafc764dd3c2f4b7a52bde7b4455e4efb5c87c20b89f7e317a85ffa619338428dabb67426df8315f7681c95ffc68e99091b8f79126e317ccc683fbbf3

phosh-base/phosh-osk-stevia/phosh-osk-stevia-0.49.0.ebuild

@@ -0,0 +1,92 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson virtualx verify-sig xdg
+
+DESCRIPTION="Alternative on screen keyboard for Phosh"
+HOMEPAGE="https://gitlab.gnome.org/guidog/stevia"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="gtk-doc man systemd test"
+RESTRICT="!test? ( test )"
+
+# TODO: package govarnam
+# TODO: hunspell is automagic
+RDEPEND="
+	!phosh-base/phosh-osk-stub
+	app-shells/fzf
+	app-text/hunspell:=
+	>=dev-libs/glib-2.80:2
+	dev-libs/feedbackd
+	dev-libs/json-glib
+	>=dev-libs/wayland-1.14
+	>=gnome-base/gnome-desktop-3.26:3=
+	>=gui-libs/libhandy-1.1.90:1
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.22:3[wayland]
+	x11-libs/pango
+	systemd? ( >=sys-apps/systemd-241:= )
+	!systemd? ( >=sys-auth/elogind-241 )
+"
+DEPEND="${RDEPEND}
+	>=dev-libs/gmobile-0.2.0
+	>=dev-libs/wayland-protocols-1.12
+	>=gnome-base/gsettings-desktop-schemas-47
+	x11-libs/libxkbcommon[wayland]
+"
+BDEPEND="
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	test? ( dev-libs/json-glib )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+QA_DESKTOP_FILE="usr/share/applications/mobi.phosh.Stevia.desktop"
+
+src_configure() {
+	local emesonargs=(
+		-Ddefault_osk=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/pos-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}