dev-python/strawberry-graphql: add 0.312.3

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>

dev-python/strawberry-graphql/Manifest

@@ -1 +1,2 @@
 DIST strawberry-graphql-0.311.0.gh.tar.gz 1266374 BLAKE2B efb47f68c3e4d60e689ed82e3adbf3a4455ae9ca6881389c0eabb2139ae774fe52251ad6000c431502389df92c66dc5cb59138916d75b95305cd1eab5bebf02f SHA512 3fa8e6b607530ba5ae81631bdd4a8b4b47a1d725f9d897a77065b689ccd8c816357cf971d647bd6b2f43508f39509a632b0879bc5b9a1fa31fa0223281565d58
+DIST strawberry-graphql-0.312.3.gh.tar.gz 1273652 BLAKE2B 0cace4518fcd65f5920cd860809ccac9fb9decfc9b0062ddbd3cb7418fcb4e41059f74464d2c44c8743d769dc3eba746534dee0e82c541f8c04fbe85b8f3cdc0 SHA512 2b4a9a28fe5551077e127d23460748be38798eaf10d8d7d78a5ec76f34efa9028145725493af06fa3f9e11683113b4dd5691b6e2cecb56bd42cdadf2ddccc493

dev-python/strawberry-graphql/strawberry-graphql-0.312.3.ebuild

@@ -0,0 +1,99 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{12..13} )
+
+inherit distutils-r1 #pypi
+
+DESCRIPTION="A library for creating GraphQL APIs"
+HOMEPAGE="
+	https://strawberry.rocks/
+	https://github.com/strawberry-graphql/strawberry/
+	https://pypi.org/project/strawberry-graphql/
+"
+# no tests in sdist
+SRC_URI="
+	https://github.com/strawberry-graphql/strawberry/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/strawberry-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cross-web-0.4.0[${PYTHON_USEDEP}]
+	<dev-python/graphql-core-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/graphql-core-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.7[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
+"
+
+# dev
+# integrations
+BDEPEND="
+	test? (
+		dev-python/asgiref[${PYTHON_USEDEP}]
+		dev-python/email-validator[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/libcst[${PYTHON_USEDEP}]
+		dev-python/markupsafe[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-api[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/pyinstrument[${PYTHON_USEDEP}]
+		dev-python/python-multipart[${PYTHON_USEDEP}]
+		dev-python/rich[${PYTHON_USEDEP}]
+		dev-python/typer[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+		dev-python/inline-snapshot[${PYTHON_USEDEP}]
+
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/chalice[${PYTHON_USEDEP}]
+		dev-python/channels[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/fastapi[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/quart[${PYTHON_USEDEP}]
+		dev-python/pydantic[${PYTHON_USEDEP}]
+		dev-python/starlette[${PYTHON_USEDEP}]
+		dev-python/litestar[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	"tests/benchmarks/"
+	# avoid daphne which requires autobahn
+	"tests/channels/test_layers.py"
+	"tests/channels/test_testing.py"
+	"tests/http/clients/channels.py"
+	# FIXME:
+	"tests/http/test_graphql_ide.py"
+)
+EPYTEST_DESELECT=(
+	# TODO: sanic
+	"tests/sanic/test_file_upload.py::test_file_cast"
+	"tests/sanic/test_file_upload.py::test_endpoint"
+	# test stdlib?
+	"tests/schema/test_lazy/test_lazy_generic.py::test_lazy_types_loaded_from_same_module[script]"
+	# FIXME
+	"tests/django/test_dataloaders.py::test_fetch_data_from_db"
+)
+EPYTEST_PLUGINS=( pytest-aiohttp pytest-asyncio pytest-django pytest-mock pytest-snapshot )
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/strawberry-0.288.3-no-emoji-test.patch
+)
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE="tests.django.django_settings"
+
+	# avoid superfluous pytest-emoji dependency
+	epytest -o addopts=
+}