mirrors/guru
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/guru.git synced 2026-07-15 18:13:10 -04:00
Code Issues Packages Projects Releases Wiki Activity

Merge updates from master

Browse Source
This commit is contained in:
Repository mirror & CI
2024-04-09 11:33:26 +00:00
parent 6c25ac8553 2be7495997
commit 86c5aee247
44 changed files with 992 additions and 67 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
app-admin/bitwarden-cli-bin/Manifest
View File

@@ -1,2 +1,3 @@
DIST bw-linux-2024.2.0.zip 32968695 BLAKE2B 808dbd4965cc26b3880bd541bc4c3627ed6b07233bb3eb62c76c5034ba734c6211c1fc907309f71d8dcfd993a61ba0bcdd049dc052c477cb43e7d4452929fe31 SHA512 80fa0ab96bf291ed5008d5c01d00eebf950e72b8c21184be3df1018ba33d33bac038b4410e17123096113642372b8013bdde0605473449cec5c69c418fa2e3c5
DIST bw-linux-2024.2.1.zip 33060347 BLAKE2B fdfeec07f9c9a0c70741461ff4969b8909fb04d6aa0411a936b8a10165d7e2a31ad02228cbb6e1aea6f375436be8dd5d2dc560a440d1db9877c056ed1e870719 SHA512 67222301f62371129eccd7847a642e7ac13191d9e8d5033774f888cb6eb989e1427ce2c02a05121a259e7c217214d31d793474827b315479b410bb780f858f0d
DIST bw-linux-2024.3.1.zip 33190371 BLAKE2B e0440980ef22083b53cf3032b9fb600fc9fefe06afd64431475871d2f64af1fb5620096aada09ff3a7b7fd89992abefa410e8bbf289230aae2515e118d36ad77 SHA512 4406a118b4815eab950f8bfdba5623f8097acf0d4018726985e4614a3deb6a52d3a0323deac35ba270c7974649da9f4a70ccdf049ce88ee0528c6980935366a0

35
app-admin/bitwarden-cli-bin/bitwarden-cli-bin-2024.3.1.ebuild Normal file
View File

@@ -0,0 +1,35 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit shell-completion
DESCRIPTION="Precompiled CLI frontend which connects to Bitwarden comapatible servers"
HOMEPAGE="https://github.com/bitwarden/clients/tree/main/apps/cli"
SRC_URI="
https://github.com/bitwarden/clients/releases/download/cli-v${PV}/bw-linux-${PV}.zip
"
S="${WORKDIR}"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
# non-stripped binary is of 99M but works
# stripped bianry is of 44M but doesnt work
RESTRICT='strip'
RDEPEND="!app-admin/bitwarden-cli"
BDEPEND="app-arch/unzip"
QA_PREBUILT="usr/bin/bw"
src_compile() {
./bw completion --shell zsh > bw.zsh 2> /dev/null || die
}
src_install() {
dobin bw
newzshcomp bw.zsh _bw
}

1
dev-build/xmake/Manifest Normal file
View File

@@ -0,0 +1 @@
DIST xmake-v2.8.9.tar.gz 2814291 BLAKE2B 8a7ba74e2a8374e34f4fd4a70a1c0c5365954d5f30093d08d5054d1f4697b98049abee6b105f3830a2bbf4dfc0fc140b536d291bc71747414e37af012b5308a6 SHA512 63edfd8ef71a363f4587fa819eb538182b3770215d9b7e844c92aa2dca07f712a5c49cea1947cad84189bc5df1350a62e6c4a6b1c23e55425220857749e39f11

0
dev-util/xmake/metadata.xml → dev-build/xmake/metadata.xml
View File

0
dev-util/xmake/xmake-2.8.8.ebuild → dev-build/xmake/xmake-2.8.9.ebuild
View File

0
dev-util/xmake/xmake-9999.ebuild → dev-build/xmake/xmake-9999.ebuild
View File

26
dev-python/digitalocean/digitalocean-1.17.0.ebuild
View File

@@ -1,26 +0,0 @@
# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1
DESCRIPTION="Digitalocean API access library"
HOMEPAGE="https://github.com/koalalorenzo/python-digitalocean"
SRC_URI="https://github.com/koalalorenzo/python-${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
S="${WORKDIR}/python-${P}"
LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
dev-python/requests[${PYTHON_USEDEP}]
dev-python/jsonpickle[${PYTHON_USEDEP}]
"
BDEPEND="test? ( dev-python/responses[${PYTHON_USEDEP}] )"
distutils_enable_sphinx docs dev-python/alabaster
distutils_enable_tests pytest

1
dev-util/xmake/Manifest
View File

@@ -1 +0,0 @@
DIST xmake-v2.8.8.tar.gz 2810801 BLAKE2B 79a877ebfbd99e034a5bb5767c1522304261024d96338671215dba0fd368737eca0603051c521859276ab811465e6c54548bb02582e5aea9d7c44387846701ec SHA512 538b33cb54a7aefc52edff1cc77144ba3d3b273f11d3b8cfa1cfac744b868467ff3ad0dc3bc39046648819b73badb7e8c9eb485d98cccf81da048a74470831a0

2
gui-wm/phoc/Manifest
View File

@@ -1,2 +1,4 @@
DIST phoc-0.36.0.tar.xz 681384 BLAKE2B 6c27c785dd01f9e44cb0940c5a4f73d5ce75cad85808d0b6c801360401ff001cca839abd27bc8442702c5241bac043c6d7015e6f1c5a5ec30cfcb6779adf973b SHA512 a47851a3e222958ad55c05ed86a068b30f6e00ed5d7e957aab99e7f4103b95fee4db6b177f2de8d0c9ce11306c68ef74d78e38ea0bdb6c47e66f9ef9bf0e9f66
DIST phoc-0.36.0.tar.xz.asc 833 BLAKE2B 0562c02dcb5d1618b3a316c4c36e4757f4729adf99b8ac748ed52c1bdcad6b65bc9fdb98462375e80f6898d699c6e237e4aa5057631434235166ca616de7d2e6 SHA512 2108eed0a0723c743d86eee9f517a9c8505faf8f55a32eb60ee9da04ae53221b00520ca9e422397617d1bde6f1047ba2ebdf6d45211df052b9b2cfa2d3ea12fe
DIST phoc-0.38.0.tar.xz 694784 BLAKE2B 51aef1cb1a4e753278727c8311b7aadfb9c18cbdf820725487c837bd0f943e6c7a0420a502e0316ba4ba96cb861a13d1f6a8cdcd9d1a5b51e75e5ecb9bdcf6f7 SHA512 739fb382336885b78ca3f50f8c5f6ddf3bc308a2158663c49c84ce506d2edf0c8d0dcd412e634eccf848d420bb5923d42ebc02044f7acf322b3ab621ffa4cd23
DIST phoc-0.38.0.tar.xz.asc 833 BLAKE2B 63dd885cda46b90f5edd56289b9114d31726a543608f5a3f02f52848713a01d06e7e8a8660797c98c3504c3c59fe485ab92e58eaf7689c185d26e41027b96b30 SHA512 f69533ed5d1bce220ea66ae4f6307620178609b6c4d9ed743d0cd62f9944faf3dd76e7fce242e722b6912246e268b466ee0bf52326b39907c78d7f6c8eceabda

BIN
gui-wm/phoc/core Normal file
View File

Binary file not shown.

2
gui-wm/phoc/phoc-0.36.0-r1.ebuild
View File

