phosh-base/phosh-osk-stub: add 0.42.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

phosh-base/phosh-osk-stub/Manifest

@@ -2,3 +2,5 @@ DIST phosh-osk-stub-0.41.0.tar.xz 317516 BLAKE2B 2a17399c2966983e96051a048bfe9dd
 DIST phosh-osk-stub-0.41.0.tar.xz.asc 833 BLAKE2B 66075735b50ca4eabad8851618d3c9d1d9f1da057b5e80e307efd502d28e6185ec4709c2296645831cff7151478daabcbbbae42f474a811ee37bc94dd4051c3c SHA512 60852c5890612f7cb74eb976074c5fc7c0f14cf91a46b871ef622bdd9edecc29f4e3cf1be0fc1bae9422db139f257b30110c790bf76275614e8d69f30c7806df
 DIST phosh-osk-stub-0.41.1.tar.xz 317632 BLAKE2B caff385e44fe9c59fd371fac8b03e4c1a95f9769f9118ea944cc3cb47401ac10b2ecbd6ec26fd4b49b775df0fa99f7ae9e13fa5620f21cee0d596e917cd01ca1 SHA512 bba73d561b001e620a2d5b5825463f41a946f17284e36e3abe54267362b7dc4ea8c0cd6293b90ce73086a1ef3818863f4f73be7a8724c077275a5377f3d10abf
 DIST phosh-osk-stub-0.41.1.tar.xz.asc 833 BLAKE2B 9eed6487d10ffcc4cc56c44cb2685edfdff9cbcfa2efcaddc5724414ee2e29d84e1898af766325c0d95c9e5cbc7a48c4c9b0e9c90bc25f80ec156e1c81ff849f SHA512 058fff4ed0cd4d404d5364c281d404d0c921fe8f24771a911f5826fdd5095845f26ca2a184854f864415ba005a68dae85836857f4331df4adf7dccd7507aad20
+DIST phosh-osk-stub-0.42.0.tar.xz 322832 BLAKE2B 04b61aee3f052561a9605fc7ef1ab053c9bedfced1f2c4868bc65e09689f105379881a348a2e69efc57d31977f40c397e1bf6137adc2e9aa39dedc6f1f211535 SHA512 bfc8c5d4da07bb44b18d42a548d567baaad54d57d24334e07efcb0baf2d6a56e40bb69ec20082d6c4bd775bea328014a5511256c0e68d4ed1db699ebc1b99345
+DIST phosh-osk-stub-0.42.0.tar.xz.asc 833 BLAKE2B 6708017deee1947e726ba989a7b5f929058f519940f45afad0393ff3db0d2159c53fa0e392cc7f9e002b71dd15817459e11e9b254d525ee9db0a4f42a04256d4 SHA512 34572065a6bd21e726225cf5eff25c6dd93f74990b3187665b31400d58d50c6c455c31b59c13f96c2f6109cf4dee62862cb1145ba5ae487ee0df78ba7e274795

phosh-base/phosh-osk-stub/phosh-osk-stub-0.42.0.ebuild

@@ -0,0 +1,93 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson virtualx verify-sig xdg
+
+DESCRIPTION="On-screen keyboard stub"
+HOMEPAGE="https://gitlab.gnome.org/guidog/phosh-osk-stub"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="elogind gtk-doc man test"
+RESTRICT="!test? ( test )"
+
+# TODO: package govarnam
+# TODO: hunspell is automagic
+COMMON_DEPEND="
+	app-shells/fzf
+	app-text/hunspell:=
+	>=dev-libs/glib-2.80:2
+	>=dev-libs/gmobile-0.2.0
+	dev-libs/feedbackd
+	dev-libs/json-glib
+	>=dev-libs/wayland-1.14
+	>=gnome-base/gnome-desktop-3.26:3
+	>=gui-libs/libhandy-1.1.90:1
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.22:3[wayland]
+	x11-libs/libxkbcommon[wayland]
+	x11-libs/pango
+	elogind? ( >=sys-auth/elogind-241 )
+	!elogind? ( >=sys-apps/systemd-241:= )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/wayland-protocols-1.12
+"
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	test? ( dev-libs/json-glib )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+QA_DESKTOP_FILE="usr/share/applications/sm.puri.Phosh.OskStub.desktop"
+
+src_configure() {
+	local emesonargs=(
+		-Ddefault_osk=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/pos-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}