media-sound/Tauon: add 8.2.0

Signed-off-by: David Roman <davidroman96@gmail.com>

media-sound/Tauon/Manifest

@@ -1,2 +1,3 @@
 DIST Tauon-8.1.3.tar.gz 1705919 BLAKE2B d835efd05e7630df3334e5e4012b2075d423e6fdbb0e3f4478fcaf8ae7a723925cf0d85c2f883ed5a0e13fe2d673b3e8a2c5009c5ebc61fb567b9dc7e6a8f35f SHA512 4ae2b135af3b471acef12c76af18eeea3ff25d5dff2500d04d4b5d07f58993e89cc7c9cf4755696e214fa49010cef9f3b7708860def7b0edf96ef00808169f58
 DIST Tauon-8.1.4.tar.gz 1706720 BLAKE2B fa0512896c3d5f1f6f5cb7aa6f8ba483c43b706188945231149601f0ec581d6a91f31951afa301531776928680f5c0dea9ed2a3c5fa451c4c1d31b39093fb3b1 SHA512 ba261d4be625378f02a306efd7ac41be568c99eed49e87933dc41d42ddc59070b5e4f8d42e3fa51873fe86933c0ec0e44a45b126fcf28c87dc008d2b7f8a02eb
+DIST Tauon-8.2.0.tar.gz 1666155 BLAKE2B 4ad6db37d633cade5834f05a4a6b5594b3133f28e6f839a533fe96a67b18a45bcc7cf638359fd90c1e5cbfd8e25e0e70fb0e2aa06d52e721517a709ab2541789 SHA512 0804b01d5566424ecaa2aec6bc989784fb1fc240ab9e8d2e7ce55787c18f8104e35ef9a186be4da858a9757f4aabbf43388ae036c26d4123948d1ba2750f7d11

media-sound/Tauon/Tauon-8.2.0.ebuild

@@ -0,0 +1,108 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
+
+PYTHON_COMPAT=( python3_{12..14} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 optfeature plocale xdg
+
+DESCRIPTION="The desktop music player of today!"
+HOMEPAGE="https://tauonmusicbox.rocks/"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_SUBMODULES=()
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
+else
+	SRC_URI="https://github.com/Taiko2k/Tauon/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+PHAZOR_DEPS="
+	dev-libs/miniaudio
+	media-libs/flac:=
+	media-libs/game-music-emu
+	media-libs/libopenmpt
+	media-libs/opus
+	media-libs/opusfile
+	media-libs/libsamplerate
+	media-libs/libvorbis
+	media-sound/mpg123
+	media-sound/wavpack
+	sci-libs/kissfft[-cpu_flags_x86_sse]
+"
+
+DEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/musicbrainzngs[${PYTHON_USEDEP}]
+	dev-python/natsort[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pysdl3[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	media-video/ffmpeg
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-libs/sdl3-image
+
+	${PHAZOR_DEPS}
+"
+
+RDEPEND="
+	${DEPEND}
+
+	dev-libs/libayatana-appindicator
+	media-sound/mpg123-base
+	x11-libs/libnotify
+"
+
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.9.0-phazor-build.patch"
+	"${FILESDIR}/${PN}-8.1.0-fix-locale-path.patch"
+)
+
+src_compile() {
+	distutils-r1_src_compile
+
+	build_locale() {
+		msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
+	}
+
+	plocale_for_each_locale build_locale
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	install_locale() {
+		insinto "/usr/share/locale/${1}/LC_MESSAGES"
+		doins "locale/${1}/LC_MESSAGES/tauon.mo"
+	}
+
+	plocale_for_each_locale install_locale
+
+	sed -i 's/Exec=tauon/Exec=tauonmb/g' extra/tauonmb.desktop || die
+	domenu extra/tauonmb.desktop
+	doicon -s scalable extra/tauonmb.svg
+
+}
+
+pkg_postinst() {
+	optfeature "Chinese searches support" app-i18n/opencc[python]
+	optfeature "last fm support" dev-python/pylast
+	optfeature "PLEX support" dev-python/plexapi
+	optfeature "Spotify support" dev-python/tekore
+
+	xdg_pkg_postinst
+}