media-libs/libavif: version bump to 0.7.2

Package-Manager: Portage-2.3.89, Repoman-2.3.20
RepoMan-Options: --force
Signed-off-by: Daniel Novomesky <dnovomesky@gmail.com>

media-libs/libavif/Manifest

@@ -1 +1,2 @@
 DIST libavif-0.6.4.tar.gz 2880753 BLAKE2B d42e106a67aa82e4e9cd28488e6393e100e78bf381f8db6f9563c8563eec8c8afe64dedd4b3cdcadc296f15472995cee979469230085aa27a19a48f2d01f5e6a SHA512 ccd9ef462b9a235914f08a75f7acefc1592037e14967089bbc118838ba3603aa527f20b842c658b357f159de28dede15ab80e27f08a19ad3456247970c0ad822
+DIST libavif-0.7.2.tar.gz 2892316 BLAKE2B 24f2a25744fda5f6847506ab4c7a326635fe417dd4385960322f8302b1b60c1ef96ed9ebf453fddb8eba6e7f58506e15ec6934eca76b33ccd803f324432c0340 SHA512 543aae3dde2ed19a8d2d22425260d09f577fbddbd5bc293cc9ec97e427f3854e7a957b4975130b1129a0c73847398ce88ab22de48bec500b83bc56fde671e6b7

media-libs/libavif/libavif-0.7.2.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Library for encoding and decoding .avif files"
+HOMEPAGE="https://github.com/AOMediaCodec/libavif"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/AOMediaCodec/libavif.git"
+else
+	SRC_URI="https://github.com/AOMediaCodec/libavif/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="dav1d +libaom rav1e"
+
+REQUIRED_USE="|| ( dav1d libaom )"
+
+DEPEND="dav1d? ( media-libs/dav1d )
+	libaom? ( >=media-libs/libaom-1.1 )
+	rav1e? ( media-video/rav1e[capi] )
+	media-libs/libpng
+	virtual/jpeg
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+src_configure() {
+	local mycmakeargs=(
+		-DAVIF_CODEC_DAV1D=$(usex dav1d ON OFF)
+		-DAVIF_CODEC_AOM=$(usex libaom ON OFF)
+		-DAVIF_CODEC_RAV1E=$(usex rav1e ON OFF)
+		-DBUILD_SHARED_LIBS=ON
+		-DAVIF_BUILD_APPS=ON
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	if ! use libaom && ! use rav1e ; then
+		ewarn "libaom and rav1e flags are not set,"
+		ewarn "libavif will work in read-only mode."
+		ewarn "Enable libaom or rav1e flag if you want to save .AVIF files."
+	fi
+
+	if use libaom ; then
+		elog "When you upgrade libaom in the future,"
+		elog " you may need to re-emerge libavif again"
+		elog " to ensure correct AVIF import/export functions."
+	fi
+
+	if use rav1e ; then
+		elog "When you upgrade rav1e in the future,"
+		elog " you may need to re-emerge libavif again"
+		elog " to ensure correct AVIF export function."
+	fi
+}