media-sound/lms: add 3.51.1

Signed-off-by: David Roman <davidroman96@gmail.com>

media-sound/lms/Manifest

@@ -1 +1,2 @@
 DIST lms-3.50.1.tar.gz 419715 BLAKE2B 80a8c08268d48e4fe8b64f66063cbe925b71288d0604c1395b54fdd35cfe7e815f9f67861cd52ba1934debc04291d96fe85c16ef99108fb9491015cea7562396 SHA512 8787d9a26bddb93d55e42f9b5f5c0295d8c67404e7648c3be620e03ae1e1ed243d87ff978a7c687dd349db4309e858807956bfa804207809c3b2fe3eed87977b
+DIST lms-3.51.1.tar.gz 427958 BLAKE2B 88e7afc4fa3c28761d0ce6fa9c5d98ab9c9525f2138ef0523e9bae45511c74c9417b8717de56b054f5ec15c444fcbc00336795f3bdcbbb906ddde97bc54ad6cd SHA512 f53907e0bbf9f6a26d9231e7eca01fd92f981e1271879bcbb960829b1416d1d73e980f50b4a5a12d1b0e48b7b9d1680b53fedce8e015eee33edc3c890625c34b

media-sound/lms/lms-3.51.1.ebuild

@@ -0,0 +1,72 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic pam systemd
+
+DESCRIPTION="Lightweight Music Server."
+HOMEPAGE="http://lms-demo.poupon.dev/ https://github.com/epoupon/lms"
+SRC_URI="https://github.com/epoupon/lms/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test stb"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-user/lms
+	dev-cpp/wt
+	dev-libs/boost
+	dev-libs/libconfig[cxx]
+	media-libs/taglib
+	media-video/ffmpeg
+
+	!stb? ( media-gfx/graphicsmagick )
+
+"
+
+DEPEND="
+	${RDEPEND}
+
+	stb? ( dev-libs/stb )
+"
+
+BDEPEND="
+	test? ( dev-cpp/gtest )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-respect-ldflags.patch"
+)
+
+src_configure() {
+	append-flags -I/usr/include/stb/deprecated
+
+	local mycmakeargs=(
+		-DIMAGE_LIBRARY=$(usex stb STB GraphicsMagick++)
+		-DENABLE_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	systemd_newunit conf/systemd/default.service lms.service
+	newinitd "${FILESDIR}/lms.init" lms
+	dopamd conf/pam/lms
+	mv "${ED}/usr/share/lms/lms.conf" "${ED}/etc/lms.conf" || die
+
+	# Already installed in the proper directory
+	rm "${ED}/usr/share/lms/default.service" || die
+	rm "${ED}/usr/share/lms/lms" || die
+
+	keepdir /var/log/lms
+	fowners -R lms:lms /var/log/lms
+
+	keepdir /var/lms
+	fowners lms:lms /var/lms
+}