media-sound/tidal-hifi-bin: add 5.13.1

Signed-off-by: Kostadin Shishmanov <kocelfc@tutanota.com>

media-sound/tidal-hifi-bin/Manifest

@@ -1,2 +1,3 @@
 DIST tidal-hifi-bin-5.10.0.tar.gz 110336673 BLAKE2B 19f1b22b7417b4e81ab182fcf98557287bc8557149b523e3f8e7ae2a59a9d584fca59a1d36c6ad292c48f0be5fdd277ac730491837d036cc62f3e549f59d8b99 SHA512 ebcaac410a1de0142c38d84c5a540e6f350e3e7c0b7a7584f9665974234bc6f2bfd378f1410f77c18346a90e908fed4de1cd58eeb8d4ccb4e9d8fcbac6903ed7
+DIST tidal-hifi-bin-5.13.1.tar.gz 114560439 BLAKE2B 114610525a3c6fd789e1bf516ddd6c94e08b689949230a35d92ec8a98fa8b90d1364cc95058dea4f4966bbafeacc568dcf9c9aee03b2dd212b1be316ba7f3689 SHA512 ea6b50a206a819258228c3793395e8c7fbc45b883c9924e674e9fe9e211e46b690e48549c3696ac13acdb6d394b40bf2b1d740ddc431e669e0b90be0e70071df
 DIST tidal-hifi-bin-5.9.0.tar.gz 110340819 BLAKE2B 9ce266441aace64718c773b8dd96f925342b38fb1b4d5d1718aec786a2c6825d14a74a94c77487a3cf9b20513561457a52706be3cea0c33ec84e5b624ade9ccb SHA512 f9ef34b04fb448906142d1f8222f9ccf6abb03328fc560e927f5bcc2a1f19955f2117aeb6151876fbb9cb7cc8646c5d61c3604e85beb7fe51e0201d75b28eb20

media-sound/tidal-hifi-bin/tidal-hifi-bin-5.13.1.ebuild

@@ -0,0 +1,100 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN/-bin/}"
+
+CHROMIUM_LANGS="
+	af am ar bg bn ca cs da de el en-GB en-US es es-419 et fa fi fil fr gu he hi
+	hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv
+	sw ta te th tr uk ur vi zh-CN zh-TW
+"
+
+inherit chromium-2 desktop linux-info unpacker xdg
+
+DESCRIPTION="Web version of Tidal running in electron with Hi-Fi support thanks to Widevine."
+HOMEPAGE="https://github.com/Mastermindzh/tidal-hifi"
+SRC_URI="https://github.com/Mastermindzh/tidal-hifi/releases/download/${PV}/tidal-hifi-${PV}.tar.gz -> ${P}.tar.gz"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/libgcrypt
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/mesa[gbm(+)]
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/libdrm
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+"
+
+DESTDIR="/opt/${PN}"
+
+QA_PREBUILT="*"
+
+CONFIG_CHECK="~USER_NS"
+
+src_configure() {
+	default
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_prepare() {
+	default
+	# cleanup languages
+	pushd "locales/" >/dev/null || die "location change for language cleanup failed"
+	chromium_remove_language_paks
+	popd >/dev/null || die "location reset for language cleanup failed"
+	rm -rf "${S}"/resources/app.asar.unpacked/node_modules/register-scheme/build/node_gyp_bins
+	rm -rf "${S}"/resources/app.asar.unpacked/node_modules/abstract-socket/build/node_gyp_bins
+}
+
+src_install() {
+	doicon -s 256 "${FILESDIR}/${MY_PN}.png"
+
+	make_desktop_entry "/usr/bin/tidal-hifi" "TIDAL Hi-Fi" ${MY_PN} "Network;AudioVideo;Audio;Video"
+
+	exeinto "${DESTDIR}"
+
+	doexe "${MY_PN}" chrome-sandbox libEGL.so libffmpeg.so libGLESv2.so libvk_swiftshader.so
+
+	insinto "${DESTDIR}"
+	doins chrome_100_percent.pak chrome_200_percent.pak icudtl.dat resources.pak snapshot_blob.bin v8_context_snapshot.bin
+	insopts -m0755
+	doins -r locales resources
+
+	# Chrome-sandbox requires the setuid bit to be specifically set.
+	# see https://github.com/electron/electron/issues/17972
+	fowners root "${DESTDIR}/chrome-sandbox"
+	fperms 4711 "${DESTDIR}/chrome-sandbox"
+
+	[[ -x chrome_crashpad_handler ]] && doins chrome_crashpad_handler
+
+	dosym "${DESTDIR}/${MY_PN}" "/usr/bin/${MY_PN}"
+}