net-irc/srain: add 1.8.1

Also add missing BDEPENDs.

Signed-off-by: Alexander Tsoy <alexander@tsoy.me>

net-irc/srain/Manifest

@@ -1 +1,2 @@
 DIST srain-1.8.0.tar.gz 2765239 BLAKE2B 123e214f336ca5f848e7f992dbd26a56331c41383b9724935a080b810d67fb6edb67d87b81e82e8872cc60b11b652d4c06628fc90666214a85e834986ea43721 SHA512 885d1f9c0472b9a0ef7f404e929c06190ab007beedd7fa5e7b886f33d194bee774b80e00c44267e955c88bafa1817bddb48a5ba9bd486fc9d61ff51e08e9c2c1
+DIST srain-1.8.1.tar.gz 2765196 BLAKE2B 48c624dc5125e27fe7d8d4be51f5ef2949e9ee32d6c491a0434b53a69daf9e4beae434e375c89e1c819f1cd2f23318fffd627f269d5770a3165d08e7be08f958 SHA512 1cb9b953ec3747217a360082accb36252485e8ab1cd7e836e6b1aa2eb659570a0654e157a3c2352dc71d94e24d392f7ad032201c6eb06afdbfe104c436455fff

net-irc/srain/srain-1.8.1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit meson python-any-r1 xdg
+
+DESCRIPTION="Modern, beautiful IRC client written in GTK+ 3"
+HOMEPAGE="https://github.com/SrainApp/srain"
+SRC_URI="https://github.com/SrainApp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="appindicator doc man"
+
+RDEPEND="
+	app-crypt/libsecret
+	dev-libs/glib:2
+	dev-libs/libconfig:=
+	dev-libs/openssl:=
+	net-libs/libsoup:3.0
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	appindicator? ( dev-libs/libayatana-appindicator )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( $(python_gen_any_dep '
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinxnotes-mock[${PYTHON_USEDEP}]
+		' ) )
+	man? ( $(python_gen_any_dep '
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinxnotes-mock[${PYTHON_USEDEP}]
+		' ) )
+	sys-devel/gettext
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+
+python_check_deps() {
+	if use doc || use man; then
+		python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/sphinxnotes-mock[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed "s/\('doc'\), meson.project_name()/\1, '${PF}'/" \
+		-i meson.build || die
+}
+
+src_configure() {
+	local -a doc_builders=()
+	use doc && doc_builders+=( html )
+	use man && doc_builders+=( man )
+
+	local emesonargs=(
+		-Ddoc_builders="$(meson-format-array "${doc_builders[@]}")"
+		$(meson_use appindicator app_indicator)
+	)
+	meson_src_configure
+}