gui-apps/noctalia: add 5.2.0

Signed-off-by: HAZARD <ghostyn678+git@gmail.com>

gui-apps/noctalia/Manifest

@@ -1,2 +1,3 @@
 DIST noctalia-5.0.1.tar.gz 22639593 BLAKE2B 9f1ba741b191237cd47fa7e9d944c44274dab74a30b92eb14db4d2dcfeac8d0a1a7c637edbfa7b3eab492d3c454c7fb5163b931a7b8f94f5d695469fab51150d SHA512 cd67611611667e302a26e1618ee6debc1ba21201d9acdcfd25f733f1ac29b0f521725f512740046ae3f023cc8886f231667801a12bce05d850e52c74472b4970
 DIST noctalia-5.1.0.tar.gz 22737127 BLAKE2B 2f4e061d49634c84e1ad1467b1c119ebeceb55466242edb326e34267b16e08c84e858a1cb9ac4bd4d4ef7dfe5ca5f0d2eb553aaccc31947d406a4d3ffe9a7506 SHA512 3ee505122b326d24df257f2de081a640bf3079e801980b14c40e98e67efa05e8173db5d061e7e7366e2775f78688c96105fa05d0adfde60b57b17342394b84cb
+DIST noctalia-5.2.0.tar.gz 22702373 BLAKE2B d2104ae2528b9cdb7187bb6cf9d9b4a416a05cc17cbedc2c8a5a1d57661d7cb67175c19ffe545667f36a654bfaa598e4bbe37fd5e4511182b2fb5f5dab0d47d5 SHA512 4305db7263175e33fd62f30e33883d355b8d006286abba6ef6da128bdc6fb45e837cdacb88c8bde40b089aefde63d7b2770d40983fdcc8c5fd530b22dfd8a043

gui-apps/noctalia/noctalia-5.2.0.ebuild

@@ -0,0 +1,101 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature shell-completion xdg
+
+DESCRIPTION="A lightweight Wayland shell and bar built directly on Wayland + OpenGL ES"
+HOMEPAGE="https://noctalia.dev/ https://github.com/noctalia-dev/noctalia"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/noctalia-dev/noctalia.git"
+else
+	SRC_URI="https://github.com/noctalia-dev/noctalia/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+IUSE="+jemalloc"
+
+DEPEND="
+	dev-cpp/nlohmann_json
+	dev-cpp/sdbus-c++
+	dev-cpp/tomlplusplus
+	dev-libs/glib:2
+	jemalloc? ( dev-libs/jemalloc:= )
+	dev-libs/libxml2
+	dev-libs/md4c
+	dev-libs/stb
+	dev-libs/libical
+	dev-libs/libsodium
+	dev-libs/wayland
+	app-crypt/libsecret
+	gnome-base/librsvg:2
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz
+	media-libs/libjxl
+	media-libs/libsndfile
+	media-libs/libwebp
+	media-libs/mesa
+	media-video/pipewire
+	media-video/wireplumber
+	net-misc/curl
+	sci-libs/libqalculate
+	sys-auth/polkit
+	sys-libs/pam
+	virtual/opengl
+	x11-libs/cairo[glib]
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	x11-themes/sound-theme-freedesktop
+"
+
+RDEPEND="
+	${DEPEND}
+	dev-vcs/git
+"
+
+BDEPEND="
+	dev-libs/wayland
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+"
+
+DOCS=( {README,CREDITS}.md example.toml )
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature jemalloc)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+
+	"${BUILD_DIR}"/${PN} completions bash > ${PN}.bash || die
+	"${BUILD_DIR}"/${PN} completions zsh > ${PN}.zsh || die
+	"${BUILD_DIR}"/${PN} completions fish > ${PN}.fish || die
+}
+
+src_install() {
+	meson_src_install
+
+	newbashcomp "${PN}.bash" "${PN}"
+	dofishcomp "${PN}.fish"
+	newzshcomp "${PN}.zsh" "_${PN}"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "external display brightness control" app-misc/ddcutil
+	optfeature "battery and power device integration" sys-power/upower
+	optfeature "clipboard auto-paste" gui-apps/wtype
+	optfeature "hardware-accelerated screen recording" media-video/gpu-screen-recorder
+}

gui-apps/noctalia/noctalia-9999.ebuild

@@ -52,6 +52,7 @@ DEPEND="
 	x11-libs/cairo[glib]
 	x11-libs/libxkbcommon
 	x11-libs/pango
+	x11-themes/sound-theme-freedesktop
 "
 
 RDEPEND="