net-irc/srain: add 1.8.0

Signed-off-by: Christopher Byrne <salah.coronya@gmail.com>

net-irc/srain/Manifest

@@ -1 +1,2 @@
 DIST srain-1.7.0.tar.gz 2760861 BLAKE2B 2cbf4bc1a1777b851ea604e63350947851fa0a4c937fbd60c6192e2d197c137870bd2859d922de9ff6bd4b2da7e8fcdcd07493f68fd021ab775125de0dbda359 SHA512 0549a08379946cc4ea0c331f212f03b08a0c7248964984d01a64744058d116ec1af05b2aefd0d689438dafa9df4e70179bb8957d9992f02414a462577c5d99dc
+DIST srain-1.8.0.tar.gz 2765239 BLAKE2B 123e214f336ca5f848e7f992dbd26a56331c41383b9724935a080b810d67fb6edb67d87b81e82e8872cc60b11b652d4c06628fc90666214a85e834986ea43721 SHA512 885d1f9c0472b9a0ef7f404e929c06190ab007beedd7fa5e7b886f33d194bee774b80e00c44267e955c88bafa1817bddb48a5ba9bd486fc9d61ff51e08e9c2c1

net-irc/srain/srain-1.8.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+inherit meson python-any-r1 xdg
+
+DESCRIPTION="Modern, beautiful IRC client written in GTK+ 3"
+HOMEPAGE="https://github.com/SrainApp/srain"
+SRC_URI="https://github.com/SrainApp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="appindicator doc man"
+
+RDEPEND="
+	app-crypt/libsecret
+	dev-libs/glib:2
+	dev-libs/libconfig:=
+	dev-libs/openssl:=
+	net-libs/libsoup:3.0
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	appindicator? ( dev-libs/libayatana-appindicator )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( $(python_gen_any_dep '
+		dev-python/sphinx[${PYTHON_USEDEP}]' ) )
+	man? ( $(python_gen_any_dep '
+		dev-python/sphinx[${PYTHON_USEDEP}]' ) )
+	${PYTHON_DEPS}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.7.0-gcc15.patch"
+)
+
+python_check_deps() {
+	if use doc || use man; then
+		python_has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed "s/\('doc'\), meson.project_name()/\1, '${PF}'/" \
+		-i meson.build || die
+}
+
+src_configure() {
+	local -a doc_builders=()
+	use doc && doc_builders+=( html )
+	use man && doc_builders+=( man )
+
+	local emesonargs=(
+		-Ddoc_builders="$(meson-format-array "${doc_builders[@]}")"
+		$(meson_use appindicator app_indicator)
+	)
+	meson_src_configure
+}