dev-util/google-antigravity: add 2.15.1

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>

dev-util/google-antigravity/Manifest

@@ -4,3 +4,5 @@ DIST google-antigravity-2.14.0_amd64.tar.gz 173968350 BLAKE2B 78bad4890b98641b90
 DIST google-antigravity-2.14.0_arm64.tar.gz 171001713 BLAKE2B 47bf9f6f885be58d857e7fe6c6140ce52ef368db8ffc68bf5bd09b2f8cb070302398235c5a381e8b9bd95fad30b44250883fe006f672f50a7ed39537f718b34d SHA512 1a504e687b7a43462211ab94d731e9c8ec308f8a91959ed3915ed53927a40e99307f914d5b0c9ba533b3544b718b61deced3145f2e20bfec3cccd9354fc0c912
 DIST google-antigravity-2.15.0_amd64.tar.gz 174278041 BLAKE2B 08da6dff1edeb8e507d12ff6bf049da1f7d1081c1e8917e06aa9c7f74cd1fc9425936e72f73723f7d1c73a7d9290f5645bcb51e881346d9e1fb917e476d42d04 SHA512 7c8fb7cb46456321160b03584544bbb8855f5dbc01afe94265c43ecb2dac833dfb88f68fbba86ef5ffe8d7c244b049bc0557398a28cc555e5a4755aeea66e339
 DIST google-antigravity-2.15.0_arm64.tar.gz 171281032 BLAKE2B fb997d35615bb370e751d7eba094f739d54a815f6514f7a778b4d5e97eb73327007da74eaa134fb2b0f2635d998581511901a40c1a78b2e0c5dc9f59640567e0 SHA512 19662d3b5016586860d0b3ae8d8f152191219135d8923039ac2bb239d7a71b58e4d1f1dc8efd2a0bef7d0216d05f3bca5af4d57747b8f65bd0ad81a5525afdd8
+DIST google-antigravity-2.15.1_amd64.tar.gz 174283090 BLAKE2B edd9762c12c1f9b8cd1c5610ed2111266e3d249db6d7476bac0ecc9c663467604db52e28adf17b6328d7c229ec4cd21b7c136a42d3c15f2c5982990f5d4e8291 SHA512 e155bde0c1f90eb31c29e96bcdf9c47ec9202a90ff7c84665ddb0b0efc757b789cd661837bb6bf9424824ff01031d276b97d65784debb5f4afedb965ed4ad814
+DIST google-antigravity-2.15.1_arm64.tar.gz 171272052 BLAKE2B 1b7378b2941ab481db182d08ef0824c2997b08f9ca1dc20e807606663143e4da53d3edaab70cebdc641967f80bc3394c5b396ae00b216cdf29275e295de6cbee SHA512 c7e79d45658bc5992a8408399a51a4a918368be268afd2bcb9ce9c55518e455d696935a306da8fc6bc68dfe61bc4607d444ba09757be74daaa8eb9dbb8cd8cc3

dev-util/google-antigravity/google-antigravity-2.15.1.ebuild

@@ -0,0 +1,115 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi
+		fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR
+		pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+
+inherit chromium-2 desktop optfeature pax-utils xdg
+
+EXECUTION_ID="5880727900913664"
+
+MY_PN="${PN#google-}"
+DESCRIPTION="Google Antigravity 2.0, a dedicated platform to work with agents"
+HOMEPAGE="https://antigravity.google/"
+BASE_URI="https://storage.googleapis.com/antigravity-public/antigravity-hub/${PV}-${EXECUTION_ID}"
+SRC_URI="
+	amd64? ( ${BASE_URI}/linux-x64/Antigravity.tar.gz -> ${P}_amd64.tar.gz )
+	arm64? ( ${BASE_URI}/linux-arm/Antigravity.tar.gz -> ${P}_arm64.tar.gz )
+"
+S="${WORKDIR}"
+
+# It's complicated...
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	|| (
+		sys-apps/systemd
+		sys-apps/systemd-utils
+	)
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret[crypt]
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/libglvnd
+	media-libs/mesa
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	virtual/zlib:=
+	sys-process/lsof
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	x11-misc/xdg-utils
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/${MY_PN}.*\\.desktop"
+
+AGY_HOME_BASE="opt/google"
+AGY_HOME="${AGY_HOME_BASE}/${MY_PN}"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	default
+	mv "Antigravity-"* "${MY_PN}" || die
+}
+
+src_prepare() {
+	default
+
+	cd "${MY_PN}" || die
+
+	pushd locales > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+}
+
+src_install() {
+	cd "${MY_PN}" || die
+
+	mkdir -p "${ED}/${AGY_HOME}" || die
+	cp -r . "${ED}/${AGY_HOME}" || die
+
+	pax-mark m "${ED}/${AGY_HOME}/${MY_PN}"
+	fperms 0755 "/${AGY_HOME}/${MY_PN}"
+	dosym "/${AGY_HOME}/${MY_PN}" "/usr/bin/${MY_PN}"
+
+	fperms 4711 "/${AGY_HOME}/chrome-sandbox"
+
+	domenu "${FILESDIR}/${MY_PN}.desktop"
+	newicon -s scalable "${FILESDIR}/${MY_PN}.png" ${MY_PN}.png
+
+	insinto /usr/share/metainfo
+	doins "${FILESDIR}/${MY_PN}.metainfo.xml"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "desktop notifications" x11-libs/libnotify
+}