dev-vcs/got: initial import

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-vcs/got/Manifest

@@ -0,0 +1 @@
+DIST got-0_p20210217.tar.gz 517647 BLAKE2B 4b4f5436c5804aa60038d737de883eb69ce4d4f0f705f7d310722222da38b917d577a09fb37b2317c1a34b1a0aa2b0fe00cf07dcbb350a901fe50dbb31ca6ede SHA512 fb3c60b5d1036d735e775e362c7349720bfeae62c1e8b830417b5edd57c86546a97113f6b10b742b1b3b6146d0a7e41906042c1008551b4d15e2bd0331c7ab2f

dev-vcs/got/got-0_p20210217.ebuild

@@ -0,0 +1,56 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+MY_PN="${PN}-portable"
+COMMIT="36536ee0b0fb5108076d8238a4b78c59db9dac3d"  # "linux" branch
+DESCRIPTION="Portable version of the Game of Trees version control system"
+HOMEPAGE="https://gameoftrees.org"
+SRC_URI="https://git.gameoftrees.org/gitweb/?p=${MY_PN}.git;a=snapshot;h=${COMMIT};sf=tgz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${COMMIT:0:7}"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	app-crypt/libmd
+	dev-libs/openssl:=
+	sys-libs/ncurses:=
+	sys-libs/zlib:=
+	elibc_Darwin? ( sys-libs/native-uuid )
+	elibc_SunOS? ( sys-libs/libuuid )
+	!elibc_Darwin? (
+		dev-libs/libbsd
+		!elibc_SunOS? (
+			sys-apps/util-linux
+		)
+	)
+"
+RDEPEND="${DEPEND}
+	dev-vcs/git
+"
+BDEPEND="
+	virtual/pkgconfig
+	virtual/yacc
+"
+
+DOCS=( CHANGES README README.portable )
+
+src_prepare() {
+	default
+
+	# remove debugging flags (-Werror, -g, ...)
+	sed "s/\(GOT_RELEASE\)=No/\1=Yes/" -i configure.ac || die
+	sed "/AM_CFLAGS += -g/d" -i Makefile.am || die
+
+	eautoreconf
+}
+
+src_install() {
+	default
+	doman got/*.5
+}

dev-vcs/got/metadata.xml

@@ -0,0 +1,26 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<longdescription>
+		Game of Trees (Got) is a version control system which prioritizes
+		ease of use and simplicity over flexibility.
+
+		Got uses Git repositories to store versioned data. Git can be used
+		for any functionality which has not yet been implemented in Got.
+		It will always remain possible to work with both Got and Git on the
+		same repository.
+	</longdescription>
+	<upstream>
+		<maintainer>
+			<email>thomas@xteddy.org</email>
+			<name>Thomas Adam</name>
+		</maintainer>
+		<bugs-to>mailto:gameoftrees@openbsd.org</bugs-to>
+		<doc>https://gameoftrees.org/examples.html</doc>
+		<changelog>https://git.gameoftrees.org/gitweb/?p=got-portable.git;a=blob_plain;f=CHANGES</changelog>
+	</upstream>
+</pkgmetadata>