media-gfx/azpainter: add 3.0.9a

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

media-gfx/azpainter/Manifest

@@ -1 +1,2 @@
 DIST azpainter-v3.0.8.tar.bz2 993619 BLAKE2B beca5c3e7f39547c35f2de38933b15ba5fb8b9a840e37b66a9b8371b2a41bdf935556907778bcaf5f669ab76cf414fd766c322fa35d60c07add440f577341068 SHA512 2584e2feb7e4c9853482ab04940c7e2766571a64d76a0f6637fb65d50011b49f1f69d4db718083b90ae6067d6de6898d87e2bf6a8612ba9014267196842b339c
+DIST azpainter-v3.0.9a.tar.bz2 993555 BLAKE2B dc3880834f016ab7cdf61ab4153e5e50054269cbb8a0d9ad2281d026d69a6a12215bd1503bc3b61da0a2171e7e6af078482c0536587ef62da710e2b3fe9b234e SHA512 d6c360cf6d46d996995fb2d3ff36f80d05696ee218c51346aee1c6c6810c83d41c5c4a9fa2c3a06704866e4e6b51e394d2e7d5570407e38d76789bf17a07b598

media-gfx/azpainter/azpainter-3.0.9a.ebuild

@@ -0,0 +1,63 @@
+# Copyright 2018-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edo ninja-utils toolchain-funcs xdg
+
+DESCRIPTION="Full color painting software for Linux for illustration drawing"
+HOMEPAGE="http://azsky2.html.xdomain.jp/soft/azpainter.html
+	https://gitlab.com/azelpg/azpainter"
+SRC_URI="https://gitlab.com/azelpg/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:=
+	media-libs/libwebp:=
+	media-libs/tiff:=
+	sys-libs/zlib:=
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXi
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${NINJA_DEPEND}
+	virtual/pkgconfig
+"
+
+DOCS=(
+	about_mlk_en.txt
+	about_mlk_ja.txt
+	translation/tool/about-en.txt
+	translation/tool/about-ja.txt
+)
+
+PATCHES=( "${FILESDIR}/${PN}-3.0.7-strict-aliasing.patch" )
+
+src_prepare() {
+	sed -i "s|cc|$(tc-getCC)|" configure || die
+	sed -i "s|ar rc|$(tc-getAR) rc|" build.ninja.in || die
+	sed -i "s|doc/@PACKAGE_NAME@|doc/${PF}|" install.sh.in || die
+	default
+}
+
+src_configure() {
+	edo sh ./configure --prefix="${EPREFIX}/usr" CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+}
+
+src_compile() {
+	eninja -C build
+}
+
+src_install() {
+	DESTDIR="${D}" eninja -C build install
+}