gnome-extra/extension-manager: Add 0.4.2

Signed-off-by: Yuan Liao <liaoyuan@gmail.com>

gnome-extra/extension-manager/Manifest

@@ -1,2 +1,3 @@
 DIST extension-manager-0.3.2.tar.gz 1447521 BLAKE2B 55d09b54219804c1910a572953d7fee4b8a9131085260db1d4ef014bccf8b13fa2da0a8673c0d78643841d603878183c2b573b084bcd5cb1818721e8194c871b SHA512 84ff2f246d582cdae06a12e5e88309d67ae32502e9885675c08d75dc686fdea28b53bffa37d396ffface8515712f0b990603b5832704ae722342f0ad49748150
 DIST extension-manager-0.4.1.tar.gz 1490668 BLAKE2B ca7c4dabc100d4a8aba8a41ecdec3c88676764b81c2e5fdb64785ca5031a31749d058c1a670867fd1028ae13721d8de0c648fd397f63a56871e11899bca4d4f5 SHA512 3da3ff3f42117ad52eecd99e92d65d8d72b95e07a5488f7184577ab10f749b1cee08a3322316bf2a92a8e2b878ca18e94ce7d986331688eafb520cdb8a0bbf1c
+DIST extension-manager-0.4.2.tar.gz 1469519 BLAKE2B 070016a50f48a89d39c760c7ec60fabc856dcdd7a8fc4a779253ede2354f7d9d6744fa7620e55a92f9ed671a00b8aff1fd9246d7dc919727893215d2f05e0658 SHA512 777c0d83f26064372a721681092ef7990ade028ea2d6bb8bb64aa8a4630cea60f2af07c1cf7d733a8f100fe5d7de5b1aeac2b99d8a585dc715ee469a874c0148

gnome-extra/extension-manager/extension-manager-0.4.2.ebuild

@@ -0,0 +1,87 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson xdg
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mjakeman/extension-manager.git"
+else
+	SRC_URI="https://github.com/mjakeman/extension-manager/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="A native tool for browsing, installing, and managing GNOME Shell Extensions"
+HOMEPAGE="https://mjakeman.github.io/extension-manager/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+BDEPEND="
+	dev-libs/glib:2
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	gui-libs/gtk:4[introspection]
+	>=gui-libs/libadwaita-1.2.0:1[introspection]
+	gui-libs/text-engine
+	net-libs/libsoup:3.0
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.4.1-make-libbacktrace-optional.patch"
+)
+
+src_configure() {
+	local emesonargs=(
+		-Dpackage="ebuild"
+		-Ddistributor="Gentoo GURU <guru-bugs@gentoo.org>"
+
+		# sys-libs/libbacktrace has been last-rited in ::gentoo
+		# and is thus unavailable
+		-Dbacktrace=false
+	)
+	if has live ${PROPERTIES}; then
+		# Produce a development build for live ebuild
+		emesonargs+=( -Ddevelopment=true )
+	fi
+	meson_src_configure
+}
+
+# Tests are skipped because as of version 0.3.0, the tests only validate
+# resource files and do not verify any functionality of the program.  Those
+# validations are either already handled by QA checks or not relevant on
+# Gentoo.  For more information about the rationale, please refer to:
+# https://github.com/gentoo/guru/commit/f896bee213fbb62c70e818c1bf503fee2a41919a#comments
+#
+# If tests are to be executed in the future because the upstream adds
+# functionality tests or for other reasons, and should there be no convenient
+# way to skip the validations, the following variable values need to be set:
+#
+# IUSE="test"
+# RESTRICT="!test? ( test )"
+# BDEPEND="test? ( dev-libs/appstream-glib dev-util/desktop-file-utils )"
+src_test() {
+	:
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}