@@ -62,7 +62,7 @@ BDEPEND="
verify-sig? ( sec-keys/openpgp-keys-phosh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/phosh.asc"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
src_prepare() {
default

111
gui-wm/phoc/phoc-0.38.0.ebuild Normal file
View File

@@ -0,0 +1,111 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome2-utils meson verify-sig virtualx xdg
DESCRIPTION="Wayland compositor for mobile phones"
HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )
"
LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="gtk-doc man test"
RESTRICT="!test? ( test )"
WLROOTS_DEPEND="
>=dev-libs/libinput-1.14.0:=
>=dev-libs/wayland-1.22.0
media-libs/libdisplay-info
media-libs/libglvnd
media-libs/mesa[egl(+),gles2]
sys-apps/hwdata
sys-auth/seatd:=
x11-base/xwayland
x11-libs/cairo
>=x11-libs/libdrm-2.4.114
x11-libs/libxcb:=
x11-libs/libxkbcommon
>=x11-libs/pixman-0.42.0
x11-libs/xcb-util-errors
x11-libs/xcb-util-renderutil
x11-libs/xcb-util-wm
virtual/libudev
amd64? ( >=dev-libs/libliftoff-0.4 )
"
COMMON_DEPEND="${WLROOTS_DEPEND}
>=dev-libs/glib-2.74:2
dev-libs/json-glib
dev-libs/libinput:=
dev-libs/wayland
>=gnome-base/gnome-desktop-3.26:3
gnome-base/gsettings-desktop-schemas
x11-libs/pixman
x11-libs/libxcb:=
x11-libs/libxkbcommon
"
DEPEND="${COMMON_DEPEND}
test? ( x11-wm/mutter )
"
RDEPEND="${COMMON_DEPEND}"
BDEPEND="
dev-libs/glib:2
dev-libs/wayland-protocols
dev-util/wayland-scanner
sys-devel/gettext
gtk-doc? ( dev-util/gi-docgen )
man? ( dev-python/docutils )
verify-sig? ( sec-keys/openpgp-keys-phosh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
src_prepare() {
default
cd subprojects/wlroots || die
eapply "${S}"/subprojects/packagefiles/wlroots
}
src_configure() {
local emesonargs=(
$(meson_use gtk-doc gtk_doc)
$(meson_use man)
$(meson_use test tests)
-Ddefault_library=static
-Dembed-wlroots=enabled
-Dxwayland=enabled
)
meson_src_configure
}
src_test() {
local -x LC_ALL="C.UTF-8"
virtx meson_src_test
}
src_install() {
meson_src_install --skip-subprojects gmobile,wlroots
if use gtk-doc; then
mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
fi
newbin helpers/auto-maximize phoc-auto-maximize
newbin helpers/scale-to-fit phoc-scale-to-fit
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}

4
net-client/telescope/Manifest
View File

@@ -1,4 +1,4 @@
DIST telescope-0.7.1.sha.sig 731 BLAKE2B f70f261e517a3eb3a6c853e7fee373d83cdd2a02c715fe1a8badad41c48d5791af968ddaf53eaaa0b7d26ee0c2b6e8d40174a344c2e9ba3c957c1a0428c89138 SHA512 233749dc11a47c4b27703bf74a434be445b5de708297e6737d4d17a076d97b04819a02ee75c53fdf2266eeaf31b5dae39b72d87839d7855adf7c23efe639ec3f
DIST telescope-0.7.1.tar.gz 282170 BLAKE2B bf0f0ed5299ce0e2d5bc1970de13ccaeb9180f6dae30d0771f7942acbf90be6f37d8c30fb710ca89c644c1257c4f2538d6080f55f8c0e0223370120c9bc478b9 SHA512 2c56bfc2bf107dc27ac569539a2db405dafe1de9604e13544c293d81667c4172d617dbacfd1403fad68950d73d4e2f1ca08204c6ac2bef17bd8591e53c38e808
DIST telescope-0.8.1.sha.sig 437 BLAKE2B 54c176b06012f32d3b31370baebcf3c2887eb57db64559f59b942f9527ee069c5b08a1516659743cb8b8d5f0ba4202ff49360c835af28c8fb3a693d3e0a856a6 SHA512 3952bb740f2146c157b613b90563b7b7badefb8fa99849dc1d3f124e30cccb6fdf2488e01afb96fc52ae20681fa7fe048e56d3c31c9acc74e300d9c2cce9169d
DIST telescope-0.8.1.tar.gz 305052 BLAKE2B 0e4955684a3694a21a46eadd5eba69b7b41424c191e596443b5edc66155e4e3f2384f2a833fec08b1c4d61e74189c0b1069e8089583a284d9df9d0bbde2a444d SHA512 1134fa763f36c306bb676fe361442e557144f5d32e29e5ba8a3fb406ef274b28b462389729f1eacc32d2bb341fbb1627fc4b07cca1089f5276317151239dc822
DIST telescope-0.9.tar.gz 349054 BLAKE2B 4fa83a47d0661e6c0bbed1f24e51152270311873bb48e80ef119175d152c40261a13ce415e5faba814bf7fc4c4f4dda84674ea30cb518d2ab11ed1163a4fad26 SHA512 cea25b8b988011ced6851917b0452d96972e0c9a48a3097f74f2f6fbef1e9d6df7ddf9408ba9885554b269a31d4a5a8ab25817f28d42e430a8ce172453cbd56d
DIST telescope-0.9.tar.gz.sha256.sig 247 BLAKE2B 9a71d0f7f51974720b913bdcc9eddd5fd6f51ab910abdf989dcf721c25ec0fa63493aedd89e34adfdcb53e1a85bcb6e7fb1e8b99b1db5b445a320d5fa73fa57f SHA512 86e29e51d4b12265ce383b6d3bb33e34d29f0fcbf062b1d13bcc53484665176a72d4a28f06439176cfdf64b1b76c754f1266816bdbbbc67bef54ed7695fde9a7

24
net-client/telescope/telescope-0.7.1.ebuild → net-client/telescope/telescope-0.9.ebuild
View File

@@ -1,4 +1,4 @@
# Copyright 2021-2022 Gentoo Authors
# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
@@ -8,23 +8,23 @@ inherit toolchain-funcs verify-sig
DESCRIPTION="w3m-like browser for Gemini"
HOMEPAGE="https://telescope.omarpolo.com"
SRC_URI="https://github.com/omar-polo/${PN}/releases/download/${PV}/${P}.tar.gz
verify-sig? ( https://github.com/omar-polo/${PN}/releases/download/${PV}/SHA256.sig -> ${P}.sha.sig )"
SRC_URI="https://ftp.omarpolo.com/${P}.tar.gz
verify-sig? ( https://ftp.omarpolo.com/${P}.tar.gz.sha256.sig )"
LICENSE="!libbsd? ( BSD MIT ) ISC unicode"
LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+libbsd"
IUSE="unicode"
DEPEND="
dev-libs/imsg-compat
dev-libs/libevent:=
dev-libs/libbsd
dev-libs/libgrapheme:=
dev-libs/libretls:=
sys-libs/ncurses:=
libbsd? ( dev-libs/libbsd )
"
RDEPEND="${DEPEND}"
BDEPEND="
app-alternatives/yacc
virtual/pkgconfig
verify-sig? ( sec-keys/signify-keys-telescope:$(ver_cut 1-2) )
"
@@ -34,10 +34,10 @@ VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/${PN}-$(ver_cut 1-2).pub"
src_unpack() {
if use verify-sig; then
# Too many levels of symbolic links
cp "${DISTDIR}"/${P}.{sha.sig,tar.gz} "${WORKDIR}" || die
cp "${DISTDIR}"/${P}.tar.gz{,.sha256.sig} "${WORKDIR}" || die
cd "${WORKDIR}" || die
verify-sig_verify_signed_checksums \
${P}.sha.sig sha256 ${P}.tar.gz
${P}.tar.gz.sha256.sig sha256 ${P}.tar.gz
fi
default
}
@@ -47,8 +47,8 @@ src_configure() {
local econf_args=(
HOSTCC="${BUILD_CC}"
HOSTCFLAGS="${BUILD_CFLAGS}"
$(use_with libbsd)
--with-libimsg
--with-libbsd
--without-libimsg
)
econf "${econf_args[@]}"

153
net-dns/AdGuardHome/AdGuardHome-0.107.48.ebuild Normal file
View File

@@ -0,0 +1,153 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit fcaps go-module readme.gentoo-r1 systemd unpacker
DESCRIPTION="Network-wide ads & trackers blocking DNS server like Pi-Hole with web ui"
HOMEPAGE="https://github.com/AdguardTeam/AdGuardHome/"
WIKI_COMMIT="7964837"
SRC_URI="
https://github.com/AdguardTeam/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
https://github.com/rahilarious/gentoo-distfiles/releases/download/${P}/deps.tar.zst -> ${P}-deps.tar.zst
https://github.com/rahilarious/gentoo-distfiles/releases/download/${PN}-0.107.46/wiki.tar.xz -> ${PN}-wiki-${WIKI_COMMIT}.tar.xz
web? ( https://github.com/rahilarious/gentoo-distfiles/releases/download/${P}/npm-deps.tar.zst -> ${P}-npm-deps.tar.zst )
"
# main
LICENSE="GPL-3"
# deps
LICENSE+=" Apache-2.0 BSD BSD-2 MIT ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="+web"
# RESTRICT="test"
BDEPEND="
$(unpacker_src_uri_depends)
>=dev-lang/go-1.22.2
web? ( net-libs/nodejs[npm] )
"
FILECAPS=(
-m 755 'cap_net_bind_service=+eip cap_net_raw=+eip' usr/bin/${PN}
)
PATCHES=(
"${FILESDIR}"/disable-update-cmd-opt.patch
)
DOCS="
../${PN,,}.wiki/*
"
DOC_CONTENTS="\n
User is advised to not run binary directly instead use systemd service\n\n
Defaults for systemd service:\n
Web UI: 0.0.0.0:3000\n
Data directory: /var/lib/${PN}\n
Default config: /var/lib/${PN}/${PN}.yaml
"
src_unpack() {
# because we're using vendor/ so we don't need go-module_src_unpack
unpacker_src_unpack
}
src_prepare() {
ln -sv ../vendor ./ || die
default
if use web; then
# mimicking `make js-deps`
export npm_config_cache="${WORKDIR}/npm-cache" NODE_OPTIONS=--openssl-legacy-provider || die
npm --verbose --offline --prefix client/ --no-progress --ignore-engines --ignore-optional --ignore-platform --ignore-scripts ci || die
fi
}
src_compile() {
# mimicking `make js-build`
use web && npm --verbose --offline --prefix client run build-prod || die
# mimicking https://github.com/AdguardTeam/AdGuardHome/blob/master/scripts/make/go-build.sh
local MY_LDFLAGS="-s -w"
MY_LDFLAGS+=" -X github.com/AdguardTeam/AdGuardHome/internal/version.version=${PV}"
MY_LDFLAGS+=" -X github.com/AdguardTeam/AdGuardHome/internal/version.channel=release"
MY_LDFLAGS+=" -X github.com/AdguardTeam/AdGuardHome/internal/version.committime=$(date +%s)"
if [ "$(go env GOARM)" != '' ]
then
MY_LDFLAGS+=" -X github.com/AdguardTeam/AdGuardHome/internal/version.goarm=$(go env GOARM)"
elif [ "$(go env GOMIPS)" != '' ]
then
MY_LDFLAGS+=" -X github.com/AdguardTeam/AdGuardHome/internal/version.gomips=$(go env GOMIPS)"
fi
ego build -ldflags "${MY_LDFLAGS}" -trimpath -v=1 -x=1
}
src_test() {
# mimicking https://github.com/AdguardTeam/AdGuardHome/blob/master/scripts/make/go-test.sh
count_flags='--count=1'
cover_flags='--coverprofile=./coverage.txt'
shuffle_flags='--shuffle=on'
timeout_flags="--timeout=30s"
fuzztime_flags="--fuzztime=20s"
readonly count_flags cover_flags shuffle_flags timeout_flags fuzztime_flags
# race only works when pie is disabled
export GOFLAGS="${GOFLAGS/-buildmode=pie/}"
# following test is failing without giving any reason. Tried disabling internal/updater internal/whois tests toggling race, but still failing.
# ego test\
# "$count_flags"\
# "$cover_flags"\
# "$shuffle_flags"\
# --race=1\
# "$timeout_flags"\
# ./...
# mimicking https://github.com/AdguardTeam/AdGuardHome/blob/master/scripts/make/go-bench.sh
ego test\
"$count_flags"\
"$shuffle_flags"\
--race=0\
"$timeout_flags"\
--bench='.'\
--benchmem\
--benchtime=1s\
--run='^$'\
./...
# mimicking https://github.com/AdguardTeam/AdGuardHome/blob/master/scripts/make/go-fuzz.sh
ego test\
"$count_flags"\
"$shuffle_flags"\
--race=0\
"$timeout_flags"\
"$fuzztime_flags"\
--fuzz='.'\
--run='^$'\
./internal/filtering/rulelist/\
;
}
src_install() {
dobin "${PN}"
dosym -r /usr/bin/"${PN}" /usr/bin/adguardhome
einstalldocs
readme.gentoo_create_doc
systemd_newunit "${FILESDIR}"/AdGuardHome-0.107.43.service "${PN}".service
}
pkg_postinst() {
readme.gentoo_print_elog
}

3
net-dns/AdGuardHome/Manifest
View File

@@ -4,4 +4,7 @@ DIST AdGuardHome-0.107.45.tar.gz 2248687 BLAKE2B 257fbd716d769657c9b40a03f91f7dc
DIST AdGuardHome-0.107.46-deps.tar.xz 2617456 BLAKE2B b53495335b348bcc86dd1c03765e14e6d30a85a60405179d5de9105ebc83ffc39dc035ff6c58adec9f92dfe3dee9714a563372f16902e8c8956b32926b4b117c SHA512 15b7521f038914757ff9e72f441b78957750a26730041adea57488548711402b76a642ae49fc970f69aea84e5d033a146fd201cb8707c0de099be096ae68a81c
DIST AdGuardHome-0.107.46-frontend.tar.gz 2791684 BLAKE2B 086826322a3cfa799081bc7b67ae91f7222cb4fa020e0be51ab6f46cb862edca967289f66747dc95f287a48e342e91156f9d155e1080aa2ca02b342223ce8192 SHA512 b4b9b5f9dfae16af9b6a77ca70226ad30e7ecf7eff883bf071304b4a3583ad6bc57d122f956db2bf7cd199abeb582f14e91393740062396eebc376d1c1018ad6
DIST AdGuardHome-0.107.46.tar.gz 2258665 BLAKE2B d3b7a6cd24e35fc22fc90919ce7143fbe3475891f151011b5c059f66cbcb78b756d40e797cbee5a1cc2d22064969abac329165f16794619e1b60ea6b22366692 SHA512 aaac649e162885c7128a0e8596b03a2b3e1a53fb605ff6d0070e97632d5b8141a3ebba6f93e7f17a51e69394dace0f5bc9b7715a739137dca6740a678ff6a075
DIST AdGuardHome-0.107.48-deps.tar.zst 3702175 BLAKE2B 2da4d5e43d8c43f3222ed638726ea541e560978ee5b7d1a452f4ca3f9af6b8f019ee9fb1115485ea76c61ec627b29b9f25d3ee00326ae3a97d7c3e3c5d391153 SHA512 2783962df7216566c87c04619488786199d2b82ea8378e2d28e01413c5f3eae66a76a85d0966b25857533548b134e2df361c97205bb00a4c51b22571e99073a1
DIST AdGuardHome-0.107.48-npm-deps.tar.zst 31298525 BLAKE2B 8b52fd0eddd4fcb5405e0d08d48c38023ef5a75715ec8eca406bd8811a7ef8d719cc842011b00e364ece9bc1deed415f65eae863baea4d09df6ad7536c0b9da7 SHA512 4bae696c842a24d3e7d0c197e3a8a42efc4c67a158a20ba7243f20300f2ddd35a89c1ad46e90c2498ec5bdfe5733a1fa961d11d033a53549240b85ddb2ee5993
DIST AdGuardHome-0.107.48.tar.gz 2264834 BLAKE2B 3fc50e5d76b9e73ab14a355f005ba0a57d51e2b45b39667b31e7558a86ea31ab23009ce5738232a9de3bdf781edda9eea9689d315c285ac5bd5273351ba6f606 SHA512 861affc0628a14b7823822c4b2b2c66a874801fc4b4fa50b909785ea57b39f86bb6cc4df84d04d941b251a6eec6055e93f41cb04eeba92a4a9477c1904e8d14f
DIST AdGuardHome-wiki-7964837.tar.xz 44012 BLAKE2B 0cef0fb890e9fd80db12d74abd39ea90efa5561e11fba0e9df55b5e48536cd5a604d18bd17907921568d73bcc1b08ebb2980e16cb4e1eeb37be10ef89a106243 SHA512 2177fe47986f3086804ef900d2e338efbaf647df7f81d8b28235f77f0375681f96db112d3b06f69ee36706fc44698bdd960b919f5b87f82546ce87cb93b3f196

5
net-im/eturnal/eturnal-1.12.0.ebuild → net-im/eturnal/eturnal-1.12.0-r1.ebuild
View File

@@ -18,7 +18,7 @@ KEYWORDS="~amd64"
DEPEND="
acct-user/eturnal
>=dev-lang/erlang-21[ssl]
>=dev-lang/erlang-21:=[ssl]
dev-libs/libyaml
dev-libs/openssl:=
>=dev-erlang/conf-0.1
@@ -42,7 +42,6 @@ src_configure() {
export CODE_LOADING=dynamic
export SKIP_DEPS=true
rebar3_src_configure
}
@@ -51,7 +50,7 @@ rebar3_install_release() {
cp -pR bin lib releases "${ED}"/opt/eturnal/ || die
systemd_dounit etc/systemd/system/eturnal.service
newinitd etc/openrc/eturnal.initd eturnal
newinitd "${FILESDIR}"/eturnal.initd eturnal
newconfd etc/openrc/eturnal.confd eturnal
insinto /etc

46
net-im/eturnal/files/eturnal.initd Normal file
View File

@@ -0,0 +1,46 @@
#!/sbin/openrc-run
# shellcheck shell=sh
#
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
extra_started_commands="reload"
command="/usr/sbin/eturnalctl"
command_args="foreground"
command_user="eturnal:turnserver"
command_background=1
pidfile="/run/eturnal.pid"
capabilities="^cap_net_bind_service"
healthcheck_delay=300
healthcheck_timer=60
depend() {
need epmd net
after firewall
}
healthcheck() {
"${command}" ping >/dev/null
}
start_post() {
local i=10
while [ $((i = i - 1)) -gt 0 ]; do
healthcheck && return 0
sleep 1
done
return 1
}
stop() {
ebegin "Stopping ${RC_SVCNAME}"
"${command}" stop
eend $?
}
reload() {
ebegin "Reloading ${RC_SVCNAME}"
"${command}" reload
eend $?
}

2
net-misc/gmid/Manifest
View File

@@ -1,2 +1,4 @@
DIST gmid-2.0.1.sha256.sig 239 BLAKE2B b118bd39fc529a05112f405589ce2d1c44d4436b19edecb388709ff2cfe4f49ec15506082da6e8a9aecba7cd9ed2d308aafef5432f1692145d6eabe3b5e53683 SHA512 83eff56ffec7ed55338dfe1e48d670779008c523634c86050a63f333ed328541dcaeb1a0d3fccb01bdf2f6d3bbea20c2898bfbd115ee7590203c04bd24baa064
DIST gmid-2.0.1.tar.gz 182989 BLAKE2B 4973711ee94babd0b0f470cf84f460343c39867753858817b7262d8ca3947e79b2e20fe004627e8acf00728a3b43db4bfddf446115acca8eadf190dcc6ef533f SHA512 38d29775968c40fe174b8ead3393c3cd77dd535dae18d3051eb9b98b248a56929d84909c07c3405ddc6035e7d1fc66ea856a2a1dd96e53ac8d30fd231c764478
DIST gmid-2.0.2.sha256.sig 239 BLAKE2B e7f6e6c0f21e10b5bc08b5b72747036ab2b7f1ce820bbf45b3bb4e589d83a6fa1d49e20b95acf3148dcf20608272d48ff2de99ea7fae5b2071a0b7c14539b0cc SHA512 482d8673b140c1a3d0b1a4bc9fd11d74d1bdf968e5d69682c911ff1ea587cfb4e66bafb5817f5286d570f48774d1e13c98939f35afdb69be2f81868dc7560df2
DIST gmid-2.0.2.tar.gz 182867 BLAKE2B edceadfdccbd2e1c90ec4059062f3fc9feaa0c8d5efede5e51a917604eb7ec7537eff25e1a53223fc0fb13645c7fd3be7e3d4545ea14c7cafc1b0f409c949616 SHA512 dd5ab9b1eb7d1ea82fb935099d05f4e606c9e4e112baf132dad72abe5469b2ade2a4a650c5bad7675ca46601721dd5f0a8ebb91b356af90aed9e11c487fd2f7d

111
net-misc/gmid/gmid-2.0.2.ebuild Normal file
View File

@@ -0,0 +1,111 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
SSL_DAYS=36500
SSL_CERT_MANDATORY=1
VERIFY_SIG_METHOD="signify"
inherit edo ssl-cert systemd toolchain-funcs verify-sig
DESCRIPTION="Simple and secure Gemini server"
HOMEPAGE="https://gmid.omarpolo.com"
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://git.omarpolo.com/${PN} https://github.com/omar-polo/${PN}.git"
inherit git-r3
else
SRC_URI="https://ftp.omarpolo.com/${P}.tar.gz
verify-sig? ( https://ftp.omarpolo.com/${P}.sha256.sig )"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="BSD ISC MIT"
SLOT="0"
IUSE="seccomp test"
RESTRICT="!test? ( test )"
DEPEND="
acct-user/gemini
dev-libs/libevent:=
dev-libs/openssl:=
!elibc_Darwin? ( dev-libs/libbsd )
"
RDEPEND="${DEPEND}"
BDEPEND="
virtual/pkgconfig
app-alternatives/yacc
seccomp? ( sys-kernel/linux-headers )
"
if [[ ${PV} != 9999 ]]; then
BDEPEND+="verify-sig? ( sec-keys/signify-keys-gmid:$(ver_cut 1-2) )"
fi
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/${PN}-$(ver_cut 1-2).pub"
DOCS=( README.md ChangeLog contrib/README )
# not an autoconf configure script
QA_CONFIG_IMPL_DECL_SKIP=( "*" )
src_unpack() {
if [[ ${PV} == 9999 ]]; then
git-r3_src_unpack
else
if use verify-sig; then
# Too many levels of symbolic links
cp "${DISTDIR}"/${P}.{sha256.sig,tar.gz} "${WORKDIR}" || die
cd "${WORKDIR}" || die
verify-sig_verify_signed_checksums \
${P}.sha256.sig sha256 ${P}.tar.gz
fi
default
fi
}
src_configure() {
local conf_args
tc-export CC
# note: not an autoconf configure script
conf_args=(
--prefix="${EPREFIX}"/usr
--mandir="${EPREFIX}"/usr/share/man
--sysconfdir="${EPREFIX}"/etc
--with-libtls=bundled
$(use_enable seccomp sandbox)
)
edo ./configure "${conf_args[@]}"
if use seccomp && has usersandbox ${FEATURES}; then
export SKIP_RUNTIME_TESTS=1
fi
}
src_install() {
default
insinto /etc/gmid
newins "${FILESDIR}"/gmid.conf-r1 gmid.conf
insinto /usr/share/vim/vimfiles
doins -r contrib/vim/*
systemd_dounit "${FILESDIR}"/gmid.service
newinitd "${FILESDIR}"/gmid.initd gmid
newconfd "${FILESDIR}"/gmid.confd gmid
keepdir /var/gemini/localhost
}
pkg_postinst() {
if [[ ! -f "${EROOT}"/etc/ssl/${PN}/${PN}.key ]]; then
install_cert /etc/ssl/${PN}/${PN}
chown gemini:gemini "${EROOT}"/etc/ssl/${PN}/${PN}.{crt,csr,key,pem}
fi
einfo "This gemini server can be run as a user with zero configuration.\n"
einfo "In order to use it with the init service you will need to generate a"
einfo "self-signed TLS certificate and a key and set up the configuration"
einfo "file (see man 1 gmid for details)."
}

1
net-p2p/gridcoin/Manifest Normal file
View File

@@ -0,0 +1 @@
DIST gridcoin-5.4.7.0.tar.gz 42846185 BLAKE2B 2d6d0858fc34611878e19ada2066d38e00abde55037a1eecc8f2c28d8db1d10c1297177c1b6b74ef0ce2630bea67075ff6fd47b6a8830465007a5860f789aae1 SHA512 042250d89151492796f8a294c83aa756fb9fbed6d62302a9d7037180d18d67b582eb0ba4fc4c9340e0d07ad9f0cd0f5dfeddc76f4c08bf417c73cb6b12a12ca2

104
net-p2p/gridcoin/gridcoin-5.4.7.0.ebuild Normal file
View File

@@ -0,0 +1,104 @@
# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake db-use multilib xdg-utils
DESCRIPTION="Proof-of-Stake based cryptocurrency that rewards BOINC computation"
HOMEPAGE="https://gridcoin.us/ https://gridcoin.world/"
SRC_URI="https://github.com/${PN}-community/${PN^}-Research/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN^}-Research-${PV}"
LICENSE="BSD BSD-2 Boost-1.0 MIT SSLeay"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+asm dbus gui qrcode test +upnp"
IUSE+=" cpu_flags_arm_neon cpu_flags_x86_avx2 cpu_flags_x86_sha cpu_flags_x86_sse4_1"
RESTRICT="!test? ( test )"
REQUIRED_USE="
dbus? ( gui )
qrcode? ( gui )
"
BDB_SLOT="5.3"
RDEPEND="
>=dev-libs/boost-1.63.0:=[zlib(+)]
>=dev-libs/libsecp256k1-0.2.0:=[recovery(+)]
>=dev-libs/leveldb-1.21:=
dev-libs/libzip:=
dev-libs/openssl:=
dev-libs/univalue
net-misc/curl[ssl]
sys-libs/db:${BDB_SLOT}[cxx]
gui? (
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
dbus? ( dev-qt/qtdbus:5 )
qrcode? ( media-gfx/qrencode:= )
)
upnp? ( net-libs/miniupnpc:= )
"
DEPEND="${RDEPEND}
test? ( gui? ( dev-qt/qttest:5 ) )
"
BDEPEND="
virtual/pkgconfig
gui? ( dev-qt/linguist-tools:5 )
test? ( app-editors/vim-core )
"
IDEPEND="gui? ( dev-util/desktop-file-utils )"
src_configure() {
local mycmakeargs=(
-DENABLE_DAEMON=$(usex !gui)
-DENABLE_GUI=$(usex gui)
-DENABLE_TESTS=$(usex test)
-DENABLE_SSE41=$(usex cpu_flags_x86_sse4_1)
-DENABLE_AVX2=$(usex cpu_flags_x86_avx2)
-DENABLE_X86_SHANI=$(usex cpu_flags_x86_sha)
-DENABLE_ARM_SHANI=$(usex cpu_flags_arm_neon)
-DUSE_ASM=$(usex asm)
-DENABLE_QRENCODE=$(usex qrcode)
-DENABLE_UPNP=$(usex upnp)
-DDEFAULT_UPNP=$(usex upnp)
-DUSE_DBUS=$(usex dbus)
-DSYSTEM_BDB=ON
-DBerkeleyDB_INCLUDE_DIR="$(db_includedir ${BDB_SLOT})"
-DBerkeleyDB_CXX_LIBRARY="${ESYSROOT}/usr/$(get_libdir)/libdb_cxx-${BDB_SLOT}$(get_libname)"
-DSYSTEM_LEVELDB=ON
-DSYSTEM_SECP256K1=ON
-DSYSTEM_UNIVALUE=ON
-DSYSTEM_XXD=ON
)
cmake_src_configure
}
src_install() {
cmake_src_install
mkdir -p "${ED}"/usr/share/man/man1 || die
mv "${ED}"{/usr/share/man/gridcoinresearch.1,/usr/share/man/man1} || die
}
pkg_postinst() {
# we don't use xdg.eclass because it adds unconditional IDEPENDs
if use gui; then
xdg_desktop_database_update
xdg_icon_cache_update
fi
}
pkg_postrm() {
if use gui; then
xdg_desktop_database_update
xdg_icon_cache_update
fi
}

14
net-p2p/gridcoin/metadata.xml Normal file
View File

@@ -0,0 +1,14 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="person">
<email>cyber+gentoo@sysrq.in</email>
<name>Anna</name>
</maintainer>
<upstream>
<remote-id type="github">gridcoin-community/Gridcoin-Research</remote-id>
</upstream>
<use>
<flag name="qrcode">Enable generation of QR Codes for receiving payments</flag>
</use>
</pkgmetadata>

3
net-wireless/bluetuith/bluetuith-0.2.2.ebuild
View File

@@ -34,6 +34,9 @@ RESTRICT="test"
RDEPEND="
net-wireless/bluez
"
BDEPEND="
$(unpacker_src_uri_depends)
"
src_unpack() {
if [[ ${PV} == 9999* ]]; then

3
net-wireless/bluetuith/bluetuith-9999.ebuild
View File

@@ -34,6 +34,9 @@ RESTRICT="test"
RDEPEND="
net-wireless/bluez
"
BDEPEND="
$(unpacker_src_uri_depends)
"
src_unpack() {
if [[ ${PV} == 9999* ]]; then

2
phosh-base/phosh-mobile-settings/Manifest
View File

@@ -1,2 +1,4 @@
DIST phosh-mobile-settings-0.36.0.tar.xz 185628 BLAKE2B bed3c8dcd278e44e9beaec29c98e8ac5847377749ff18cc1e0d58f3f7178ae56b0642ae2c6ff89f5a724a9878da6660e6b60b2a4734a8d4d1feeb6f85dfa07db SHA512 f899105719908a044ac85d326288eec8dcaa2e5a8c27cffa1ad9354896f85c96b44f8114c08c4f7be6955faf79e32c7f26977a70c9d99a6b4654a8cd6d6db443
DIST phosh-mobile-settings-0.36.0.tar.xz.asc 833 BLAKE2B 749625bae2a1bafc77ad5867b65a0a526dd5c9da25eebe9967fea816e30855f98e5bfec61c7cfcad3019fcb32290a262dbc108902bc969787e02d9be11e405f6 SHA512 bbe173ae4f34757963637c9e26bc0dd8d0ee60ea789a894b4732e572eaa25762605d79351f6e0e1b330e51dcc3dc9538b2e70ee98b679f46ea9d95df0e0906c0
DIST phosh-mobile-settings-0.38.0.tar.xz 197692 BLAKE2B df92c780943fcd441b6709e5a9722e02e0b08f27b3355b0621ff3ee626276af53988b9a2bf8047bc3cf14c73691a01b8502c1952795e2388fe29652c16cef3be SHA512 7406ca631d0bb2d51bf405ffb1820496bbd3349927b677b208d623d7a792dbfbd5f6bfd6edc31bb3009490e4ea6c860660df5d983861d929b7b9300d69c8f9e8
DIST phosh-mobile-settings-0.38.0.tar.xz.asc 833 BLAKE2B baab43631489a35bcea287b096dfcbaa0379bb7499c0f50006372c4e1138b545f7253cd9172eae3598840c5f9eb8be5590cc7d7b506e6c148705a04c9ff3fe54 SHA512 9af93755cd5aa0e265b97e999d692dd00ad923c4a676da33d72248cb352c2d818fe299926c8bea0799255156cc29bb2bb6c7bc7efc31202aacf29124f7f9ad1b

2
phosh-base/phosh-mobile-settings/phosh-mobile-settings-0.36.0.ebuild
View File

@@ -36,7 +36,7 @@ BDEPEND="
verify-sig? ( sec-keys/openpgp-keys-phosh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/phosh.asc"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
QA_DESKTOP_FILE="usr/share/applications/mobi.phosh.MobileSettings.desktop"

60
phosh-base/phosh-mobile-settings/phosh-mobile-settings-0.38.0.ebuild Normal file
View File

@@ -0,0 +1,60 @@
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome2-utils meson verify-sig xdg
DESCRIPTION="Mobile Settings App for phosh and related components"
HOMEPAGE="https://gitlab.gnome.org/guidog/phosh-mobile-settings"
SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
>=dev-libs/glib-2.74:2
>=dev-libs/json-glib-1.6.2
>=dev-libs/wayland-1.14
>=gui-libs/gtk-4.12.5:4[wayland]
>=gui-libs/libadwaita-1.4:1
media-libs/gsound
phosh-base/phosh-shell
sys-apps/lm-sensors:=
"
DEPEND="${RDEPEND}
>=dev-libs/wayland-protocols-1.12
"
BDEPEND="
dev-libs/glib:2
dev-util/gdbus-codegen
dev-util/glib-utils
dev-util/wayland-scanner
sys-devel/gettext
verify-sig? ( sec-keys/openpgp-keys-phosh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
QA_DESKTOP_FILE="usr/share/applications/mobi.phosh.MobileSettings.desktop"
src_test() {
# No useful tests
:
}
src_install() {
meson_src_install --skip-subprojects gmobile
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}

2
phosh-base/phosh-osk-stub/Manifest
View File

@@ -1,2 +1,4 @@
DIST phosh-osk-stub-0.36.0.tar.xz 304016 BLAKE2B 279e1dd69e5a7b63bf4c7fb42d415a3a306b57121020add96050eebd98053c18592ca994d098e2018216e926e7d78cc38992586beeff9bd3a1d41c9beaf9cabb SHA512 8482a1d6f6c94c7a73a1c7359f786fc0d30da4e7506413a2390c483e294cda7af708916dc55ea8e352ef115490b7ba187499c0c8e64aec9e2bc9a6c6e7142d85
DIST phosh-osk-stub-0.36.0.tar.xz.asc 833 BLAKE2B 61ad2f9d3511bad7c6423c851bae5738c2b7d4e023a550f4fb06a94df975c9b3a58ffdbb59ffbb5281e7e38d81f910fee8f262a06c4291fb7bc02fca8e449daa SHA512 9f842c0e944c5a1f2db89efc32661b4e9c4ec919760d44cb172101549418a698a152689c3fa29ae0d3cad43f6deb11e955971dc8158555c159b0d5e8e9546023
DIST phosh-osk-stub-0.38.0.tar.xz 310460 BLAKE2B 2d7b24bc35975af5a0646897a4a97868dc4ef97bfe3b573765e228e73e6c093726ed188c22908a9352346be2b92f7b5d3e75059ecf591b819937c01522ede433 SHA512 6f16c606d03263c23ba4081b323104d04efb9d750c725750c46b9dc34819cf38bb032a55d6213891b7579d2bc9776641567488ac39fed63913c37af77f7b162f
DIST phosh-osk-stub-0.38.0.tar.xz.asc 833 BLAKE2B c1e5bd79c68d83e004f11fec25879279d251c95a24c80e10bac8549e4cbf6dfbcc68daba2223d7a8033b709357c162be9a7a64c86119aac798f08c9e41459266 SHA512 03b3d2b0f984b9ddc4d989e78ff2707e41401dc7682c29c6bc3d8d0ad8ff3d4e2ffbbf167b4b70b24d77d38328d1a806f46131405fea50370c647019d41ea556

2
phosh-base/phosh-osk-stub/phosh-osk-stub-0.36.0.ebuild
View File

@@ -51,7 +51,7 @@ BDEPEND="
verify-sig? ( sec-keys/openpgp-keys-phosh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/phosh.asc"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
QA_DESKTOP_FILE="usr/share/applications/sm.puri.Phosh.OskStub.desktop"

90
phosh-base/phosh-osk-stub/phosh-osk-stub-0.38.0.ebuild Normal file
View File

@@ -0,0 +1,90 @@
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome2-utils meson virtualx verify-sig xdg
DESCRIPTION="On-screen keyboard stub"
HOMEPAGE="https://gitlab.gnome.org/guidog/phosh-osk-stub"
SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"
IUSE="elogind gtk-doc man test"
RESTRICT="!test? ( test )"
# TODO: package govarnam
# TODO: hunspell is automagic
COMMON_DEPEND="
app-shells/fzf
app-text/hunspell:=
>=dev-libs/glib-2.66:2
dev-libs/feedbackd
dev-libs/json-glib
>=dev-libs/wayland-1.14
>=gnome-base/gnome-desktop-3.26:3
>=gui-libs/libhandy-1.1.90:1
>=x11-libs/gtk+-3.22:3[wayland]
x11-libs/libxkbcommon[wayland]
elogind? ( >=sys-auth/elogind-241 )
!elogind? ( >=sys-apps/systemd-241:= )
"
DEPEND="${COMMON_DEPEND}
>=dev-libs/wayland-protocols-1.12
"
RDEPEND="${COMMON_DEPEND}
gnome-base/gsettings-desktop-schemas
"
BDEPEND="
dev-libs/glib:2
dev-libs/libxml2:2
dev-util/gdbus-codegen
dev-util/glib-utils
dev-util/wayland-scanner
sys-devel/gettext
gtk-doc? ( dev-util/gi-docgen )
man? ( dev-python/docutils )
test? ( dev-libs/json-glib )
verify-sig? ( sec-keys/openpgp-keys-phosh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
QA_DESKTOP_FILE="usr/share/applications/sm.puri.Phosh.OskStub.desktop"
src_configure() {
local emesonargs=(
-Ddefault_osk=false
$(meson_use gtk-doc gtk_doc)
$(meson_use man)
$(meson_use test tests)
)
meson_src_configure
}
src_test() {
virtx meson_src_test
}
src_install() {
meson_src_install
if use gtk-doc; then
mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
mv "${ED}"/usr/share/doc/pos-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
fi
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}

2
phosh-base/phosh-shell/Manifest
View File

@@ -1,2 +1,4 @@
DIST phosh-0.36.0.tar.xz 839440 BLAKE2B a6aa1c6fc2356055b0a451cb66fcfcbf3329059ab620aa56122e63e5eafc7f43ff1b1e4842fcadd7506f4724dbbab6e4785c6fb9b9e669e888c427be9163f0ab SHA512 e108423c97343917b4be1827c44642e90738027b543bdc4bf2f45073101383227a157771a9efdf0b65a9adf30a09d1111210be21d35043ced8a9046fe70588e2
DIST phosh-0.36.0.tar.xz.asc 833 BLAKE2B 1dcdfd6cd0708f60408a34bd2df891db4050de02c9349d5517fe23b2e17e0fb0fdfe97e3f86f5b30fb47c871932bd67310b889ce4d03b32408c7704d7ea31ce4 SHA512 c1ceac2eaad073b79f342915205f0539454f789eb6cb8aaae5fa4847bfac60641822796ee0adc83970af7ee6d6e57248bba48a718a05da1d2123984c4a3c9b91
DIST phosh-0.38.0.tar.xz 866816 BLAKE2B 22be8e8a673494da7795270d7fb7fff2bfb87762b8cce9540d2f8644ded760ee2ac8a75d8052eb46172d6f5764e020ef949330ed14f5cc645cef586e26b5a398 SHA512 dfde54b64ea6edba2b66dfe2f5ff0f4b3edbb192b1a37fbc8c98d9365bdedc5d19ddb1464673e516cb8e436a6c0ea00c84087cc6431b6c1862019f90e02b73ce
DIST phosh-0.38.0.tar.xz.asc 833 BLAKE2B d9c49a42bc5083678e3195eb6fded80455312887b0c0f99dd03c6662d3c01bec228b0c68f7044dfe86fe1473b8ddbaf797729a5a92fbbbb5c8d18302149376dd SHA512 8007c2f58c311659310d06962ad825c51fb90f4da864f110db5b1f0f5d7c70b0ef69ddbfa169489657b3088ed6b89dbdf7e910101267ccd307578d75f9301b46

4
phosh-base/phosh-shell/phosh-shell-0.36.0.ebuild
View File

@@ -13,9 +13,9 @@ SRC_URI="https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz
verify-sig? ( https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz.asc )"
S="${WORKDIR}/${MY_P}"
KEYWORDS="~amd64 ~arm64"
LICENSE="CC0-1.0 CC-BY-SA-4.0 GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+ MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="elogind gtk-doc +lockscreen-plugins man test test-full"
REQUIRED_USE="test? ( lockscreen-plugins )"
@@ -77,7 +77,7 @@ BDEPEND="
verify-sig? ( sec-keys/openpgp-keys-phosh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/phosh.asc"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
src_configure() {
local emesonargs=(

138
phosh-base/phosh-shell/phosh-shell-0.38.0.ebuild Normal file
View File

@@ -0,0 +1,138 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome2-utils meson pam systemd verify-sig virtualx xdg
MY_PN="${PN%-shell}"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="Pure Wayland shell for mobile devices"
HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phosh/"
SRC_URI="https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz
verify-sig? ( https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz.asc )"
S="${WORKDIR}/${MY_P}"
LICENSE="CC0-1.0 CC-BY-SA-4.0 GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+ MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="elogind gtk-doc +lockscreen-plugins man test test-full"
REQUIRED_USE="test? ( lockscreen-plugins )"
COMMON_DEPEND="
>=app-crypt/gcr-3.7.5:0
app-crypt/libsecret
>=dev-libs/feedbackd-0.2.0
dev-libs/fribidi
>=dev-libs/glib-2.76:2
>=dev-libs/json-glib-1.6.2
dev-libs/libgudev:=
>=dev-libs/wayland-1.14
>=gnome-base/gnome-desktop-3.26:3
>=gnome-base/gsettings-desktop-schemas-42
>=gnome-extra/evolution-data-server-3.33.1:=
>=gui-libs/libhandy-1.1.90:1
media-libs/libpulse[glib]
media-sound/callaudiod
net-libs/libsoup:3.0
>=net-misc/networkmanager-1.14
sys-apps/dbus
>=sys-auth/polkit-0.105
sys-libs/pam
>=sys-power/upower-0.99.1:=
>=x11-libs/gtk+-3.22:3[wayland]
elogind? ( >=sys-auth/elogind-241 )
!elogind? ( >=sys-apps/systemd-241:= )
lockscreen-plugins? (
app-text/evince:=
gui-libs/gtk:4
gui-libs/libadwaita:1
)
"
RUNTIME_DEPEND="
gnome-base/gnome-shell
virtual/freedesktop-icon-theme
x11-themes/gnome-themes-standard
"
DEPEND="
${COMMON_DEPEND:?}
>=dev-libs/wayland-protocols-1.12
test-full? ( ${RUNTIME_DEPEND:?} )
"
RDEPEND="
${COMMON_DEPEND:?}
${RUNTIME_DEPEND:?}
!elogind? ( sys-libs/libcap )
"
BDEPEND="
dev-libs/glib:2
dev-libs/libxml2
dev-util/gdbus-codegen
dev-util/glib-utils
dev-util/wayland-scanner
sys-devel/gettext
gtk-doc? ( dev-util/gi-docgen )
man? ( dev-python/docutils )
test-full? ( >=gui-wm/phoc-0.36.0-r1 )
verify-sig? ( sec-keys/openpgp-keys-phosh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
src_configure() {
local emesonargs=(
-Dcompositor="${EPREFIX}"/usr/bin/phoc
-Dtools=true
-Dquick-setting-plugins=true
$(meson_use !elogind systemd)
$(meson_use gtk-doc gtk_doc)
$(meson_use lockscreen-plugins)
$(meson_use man)
$(meson_use test tests)
$(meson_feature test-full phoc_tests)
)
meson_src_configure
}
src_test() {
local -x LC_ALL="C.UTF-8"
local -x WLR_RENDERER="pixman"
virtx meson_src_test --suite unit
if use test-full; then
virtx meson_src_test --suite integration
fi
}
src_install() {
meson_src_install --skip-subprojects gmobile
pamd_mimic system-local-login phosh auth account session
systemd_douserunit data/phosh.service
if use gtk-doc; then
mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
mv "${ED}"/usr/share/doc/${MY_PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
fi
}
phosh_giomodule_cache_update() {
local plugins_dir
plugins_dir=$(pkg-config --variable=lockscreen_plugins_dir phosh-plugins) || return 1
ebegin "Updating GIO modules cache"
gio-querymodules "${plugins_dir}"
eend $?
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
phosh_giomodule_cache_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
phosh_giomodule_cache_update
}

3
phosh-base/phosh-tour/Manifest
View File

@@ -1,3 +1,4 @@
DIST phosh-tour-0.36.0.tar.xz 113636 BLAKE2B 21803419b5e70d7fbb38da23d266905eb254b7f38653d222b7da062c603071ff682a4c92ec673e50850d4cdadc5fc82c2b59fa7d1c87d9a5827bc12ab4f0a35b SHA512 c0d493be60462fe801a72d957ab2f36aafd7fcb5a515f087094ca9723889b8725c241d251cf5e6a0fe2b895417b8779b3c4efe19eb8372e4da9ec812b849dc15
DIST phosh-tour-0.36.0.tar.xz.asc 833 BLAKE2B 5501484621f4aa76f4a4f71c65d6c1469d521e1e0b01427180b6753b9c20d7aa07e72cd75c43eee08fa7e6493a07c6b8f671c539afca389d44f5fe836731469b SHA512 a243fe4ea2933bc3b4de46ce23e29571a620db6e8c415e16f928f5c6a9c821c6c87146dec85832d36cd1d68349054a12888f1f67ee4fdcbfc6fee7fb01add7aa
DIST phosh-tour-v0.35.0.tar.bz2 121098 BLAKE2B cd229c7d7a406dd4cea1a4e5bdf6c271f93025c2337d974873995c7b000316d7d210dcf729955d3c49dbb6360f79d1d28d6198c257142dd252cf263ab1089693 SHA512 af435e228f4a3151accf122faf7eb33d1198ccc890fee8d45e9005dfa3887a5fd0ae7a931756a707bcbe0511c20a54e1adf967873dca126f9904bf43174769c3
DIST phosh-tour-0.38.0.tar.xz 151456 BLAKE2B 24335f40cf358ce706f19cab08afb6c9e2176fed533f8bc8a43ac6b8d1d64d4a5c8874e5a857070e846dbd857ed0aecbe516366bdbc7708dcb6c2c5abeef6a43 SHA512 27462565c96071bf3877cc823b09b61ee739904d6df75e5da0cf57f3a89fa51a35c7a81201228194d44a125480a484e8fd7cfaa640ede0b464a93d13bfcb488d
DIST phosh-tour-0.38.0.tar.xz.asc 833 BLAKE2B 1afa17d9be38d2717caaef67cd66021616ba07ff26180580b8c353b698cc92293dc6e04d183ffd7f9db7b18def277ceadbbe82bfd99aec1feea53780f281b449 SHA512 17039d7debbbcde2fc2e178186e30ca14e3eaad4e3577be7eba7b098f43031b27e08cf629274a46b794dccb4f82e0f19dfb6d66d6e33e5c2495f62c64d0f02e7

2
phosh-base/phosh-tour/phosh-tour-0.36.0.ebuild
View File

@@ -27,7 +27,7 @@ BDEPEND="
)
"
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/phosh.asc"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
QA_DESKTOP_FILE="usr/share/applications/mobi.phosh.PhoshTour.desktop"

27
phosh-base/phosh-tour/phosh-tour-0.35.0.ebuild → phosh-base/phosh-tour/phosh-tour-0.38.0.ebuild
View File

@@ -3,25 +3,32 @@
EAPI=8
inherit gnome2-utils meson xdg
inherit gnome2-utils meson verify-sig xdg
MY_P="${PN}-v${PV}"
DESCRIPTION="Introduction to phosh on smartphones"
HOMEPAGE="https://gitlab.gnome.org/guidog/phosh-tour"
SRC_URI="https://gitlab.gnome.org/guidog/${PN}/-/archive/v${PV}/${MY_P}.tar.bz2"
S="${WORKDIR}/${MY_P}"
SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"
DEPEND="
dev-libs/glib:2
>=gui-libs/gtk-4.4:4
>=gui-libs/libadwaita-1.1:1
>=dev-libs/glib-2.74:2
>=gui-libs/gtk-4.12:4
>=gui-libs/libadwaita-1.4:1
"
RDEPEND="${DEPEND}"
BDEPEND="sys-devel/gettext"
BDEPEND="
dev-libs/libxml2
sys-devel/gettext
verify-sig? (
sec-keys/openpgp-keys-phosh
)
"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
QA_DESKTOP_FILE="usr/share/applications/mobi.phosh.PhoshTour.desktop"
@@ -38,6 +45,10 @@ src_test() {
:
}
src_install() {
meson_src_install --skip-subprojects gmobile
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update

4
phosh-base/phosh/metadata.xml
View File

@@ -5,4 +5,8 @@
<email>cyber+gentoo@sysrq.in</email>
<name>Anna</name>
</maintainer>
<use>
<flag name="desktop-portal">Enable <pkg>sys-apps/xdg-desktop-portal</pkg> backend implementation</flag>
<flag name="iio">Enable support for IIO sensors via <pkg>gnome-extra/iio-sensor-proxy</pkg></flag>
</use>
</pkgmetadata>

31
phosh-base/phosh/phosh-0.38.0.ebuild Normal file
View File

@@ -0,0 +1,31 @@
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DESCRIPTION="Meta package for Phosh, merge this package to install"
HOMEPAGE="https://phosh.mobi/"
LICENSE="metapackage"
SLOT="0"
KEYWORDS="~amd64"
IUSE="cups +desktop-portal geolocation iio"
RDEPEND="
app-alternatives/phosh-keyboard
dev-libs/feedbackd[daemon]
gnome-base/gnome-core-libs[cups?]
>=gui-wm/phoc-${PV}
media-fonts/cantarell
>=phosh-base/phosh-mobile-settings-${PV}
>=phosh-base/phosh-shell-${PV}
>=phosh-base/phosh-tour-${PV}
x11-themes/gnome-backgrounds
x11-themes/sound-theme-freedesktop
desktop-portal? (
gui-libs/xdg-desktop-portal-wlr
sys-apps/xdg-desktop-portal-gtk
)
geolocation? ( app-misc/geoclue:2.0 )
iio? ( gnome-extra/iio-sensor-proxy )
"

1
profiles/updates/2Q-2024
View File

@@ -1,2 +1,3 @@
move dev-util/cargo-make dev-build/cargo-make
move app-text/md4c dev-libs/md4c
move dev-util/xmake dev-build/xmake

3
sec-keys/signify-keys-telescope/Manifest
View File

@@ -1,2 +1,3 @@
DIST telescope-0.7.pub 101 BLAKE2B b8e570c28fe03c538e99bc4b1a49dd28ac999bcfb16d23a08c9d489a56a8b454fdd0eb6d5afffd48bfa0e9b0fe00d193f916316caeb6b09bf5f378903377c2e1 SHA512 6cd51e98fcafb5719220c8b82cbf833d258469e0be12099a3a528db0f56653a80da3de299b70d1b889cbc76fb91bffbe60b205b4fe94891c1318a385e5ebe0e4
DIST telescope-0.10.pub 95 BLAKE2B 8e79de6da956e7de25994fbca4949b431c792a1c77317c76a04218e065b27d25758d42dbadc5c57e3c35477a60ea9224cf6ca48e77bab9445601df2ee22479c7 SHA512 92e5839684de4cf2c91972d14ee914bb67b4b1f8b083bf60328c90c4beb8968646708269a7bbffb052fefde4c8454a602b021cea5844b88cde9d377c18902639
DIST telescope-0.8.pub 95 BLAKE2B 51db0037fb1739fc087163650c8a76f02ef5f8122b0462ca114b63441f09f032ee28dc281c7260c6f286cfd51bac7e1fc7fc6918b38bd3c0b5d296656881000b SHA512 c8eeda00e65a30c75e4c4c7bec999ee37a8122ec93c4e1c444f980fb82e0c91984455c5300b49a2da35418aef4e184c421141662a9bb8be40841307029e96577
DIST telescope-0.9.pub 95 BLAKE2B 5b65eb226db41efc31502e6b4e190aab4ec59b00206da3944028d2af0b0ebe8e0ae48a532238da79c370e2b148ff6b50ca212889799fea1fc0a0b0aee4f807d6 SHA512 c3b316d31fac4f586e0db922628529f8d64f3addc7f80b6be3a01a5b62065607351a998868fc34f581d794e563d72feaf84dd8faa6dba1b417a67d6ee8ecf211

12
sec-keys/signify-keys-telescope/signify-keys-telescope-0.7.ebuild → sec-keys/signify-keys-telescope/signify-keys-telescope-0.10.ebuild
View File

@@ -1,18 +1,16 @@
# Copyright 1999-2022 Gentoo Authors
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PN="${PN#signify-keys-}"
MY_PV="$(ver_cut 1-2)"
MY_P="${MY_PN}-${MY_PV}"
MY_P="${PN#signify-keys-}-${PV}"
DESCRIPTION="Signify keys used to sign telescope releases"
HOMEPAGE="https://github.com/omar-polo/telescope"
SRC_URI="https://github.com/omar-polo/${MY_PN}/releases/download/${PV}/${MY_P}.pub"
HOMEPAGE="https://telescope.omarpolo.com/"
SRC_URI="https://ftp.omarpolo.com/${MY_P}.pub"
S="${WORKDIR}"
LICENSE="public-domain"
SLOT="${MY_PV}"
SLOT="${PV}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
src_install() {

21
sec-keys/signify-keys-telescope/signify-keys-telescope-0.9.ebuild Normal file
View File

@@ -0,0 +1,21 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_P="${PN#signify-keys-}-${PV}"
DESCRIPTION="Signify keys used to sign telescope releases"
HOMEPAGE="https://telescope.omarpolo.com/"
SRC_URI="https://ftp.omarpolo.com/${MY_P}.pub"
S="${WORKDIR}"
LICENSE="public-domain"
SLOT="${PV}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
src_install() {
local files=( ${A} )
insinto /usr/share/signify-keys
newins - ${MY_P}.pub < <(cat "${files[@]/#/${DISTDIR}/}" || die)
}

1
www-apps/vaultwarden-web/vaultwarden-web-2024.3.1.ebuild
View File

@@ -25,6 +25,7 @@ KEYWORDS="~amd64"
RDEPEND="!www-apps/vaultwarden-web-bin"
BDEPEND="
${PYTHON_DEPS}
$(unpacker_src_uri_depends)
net-libs/nodejs[npm]
"