gui-libs/mir: add 2.25.2

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

gui-libs/mir/Manifest

@@ -1,2 +1,3 @@
 DIST mir-2.22.2.tar.gz 6943488 BLAKE2B ab8d3fb10c359f7364c5ff19fb9f75e483f251ba3619feda7a58cffff99d5a2c6193dd4612c4d20a2f25c8c582c99506f49b5b378366ec7d3a10b1e15adab154 SHA512 3b2246343557a0c1770173f89371402da4b4694ffd7b1ee53a3b8098ddbd81800cc91773b76d0f12eb22cc6d44eada258e3481817050348e913b1d6c34d1bd54
 DIST mir-2.23.0.tar.gz 6919597 BLAKE2B 0e0b165ffb2a182be0f7f359dc9e488898533a4999a6e637b77f8230decb72c01902cd22a01867929634aace6166a992ba7e1bbfe41120b83b2a05885337662d SHA512 1c020f9e863d7cdc7d75f41ab72cbfdc87229d6810042c271b95a4de5f143caeb337aa2fa47e86b146bde758c10bdb946f7d600703b4dabf63b7fedd6c95a856
+DIST mir-2.25.2.tar.gz 6989237 BLAKE2B 174a053c41c5c8df5adbd0e5cab8f7705b8645ec8e1d0848bbc2ed26ed0d9d44eb7b00c50e7bf0088df2db4b3e3e60cd70e20a668998108c8e9917be0f271bd9 SHA512 d00ee931ea3ff0017e2acd7ce9c654208d0970d0f1ec4265893eee0bd90cf05b90dc35c9a8535e03465eb61605c04f326bc93f60ff07200e8ddb20ed61a78eb6

gui-libs/mir/mir-2.25.2.ebuild

@@ -0,0 +1,91 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Set of libraries for building Wayland based shells"
+HOMEPAGE="https://canonical.com/mir"
+SRC_URI="https://github.com/canonical/mir/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 GPL-3 ) || ( LGPL-2.1 LGPL-3 )"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64"
+IUSE="examples test wayland X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/glibmm:2
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/yaml-cpp:=
+	dev-libs/boost:=
+	dev-libs/glib:2
+	dev-libs/libinput:=
+	dev-libs/wayland
+	dev-util/lttng-ust:=
+	media-libs/freetype
+	media-libs/libdisplay-info:=
+	media-libs/libepoxy
+	media-libs/libglvnd
+	media-libs/mesa
+	sys-apps/util-linux
+	x11-libs/libXcursor
+	x11-libs/libdrm
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	virtual/libudev:=
+	X? ( x11-libs/libX11 )
+"
+DEPEND="
+	${RDEPEND}
+	media-libs/glm
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	test? (
+		dev-cpp/gtest
+		dev-util/umockdev
+		x11-base/xwayland
+	)
+"
+
+PATCHES=(
+	# bug 932786
+	"${FILESDIR}/${PN}-2.17.0-remove-debug-flags.patch"
+	"${FILESDIR}/${PN}-2.20.0-remove-tests.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+	use examples || cmake_comment_add_subdirectory examples/ examples/tests/
+}
+
+src_configure() {
+	local platforms=( gbm-kms atomic-kms )
+	use wayland && platforms+=( wayland )
+	use X && platforms+=( x11 )
+
+	local mycmakeargs=(
+		# wlcs is not packaged
+		-DMIR_ENABLE_WLCS_TESTS=OFF
+		-DMIR_ENABLE_TESTS="$(usex test)"
+		-DMIR_FATAL_COMPILE_WARNINGS=OFF
+		-DMIR_PLATFORM="$(IFS=';'; echo "${platforms[*]}")"
+		-DMIR_ENABLE_RUST=OFF
+	)
+	use test && mycmakeargs+=(
+		# likely will not work in build environment
+		-DMIR_BUILD_PERFORMANCE_TESTS=OFF
+		-DMIR_BUILD_PLATFORM_TEST_HARNESS=OFF
+		-DMIR_BUILD_UNIT_TESTS=OFF
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	xdg_environment_reset
+	cmake_src_test
+}