net-analyzer/ipv4-heatmap: new package, add 0_p20210302, 9999

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>

net-analyzer/ipv4-heatmap/Manifest

@@ -0,0 +1 @@
+DIST ipv4-heatmap-3b4b4f87298c84cd1d501e77948c1101ddea1cf6.tar.gz 34250 BLAKE2B 6d0d42d3d4e69416cb97d5ea155a858da6a1f479188a6fdeb7382a557c64d9aab7cc555028ad71ca3ab502a7708f4c5474f1a6bd81932b4e05ed35e08e2fc825 SHA512 aac95c4fe382d9b2a398bac294d4165d3b88365ca48c34f3e128dbc1ae84582a9a26d78e9d6080699cea528439b472ead6b2ef85adefaee8054d1c30e03e2624

net-analyzer/ipv4-heatmap/ipv4-heatmap-0_p20210302.ebuild

@@ -0,0 +1,50 @@
+# Copyright 2026 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+if [[ "${PV}" == "9999"* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/measurement-factory/ipv4-heatmap"
+else
+	EGIT_COMMIT="3b4b4f87298c84cd1d501e77948c1101ddea1cf6"
+	SRC_URI="https://github.com/measurement-factory/ipv4-heatmap/archive/${EGIT_COMMIT}.tar.gz -> ${PN}-${EGIT_COMMIT}.tar.gz"
+	S="${WORKDIR}/${PN}-${EGIT_COMMIT}/"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Generate Hilbert curve heatmaps of the IPv4 address space"
+HOMEPAGE="https://github.com/measurement-factory/ipv4-heatmap"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="media-libs/gd:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '1aPKG_CONFIG ?= pkg-config' \
+		-e 's,^LIBS=.*,LIBS = -lm `${PKG_CONFIG} --libs gdlib`,' \
+		-e 's,^CFLAGS=.*,CFLAGS += `${PKG_CONFIG} --cflags gdlib`,' \
+		-e 's,^LDFLAGS=.*,#LDFLAGS,' \
+		Makefile || die
+}
+
+src_configure() {
+	tc-export CC PKG_CONFIG
+}
+
+src_install() {
+	einstalldocs
+
+	dobin ipv4-heatmap
+	doman ipv4-heatmap.1
+
+	dodoc labels/iana/iana-labels.txt
+}

net-analyzer/ipv4-heatmap/ipv4-heatmap-9999.ebuild

@@ -0,0 +1,50 @@
+# Copyright 2026 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+if [[ "${PV}" == "9999"* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/measurement-factory/ipv4-heatmap"
+else
+	EGIT_COMMIT="3b4b4f87298c84cd1d501e77948c1101ddea1cf6"
+	SRC_URI="https://github.com/measurement-factory/ipv4-heatmap/archive/${EGIT_COMMIT}.tar.gz -> ${PN}-${EGIT_COMMIT}.tar.gz"
+	S="${WORKDIR}/${PN}-${EGIT_COMMIT}/"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Generate Hilbert curve heatmaps of the IPv4 address space"
+HOMEPAGE="https://github.com/measurement-factory/ipv4-heatmap"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="media-libs/gd:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '1aPKG_CONFIG ?= pkg-config' \
+		-e 's,^LIBS=.*,LIBS = -lm `${PKG_CONFIG} --libs gdlib`,' \
+		-e 's,^CFLAGS=.*,CFLAGS += `${PKG_CONFIG} --cflags gdlib`,' \
+		-e 's,^LDFLAGS=.*,#LDFLAGS,' \
+		Makefile || die
+}
+
+src_configure() {
+	tc-export CC PKG_CONFIG
+}
+
+src_install() {
+	einstalldocs
+
+	dobin ipv4-heatmap
+	doman ipv4-heatmap.1
+
+	dodoc labels/iana/iana-labels.txt
+}

net-analyzer/ipv4-heatmap/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>contact@hacktivis.me</email>
+		<name>Haelwenn (lanodan) Monnier</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">measurement-factory/ipv4-heatmap</remote-id>
+	</upstream>
+</pkgmetadata>