sys-cluster/launchmon: initial import

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

sys-cluster/launchmon/Manifest

@@ -0,0 +1 @@
+DIST launchmon-1.0.2_p20210430.tar.gz 303361 BLAKE2B e1aaed16fee557a33492bd7df2fa95fc9c42e76a2b246ae37522ca7ac36b244acb63ca74c67f91b33c542dbe9628cc67f163294b47595ab4aee4156aad22d55c SHA512 11e158d0a49b369355275117673f9810a65b79aa75d481c6103ca5e49a3b674e2d8cb3b04ec0ffa956cb9f08a6148a31ba859c5f0f8eb38a813ae0cdacdde347

sys-cluster/launchmon/launchmon-1.0.2_p20210430.ebuild

@@ -0,0 +1,53 @@
+# Copyright 2019-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+COMMIT="98ab769c53563f47c4319ce3c98ac394b4870bac"
+MYPV="$(ver_cut 1-3)"
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="software infrastructure that enables HPC run-time tools to co-locate tool daemons with a parallel job"
+HOMEPAGE="https://github.com/LLNL/LaunchMON"
+SRC_URI="https://github.com/LLNL/LaunchMON/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/LaunchMON-${COMMIT}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+munge tracing-cost"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/libgcrypt
+	dev-libs/libgpg-error
+	virtual/libelf
+
+	munge? ( sys-auth/munge )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	sed -e "s|m4_esyscmd.*|${MYPV})|g" -i configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	append-cxxflags "-std=c++14"
+	local sec="none"
+	use munge && sec="munge"
+	local myconf=(
+		--enable-shared
+		--enable-sec-${sec}
+		$(use_enable tracing-cost)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	mv "${ED}/usr/etc" "${ED}" || die
+}

sys-cluster/launchmon/metadata.xml

@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>lssndrbarbieri@gmail.com</email>
+		<name>Alessandro Barbieri</name>
+	</maintainer>
+	<longdescription lang="en">
+LaunchMON is a software infrastructure that enables HPC run-time tools to co-locate tool daemons with a parallel job. Its API allows a tool to identify all the remote processes of a job and to scalably launch daemons into the relevant nodes.
+	</longdescription>
+	<use>
+		<flag name="munge">enable munge for connection authentication</flag>
+		<flag name="tracing-cost">enable tracing cost measuring codes</flag>
+	</use>
+	<upstream>
+		<bugs-to>https://github.com/LLNL/LaunchMON/issues</bugs-to>
+		<remote-id type="github">LLNL/LaunchMON</remote-id>
+	</upstream>
+</pkgmetadata>