net-p2p/gridcoin: add 5.5.1.0

Closes: https://bugs.gentoo.org/945705 (obsolete) Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
2026-07-08 06:32:59 -04:00 · 2026-06-08 19:51:44 +05:00
parent 4eb307e102
commit 3a0a6b5ef4
2 changed files with 104 additions and 0 deletions
--- a/net-p2p/gridcoin/Manifest
+++ b/net-p2p/gridcoin/Manifest
@@ -1 +1,2 @@
 DIST gridcoin-5.5.0.0.tar.gz 44109432 BLAKE2B 4e7d1e4e36f6ecab44a181e99bf4e71934db145b7b5e31aa4b8736419d12a40f85391542f01c0c26f199f3d591798dc3c342c7e295fc0ec84c8c235211e4f6f8 SHA512 b0927b11499d8ff6f16cafe54393b2ace1a9b73966e26790e86919f6c29b0a85a45fb3329019c640c6ee945f28d8cae4556bdb2ec4c5df8d6efaca17824e9082
+DIST gridcoin-5.5.1.0.tar.gz 44116562 BLAKE2B 9a91d866ce56943c1186131fd62074100833c312ecab0ba0439113dfb19b99e9995b3fc631b5d2ae190945d128e714a74cbeb926bdc176acb9317e2a0606face SHA512 39ca131de0987a5b7bccd3d117362981bbf6300d01790bb0fe5b73f06e8918d25b1849753f7889058dca61e0dc3d5c8edcdb2ff9d99e10e225b3d4494212f05b
--- a/net-p2p/gridcoin/gridcoin-5.5.1.0.ebuild
+++ b/net-p2p/gridcoin/gridcoin-5.5.1.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake db-use multilib xdg-utils
+
+MY_PV="${PV/_p/-hotfix-}"
+DESCRIPTION="Proof-of-Stake based cryptocurrency that rewards BOINC computation"
+HOMEPAGE="https://gridcoin.us/"
+SRC_URI="https://github.com/${PN}-community/${PN^}-Research/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN^}-Research-${MY_PV}"
+
+LICENSE="BSD BSD-2 Boost-1.0 MIT SSLeay"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+asm dbus gui qrcode test +upnp"
+IUSE+=" cpu_flags_arm_neon cpu_flags_x86_avx2 cpu_flags_x86_sha cpu_flags_x86_sse4_1"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	dbus? ( gui )
+	qrcode? ( gui )
+"
+
+BDB_SLOT="5.3"
+RDEPEND="
+	>=dev-libs/boost-1.66.0:=[zlib(+)]
+	>=dev-libs/libsecp256k1-0.2.0:=[recovery(+)]
+	>=dev-libs/leveldb-1.21:=
+	dev-libs/libzip:=
+	dev-libs/openssl:=
+	dev-libs/univalue
+	net-misc/curl[ssl]
+	sys-libs/db:${BDB_SLOT}[cxx]
+	gui? (
+		dev-qt/qt5compat:6[gui]
+		dev-qt/qtbase:6[concurrent,dbus?,gui,network,widgets]
+		dev-qt/qtsvg:6
+		qrcode? ( media-gfx/qrencode:= )
+	)
+	upnp? ( net-libs/miniupnpc:= )
+"
+DEPEND="${RDEPEND}
+	virtual/zlib
+"
+BDEPEND="
+	virtual/pkgconfig
+	gui? ( dev-qt/qttools:6[linguist] )
+	test? ( dev-util/xxd )
+"
+IDEPEND="gui? ( dev-util/desktop-file-utils )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DAEMON=$(usex !gui)
+		-DENABLE_GUI=$(usex gui)
+		-DENABLE_TESTS=$(usex test)
+
+		-DENABLE_SSE41=$(usex cpu_flags_x86_sse4_1)
+		-DENABLE_AVX2=$(usex cpu_flags_x86_avx2)
+		-DENABLE_X86_SHANI=$(usex cpu_flags_x86_sha)
+		-DENABLE_ARM_SHANI=$(usex cpu_flags_arm_neon)
+		-DUSE_ASM=$(usex asm)
+
+		-DENABLE_QRENCODE=$(usex qrcode)
+		-DENABLE_UPNP=$(usex upnp)
+		-DDEFAULT_UPNP=$(usex upnp)
+		-DUSE_DBUS=$(usex dbus)
+		-DUSE_QT6=ON
+
+		-DSYSTEM_BDB=ON
+		-DBerkeleyDB_INCLUDE_DIR="$(db_includedir ${BDB_SLOT})"
+		-DBerkeleyDB_CXX_LIBRARY="${ESYSROOT}/usr/$(get_libdir)/libdb_cxx-${BDB_SLOT}$(get_libname)"
+		-DSYSTEM_LEVELDB=ON
+		-DSYSTEM_SECP256K1=ON
+		-DSYSTEM_UNIVALUE=ON
+		-DSYSTEM_XXD=ON
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	if use gui; then
+		rm "${ED}"/usr/bin/gridcoin.icns || die
+	fi
+}
+
+pkg_postinst() {
+	# we don't use xdg.eclass because it adds unconditional IDEPENDs
+	if use gui; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use gui; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}