app-misc/fastfetch: add 1.7.3

Signed-off-by: Viorel Munteanu <ceamac.paragon@gmail.com>

app-misc/fastfetch/Manifest

@@ -1 +1,2 @@
 DIST fastfetch-1.7.2.tar.gz 426097 BLAKE2B 5f9714b735605d4cc4cf8179f048c4cff24db0010f91e080f5e6c0f41329cbc155cdb883775ccb98bda77bfd4efb1f2b79f0adad4a2694d338b0027a31f170b1 SHA512 9f3051d8b9bc22ef93a2e6993c553c5a18d475c8cbb16a63087706aa823a0a4806c49aabb3cdbf5f240f9c9325ea5cb7db2498adcc87c9e44b77d26f6c28a39f
+DIST fastfetch-1.7.3.tar.gz 449029 BLAKE2B 220a2c031ffc45ab1783cf6b51887320225aba9787a07026bc80528477790c84dc3d484323a041aae448d22b7122d17f73f6ce456c3cec1525c9eb8833a3a566 SHA512 a30d844a84d1da1fa9517793a7ba482b66db92170cb7ec5e2510f562815caff614aec2ef8a8d29a707865488b585a5f785013f7fe7759de5a062085a596e96c1

app-misc/fastfetch/fastfetch-1.7.3.ebuild

@@ -0,0 +1,87 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Fast system information tool"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X chafa dbus gnome imagemagick opencl opengl osmesa pci sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	dev-libs/cJSON
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_ZLIB=yes
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_LIBCJSON=yes
+	)
+
+	cmake_src_configure
+}

app-misc/fastfetch/fastfetch-9999.ebuild

@@ -20,6 +20,7 @@ IUSE="X chafa dbus gnome imagemagick opencl opengl osmesa pci sqlite vulkan wayl
 
 # note - qa-vdb will always report errors because fastfetch loads the libs dynamically
 RDEPEND="
+	dev-libs/cJSON
 	sys-libs/zlib
 	X? ( x11-libs/libX11 )
 	chafa? ( media-gfx/chafa )
@@ -78,6 +79,7 @@ src_configure() {
 		-DENABLE_OSMESA=$(usex osmesa)
 		-DENABLE_OPENCL=$(usex opencl)
 		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_LIBCJSON=yes
 	)
 
 	cmake_src_configure