dev-python/expression: new package, add 5.6.0

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>

dev-python/expression/Manifest

@@ -0,0 +1 @@
+DIST expression-5.6.0.gh.tar.gz 136000 BLAKE2B 348c35988bff149cec8da214ddeb8c52259acd976fd84ab9519b66ebb8f3ea12f987ee3fba86803ef8e5ca14e5d29473a3b0421bf6dd0110b31cd884efdf6169 SHA512 d4bd38b7e83e0d435d6dea1f90f0379d168107ff9085a95cbc11975b97f33427edc9b7c60b027eb7d4e67ae024329b3fd277efed46d40dd2e959492be1850785

dev-python/expression/expression-5.6.0.ebuild

@@ -0,0 +1,62 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1 optfeature
+
+MY_PN="Expression"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="Practical functional programming for Python 3.10+"
+HOMEPAGE="
+	https://github.com/dbrattli/Expression
+	https://pypi.org/project/expression/
+"
+SRC_URI="https://github.com/dbrattli/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/typing-extensions-4.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/pydantic-2.6.2[${PYTHON_USEDEP}]
+		' python3_{12..14})
+	)
+"
+
+EPYTEST_PLUGINS=( hypothesis pytest-asyncio )
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	sed '/^version = /s/"0.0.0"/"'${PV}'"/' -i pyproject.toml || die
+}
+
+python_test() {
+	local EPYTEST_IGNORE=()
+
+	if ! has_version "dev-python/pydantic[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			# pydantic
+			tests/test_block.py
+			tests/test_option.py
+			tests/test_result.py
+		)
+	fi
+
+	epytest
+}
+
+pkg_setup() {
+	optfeature "Pydantic support" ">=dev-python/pydantic-2.6.2"
+}

dev-python/expression/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>falbrechtskirchinger@gmail.com</email>
+		<name>Florian Albrechtskirchinger</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">expression</remote-id>
+		<remote-id type="github">dbrattli/Expression</remote-id>
+	</upstream>
+</pkgmetadata>