net-vpn/amneziawg-tools: add 3.1.20260812

Signed-off-by: Pavel Sobolev <contact@paveloom.dev>
2026-10-12 17:51:11 -04:00 · 2026-08-24 21:33:16 +03:00
1 parent 91b95a14f2
commit 427269fef0
@@ -1,2 +1,3 @@
 DIST amneziawg-tools-1.0.20260618_p2.tar.gz 160003 BLAKE2B e2b136d8da475f584f5a7c9db8be52687bce48083050d3d15e7c92c5ccd3c6b091540298f32741f65bb1ce2f9c439ceb6d2ef0c3a191a1c82682c2500d83da07 SHA512 5f75260e9de307b1e20f403b5acaf044e0930557adfc1556d9fa04f96e776d73be261658d9aee21aec518c09fa98d4405ef663c8eb908ea76c84d184bf77ec53
 DIST amneziawg-tools-3.0.20260805.tar.gz 161302 BLAKE2B 4fd49d65690870fbb5970c0154b0de426fd9675a05733a1b7ada0a0a64fa8f71b417cfa394a7c8562c9a63096058b9c61df94288a06046c6d11fe26ee0ba0ebb SHA512 537031368132f8ae266f2717742d80b7f628cfc0d5c1a00d3297fd6c668574c6b5a581ca270565ea13ec53f38100ae699d984e5c3bfeba76a0b1dd78d97c71e9
+DIST amneziawg-tools-3.1.20260812.tar.gz 161898 BLAKE2B 5a973b2d500ac9bf0954f555ecabc0f36b0a2bdcc9139deadf1bfc95c1b3caa76b1042851f7517e70b3b8456e3635e686340823c9d177a0b49c50bd51d888b1e SHA512 22fd16d6e9ade7e2ed41bad785e41dea4204218ca20fdf875dd60d30a93090ade22f8d2d502803bcaa6ffd0c715adc566b70c2798c181dd0c668277a200facd1
@@ -0,0 +1,89 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info shell-completion systemd toolchain-funcs
+
+DESCRIPTION="Required tools for AmneziaWG, such as awg(8) and awg-quick(8)"
+HOMEPAGE="https://github.com/amnezia-vpn/amneziawg-tools"
+SRC_URI="https://github.com/amnezia-vpn/${PN}/archive/refs/tags/v${PV/_p/-}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${PV/_p/-}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+awg-quick selinux"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="${DEPEND}
+	awg-quick? (
+		|| ( net-firewall/nftables net-firewall/iptables )
+		virtual/resolvconf
+	)
+	selinux? ( sec-policy/selinux-wireguard )
+"
+
+awg_quick_optional_config_nob() {
+	CONFIG_CHECK="$CONFIG_CHECK ~$1"
+	declare -g ERROR_$1="CONFIG_$1: This option is required for automatic routing of default routes inside of awg-quick(8), though it is not required for general AmneziaWG usage."
+}
+
+pkg_setup() {
+	if use awg-quick; then
+		awg_quick_optional_config_nob IP_ADVANCED_ROUTER
+		awg_quick_optional_config_nob IP_MULTIPLE_TABLES
+		awg_quick_optional_config_nob IPV6_MULTIPLE_TABLES
+		if has_version net-firewall/nftables; then
+			awg_quick_optional_config_nob NF_TABLES
+			awg_quick_optional_config_nob NF_TABLES_IPV4
+			awg_quick_optional_config_nob NF_TABLES_IPV6
+			awg_quick_optional_config_nob NFT_CT
+			awg_quick_optional_config_nob NFT_FIB
+			awg_quick_optional_config_nob NFT_FIB_IPV4
+			awg_quick_optional_config_nob NFT_FIB_IPV6
+			awg_quick_optional_config_nob NF_CONNTRACK_MARK
+		elif has_version net-firewall/iptables; then
+			awg_quick_optional_config_nob NETFILTER_XTABLES
+			awg_quick_optional_config_nob NETFILTER_XT_MARK
+			awg_quick_optional_config_nob NETFILTER_XT_CONNMARK
+			awg_quick_optional_config_nob NETFILTER_XT_MATCH_COMMENT
+			awg_quick_optional_config_nob NETFILTER_XT_MATCH_ADDRTYPE
+			awg_quick_optional_config_nob IP6_NF_RAW
+			awg_quick_optional_config_nob IP_NF_RAW
+			awg_quick_optional_config_nob IP6_NF_FILTER
+			awg_quick_optional_config_nob IP_NF_FILTER
+		fi
+	fi
+	get_version
+	if ! has_version net-vpn/amneziawg-modules; then
+		ewarn
+		ewarn "Linux kernel does not have upstream support for AmneziaWG."
+		ewarn "However, the net-vpn/amneziawg-modules ebuild"
+		ewarn "contains a module that should work for your kernel."
+		ewarn "It is highly recommended to install it:"
+		ewarn
+		ewarn "    emerge -av net-vpn/amneziawg-modules"
+		ewarn
+	fi
+	linux-info_pkg_setup
+}
+
+src_compile() {
+	emake RUNSTATEDIR="${EPREFIX}/run" -C src CC="$(tc-getCC)" LD="$(tc-getLD)"
+}
+
+src_install() {
+	dodoc README.md
+	dodoc -r contrib
+	emake \
+		WITH_BASHCOMPLETION=yes \
+		WITH_SYSTEMDUNITS=yes \
+		WITH_WGQUICK=$(usex awg-quick) \
+		DESTDIR="${D}" \
+		BASHCOMPDIR="$(get_bashcompdir)" \
+		SYSTEMDUNITDIR="$(systemd_get_systemunitdir)" \
+		PREFIX="${EPREFIX}/usr" \
+		-C src install
+	use awg-quick && newinitd "${FILESDIR}/awg-quick.init" awg-quick
+}