dev-scheme/cozenage: new package, add 0.19.1

Signed-off-by: Darren Kirby <bulliver@gmail.com>
Part-of: https://github.com/gentoo/guru/pull/545
Closes: https://github.com/gentoo/guru/pull/545
Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-scheme/cozenage/Manifest

@@ -0,0 +1 @@
+DIST cozenage-0.19.1.tar.xz 352376 BLAKE2B 974951bfe6f16e2697c36ad284a2340f45e3ed47a42e75f5d4d0c7fc38d65cea869f58e7b87a5e2859d09b8c57018e183d5ea79c2e8c15935f83848e69085284 SHA512 bdcf64816705d542257e9cd4c1324cfecd031134000dadafb9d00d6e0c66d362699c41b1ae293bf36d92aadce7a060d9cb846062724035767c9b4b6aee30d2c8

dev-scheme/cozenage/cozenage-0.19.1.ebuild

@@ -0,0 +1,45 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="A Scheme-derived Lisp written in C"
+HOMEPAGE="https://github.com/DarrenKirby/cozenage"
+SRC_URI="https://github.com/DarrenKirby/cozenage/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="dev-libs/icu
+		dev-libs/boehm-gc
+		dev-libs/gmp
+		dev-libs/openssl"
+RDEPEND="${DEPEND}"
+BDEPEND=" test? ( dev-libs/criterion ) "
+
+src_prepare() {
+	default
+
+	# Strip AddressSanitizer from tests as it conflicts with Portage's LD_PRELOAD sandbox.
+	# Strip -Werror per Gentoo QA policy to prevent build failures on future GCC bumps.
+	sed -i \
+		-e 's/-fsanitize=address//g' \
+		-e 's/-Werror//g' \
+		Makefile || die
+}
+
+src_test() {
+	emake test
+	./run_tests
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+	# install documentation
+	dodoc *.md
+	doman docs/cozenage.1
+}

dev-scheme/cozenage/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>bulliver@gmail.com</email>
+		<name>Darren Kirby</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">DarrenKirby/cozenage</remote-id>
+	</upstream>
+</pkgmetadata>