net-im/mautrix-telegram: add 0.14.0

Signed-off-by: Julien Roy <julien@jroy.ca>

net-im/mautrix-telegram/Manifest

@@ -1 +1,2 @@
 DIST mautrix-telegram-0.13.0.gh.tar.gz 807103 BLAKE2B 678f763bf21733a57452db4e27b82188851fcfc5538e4cd513d27159f6ea5394bcc12d3e90d4be530fd1be639162816d7e00b990a8dce98e27cf43d2a7c458d7 SHA512 d0f68d24d8281faa6c3895bba60c5b0c356f4fa1312b4f041f3ac7d37cccc791e8d871dd15c11c2bbbb7fa0cb1fe5a9049a6ff3b96c86d0715943e7a3cb31156
+DIST mautrix-telegram-0.14.0.gh.tar.gz 810304 BLAKE2B 3b0391841730e565d5fdb8c272cd19e31aced4b56f5077806ef05d855b9fab1a486baa1cbab3414886d0523db9ccf6de5059f4051ff3dcef0c41ff184bda5277 SHA512 f11500ee00d15763bd4d3f17910805cf3ece9053840c5f7ff9db2287f9668d17a46ca40ce8f4eba0ec876795db92458ff402108d78808ec9aa5cfaa8e2552d8a

net-im/mautrix-telegram/mautrix-telegram-0.14.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature systemd
+
+DESCRIPTION="A Matrix-Telegram Messenger puppeting bridge "
+HOMEPAGE="https://github.com/mautrix/telegram/"
+SRC_URI="https://github.com/mautrix/telegram/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/telegram-${PV}"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	acct-user/${PN}
+	app-arch/brotli[python]
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/aiodns[${PYTHON_USEDEP}]
+	dev-python/asyncpg[${PYTHON_USEDEP}]
+	dev-python/commonmark[${PYTHON_USEDEP}]
+	dev-python/cryptg[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/mautrix[${PYTHON_USEDEP}]
+	dev-python/olm[${PYTHON_USEDEP}]
+	dev-python/phonenumbers[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	>=dev-python/tulir-telethon-1.28.0_alpha9[${PYTHON_USEDEP}]
+	dev-python/unpaddedbase64[${PYTHON_USEDEP}]
+	dev-python/yarl[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+src_install() {
+	distutils-r1_src_install
+
+	keepdir /var/log/mautrix
+	fowners root:mautrix /var/log/mautrix
+	fperms 770 /var/log/mautrix
+	sed -i -e "s/\.\/${PN}.log/\/var\/log\/mautrix\/${PN}.log/" "${ED}/usr/example-config.yaml" || die
+
+	insinto "/etc/mautrix"
+	newins "${ED}/usr/example-config.yaml" "${PN/-/_}.yaml"
+	rm "${ED}/usr/example-config.yaml" || die
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	fowners -R root:mautrix /etc/mautrix
+	fperms -R 770 /etc/mautrix
+}
+
+pkg_postinst() {
+	optfeature "Prometheus statistics" dev-python/prometheus_client
+	optfeature "Sqlite backend" dev-python/aiosqlite
+
+	einfo
+	elog ""
+	elog "Before you can use ${PN}, you must configure it correctly"
+	elog "The configuration file is located at \"/etc/mautrix/${PN/-/_}.yaml\""
+	elog "When done, run the following command: emerge --config ${CATEGORY}/${PN}"
+	elog "Then, you must register the bridge with your homeserver"
+	elog "Refer your homeserver's documentation for instructions"
+	elog "The registration file is located at /var/lib/${PN/-/\/}/registration.yaml"
+	elog "Finally, you may start the ${PN} daemon"
+	einfo
+}
+
+pkg_config() {
+	su - "${PN}" -s /bin/sh -c \
+	   "/usr/bin/python -m ${PN/-/_} -c /etc/mautrix/${PN/-/_}.yaml -g -r /var/lib/${PN/-/\/}/registration.yaml"
+}