kde-misc/geminipart: add 20221020

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

kde-misc/geminipart/Manifest

@@ -1 +1,2 @@
 DIST geminipart-117b525d7a33f7ecc3bb772323c7609c76a6aeb4.tar.gz 23164 BLAKE2B 4ce0eede9f7f54de416d715e2a1a9769f7371238e8520dfb7e0806227da709daf289636caaaa81918a35eb0e719d3f7d78957e00a89c1e9295f7880c1ce2f3d8 SHA512 eb74bff304a0847e2f67d8bb8da6b81d339acb75e9fdcb44fb18950de6bcd65e972ce88abb8b1c258d14a732cb51917d41746baab041ea0f8436e9d859e96fe5
+DIST geminipart-d3fb6f32fb9112d2073d0b0251ae9069224096df.tar.gz 23688 BLAKE2B 1c4da235eb33e3a75a207b2cbc3c0f898c298d04a26b9588b1aa9cb7481aa5dfafa9c58d361b94510bfbf2e13b7fb13f2b2b6c2f5027ea940e49414673f837c0 SHA512 03297a1540be72a932fed8345b35226129682feed69ef34be3a6b121b2640597a24556368e7dcfd49b7304806d5558ce6bdecf6ef36d69d73c83436a6aefed72

kde-misc/geminipart/geminipart-20221020.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COMMIT="d3fb6f32fb9112d2073d0b0251ae9069224096df"
+ECM_TEST="forceoptional"
+KFMIN=5.98.0
+QTMIN=5.4.0
+inherit ecm optfeature
+
+DESCRIPTION="KPart for viewing text/gemini files"
+HOMEPAGE="https://gitlab.com/tobiasrautenkranz/geminipart"
+SRC_URI="https://gitlab.com/tobiasrautenkranz/${PN}/-/archive/${COMMIT}/${PN}-${COMMIT}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="LGPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}"
+
+src_test() {
+	export QT_QPA_PLATFORM=offscreen
+	ecm_src_test
+}
+
+src_prepare() {
+	# Konqueror may not be installed, don't make it default text/gemini handler
+	sed "/MimeType=/d" -i integration/gemini-konqueror.desktop || die
+	ecm_src_prepare
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	optfeature "handling gemini:// URLs in Konqueror browser" \
+		"kde-apps/konqueror kde-misc/kio-gemini"
+}

kde-misc/geminipart/metadata.xml

@@ -6,7 +6,7 @@
 			<name>Tobias Rautenkranz</name>
 			<email>mail@tobias.rautenkranz.ch</email>
 		</maintainer>
-		<bugs-to>https://invent.kde.org/tobias/geminipart/-/issues</bugs-to>
+		<remote-id type="gitlab">tobiasrautenkranz/geminipart</remote-id>
 	</upstream>
 	<maintainer type="person">
 		<email>cyber+gentoo@sysrq.in</email>